lighttpd: Upgrade to 1.4.30

(From OE-Core rev: 26d2c86babf13d594d7e735c7bf15196d33605de)

Signed-off-by: Zhai Edwin <edwin.zhai@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 63 insertions, 0 deletions

diff --git a/meta/recipes-extended/lighttpd/lighttpd_1.4.30.bb b/meta/recipes-extended/lighttpd/lighttpd_1.4.30.bb
new file mode 100644
index 0000000000..2c247f0531
--- /dev/null
+++ b/meta/recipes-extended/lighttpd/lighttpd_1.4.30.bb
@@ -0,0 +1,63 @@
+DESCRIPTION = "Lightweight high-performance web server"
+HOMEPAGE = "http://www.lighttpd.net/"
+BUGTRACKER = "http://redmine.lighttpd.net/projects/lighttpd/issues"
+
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://COPYING;md5=e4dac5c6ab169aa212feb5028853a579"
+
+
+SECTION = "net"
+DEPENDS = "zlib libpcre"
+RDEPENDS_${PN} += " \
+               lighttpd-module-access \
+               lighttpd-module-accesslog \
+               lighttpd-module-indexfile \
+               lighttpd-module-dirlisting \
+               lighttpd-module-staticfile \
+"
+
+PR = "r0"
+
+SRC_URI = "http://download.lighttpd.net/lighttpd/releases-1.4.x/lighttpd-${PV}.tar.bz2 \
+        file://index.html.lighttpd \
+        file://lighttpd.conf \
+        file://lighttpd \
+"
+
+SRC_URI[md5sum] = "63f9df52dcae0ab5689a95c99c54e48a"
+SRC_URI[sha256sum] = "0d795597e4666dbf6ffe44b4a42f388ddb44736ddfab0b1ac091e5bb35212c2d"
+
+EXTRA_OECONF = " \
+             --without-bzip2 \
+             --without-ldap \
+             --without-lua \
+             --without-memcache \
+             --with-pcre \
+             --without-webdav-props \
+             --without-webdav-locks \
+             --without-openssl \
+             --disable-static \
+"
+
+inherit autotools pkgconfig update-rc.d gettext
+
+INITSCRIPT_NAME = "lighttpd"
+INITSCRIPT_PARAMS = "defaults 70"
+
+do_install_append() {
+    install -d ${D}${sysconfdir}/init.d ${D}/www/logs ${D}/www/pages/dav ${D}/www/var
+    install -m 0755 ${WORKDIR}/lighttpd ${D}${sysconfdir}/init.d
+    install -m 0755 ${WORKDIR}/lighttpd.conf ${D}${sysconfdir}
+    install -m 0644 ${WORKDIR}/index.html.lighttpd ${D}/www/pages/index.html
+}
+
+FILES_${PN} += "${sysconfdir} /www"
+
+CONFFILES_${PN} = "${sysconfdir}/lighttpd.conf"
+
+PACKAGES_DYNAMIC = "lighttpd-module-*"
+
+python populate_packages_prepend () {
+        lighttpd_libdir = bb.data.expand('${libdir}', d)
+        do_split_packages(d, lighttpd_libdir, '^mod_(.*)\.so$', 'lighttpd-module-%s', 'Lighttpd module for %s', extra_depends='')
+}