diff options
author | Pierre-Jean Texier <pjtexier@koncepto.io> | 2020-06-07 18:11:23 +0200 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2020-06-09 13:14:01 +0100 |
commit | f08d269c484417f3284c683ed690584642d33915 (patch) | |
tree | 10b892e315bc736a977938fb841d29658907abd3 /meta/recipes-extended/iptables/iptables_1.8.5.bb | |
parent | 5d3497828a1c31aac5e898ed2f4f62493e1b6d29 (diff) | |
download | poky-f08d269c484417f3284c683ed690584642d33915.tar.gz |
iptables: upgrade 1.8.4 -> 1.8.5
This release contains the following fixes and enhancements:
xtables-save/xtables-restore:
- Fix parser in `--noflush' mode incorrectly rejecting chain definitions
and empty lines.
- Fix crash when restoring or dumping while other ruleset changes happen
in parallel.
iptables-apply:
- Install the script along with `make install'.
- Introduce parameters `-c' (run command) and `-w' (save successfully
applied rules to file).
- Use `mktemp' instead of `tempfile' for temporary files.
iptables-translate:
- Support `time' match and `NOTRACK' target.
- Fix for special interface names `*', `+' and `eth++'.
ebtables-nft:
- Full among match support, including sets with mixed MAC and MAC+IP
entries.
extensions:
- connlabel: Numeric labels were rejected if a connlabel.conf existed in
the system.
- IDLETIMER: Introduce `--alarm' option.
libxtables:
- Introduce xtables_fini() to properly deinit the library and close any
loaded shared objects.
nfnl_osf:
- Fix lockup after loading the first line from fingerprints file.
- Improve error handling, don't silently exit when deleting a
non-existing fingerprint.
General:
- Fixes for undefined behaviour.
- Replace a few unsafe calls to strcpy().
- Fix some warnings when compiling with clang.
- Various fixes for valgrind-detected problems such as memory leaks and
reachable memory at program exit.
(From OE-Core rev: 0d28b963d91503c557adf87e096eb7a98dff6c76)
Signed-off-by: Pierre-Jean Texier <pjtexier@koncepto.io>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-extended/iptables/iptables_1.8.5.bb')
-rw-r--r-- | meta/recipes-extended/iptables/iptables_1.8.5.bb | 107 |
1 files changed, 107 insertions, 0 deletions
diff --git a/meta/recipes-extended/iptables/iptables_1.8.5.bb b/meta/recipes-extended/iptables/iptables_1.8.5.bb new file mode 100644 index 0000000000..fa1e5c229d --- /dev/null +++ b/meta/recipes-extended/iptables/iptables_1.8.5.bb | |||
@@ -0,0 +1,107 @@ | |||
1 | SUMMARY = "Tools for managing kernel packet filtering capabilities" | ||
2 | DESCRIPTION = "iptables is the userspace command line program used to configure and control network packet \ | ||
3 | filtering code in Linux." | ||
4 | HOMEPAGE = "http://www.netfilter.org/" | ||
5 | BUGTRACKER = "http://bugzilla.netfilter.org/" | ||
6 | LICENSE = "GPLv2+" | ||
7 | LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \ | ||
8 | file://iptables/iptables.c;beginline=13;endline=25;md5=c5cffd09974558cf27d0f763df2a12dc \ | ||
9 | " | ||
10 | |||
11 | SRC_URI = "http://netfilter.org/projects/iptables/files/iptables-${PV}.tar.bz2 \ | ||
12 | file://0001-configure-Add-option-to-enable-disable-libnfnetlink.patch \ | ||
13 | file://0002-configure.ac-only-check-conntrack-when-libnfnetlink-enabled.patch \ | ||
14 | file://iptables.service \ | ||
15 | file://iptables.rules \ | ||
16 | file://ip6tables.service \ | ||
17 | file://ip6tables.rules \ | ||
18 | " | ||
19 | SRC_URI[sha256sum] = "d457d74512e63aa3f50336e0597d4023c0e3c6845594d38532efb6ebcb294309" | ||
20 | |||
21 | SYSTEMD_SERVICE_${PN} = "\ | ||
22 | iptables.service \ | ||
23 | ${@bb.utils.contains('PACKAGECONFIG', 'ipv6', 'ip6tables.service', '', d)} \ | ||
24 | " | ||
25 | |||
26 | inherit autotools pkgconfig systemd | ||
27 | |||
28 | EXTRA_OECONF = "--with-kernel=${STAGING_INCDIR}" | ||
29 | |||
30 | PACKAGECONFIG ?= "${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)}" | ||
31 | PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6," | ||
32 | |||
33 | # libnfnetlink recipe is in meta-networking layer | ||
34 | PACKAGECONFIG[libnfnetlink] = "--enable-libnfnetlink,--disable-libnfnetlink,libnfnetlink libnetfilter-conntrack" | ||
35 | |||
36 | # libnftnl recipe is in meta-networking layer(previously known as libnftables) | ||
37 | PACKAGECONFIG[libnftnl] = "--enable-nftables,--disable-nftables,libnftnl" | ||
38 | |||
39 | do_configure_prepend() { | ||
40 | # Remove some libtool m4 files | ||
41 | # Keep ax_check_linker_flags.m4 which belongs to autoconf-archive. | ||
42 | rm -f libtool.m4 lt~obsolete.m4 ltoptions.m4 ltsugar.m4 ltversion.m4 | ||
43 | } | ||
44 | |||
45 | IPTABLES_RULES_DIR ?= "${sysconfdir}/${BPN}" | ||
46 | |||
47 | do_install_append() { | ||
48 | install -d ${D}${IPTABLES_RULES_DIR} | ||
49 | install -m 0644 ${WORKDIR}/iptables.rules ${D}${IPTABLES_RULES_DIR} | ||
50 | |||
51 | install -d ${D}${systemd_system_unitdir} | ||
52 | install -m 0644 ${WORKDIR}/iptables.service ${D}${systemd_system_unitdir} | ||
53 | |||
54 | sed -i \ | ||
55 | -e 's,@SBINDIR@,${sbindir},g' \ | ||
56 | -e 's,@RULESDIR@,${IPTABLES_RULES_DIR},g' \ | ||
57 | ${D}${systemd_system_unitdir}/iptables.service | ||
58 | |||
59 | if ${@bb.utils.contains('PACKAGECONFIG', 'ipv6', 'true', 'false', d)} ; then | ||
60 | install -m 0644 ${WORKDIR}/ip6tables.rules ${D}${IPTABLES_RULES_DIR} | ||
61 | install -m 0644 ${WORKDIR}/ip6tables.service ${D}${systemd_system_unitdir} | ||
62 | |||
63 | sed -i \ | ||
64 | -e 's,@SBINDIR@,${sbindir},g' \ | ||
65 | -e 's,@RULESDIR@,${IPTABLES_RULES_DIR},g' \ | ||
66 | ${D}${systemd_system_unitdir}/ip6tables.service | ||
67 | fi | ||
68 | } | ||
69 | |||
70 | PACKAGES += "${PN}-modules" | ||
71 | PACKAGES_DYNAMIC += "^${PN}-module-.*" | ||
72 | |||
73 | python populate_packages_prepend() { | ||
74 | modules = do_split_packages(d, '${libdir}/xtables', r'lib(.*)\.so$', '${PN}-module-%s', '${PN} module %s', extra_depends='') | ||
75 | if modules: | ||
76 | metapkg = d.getVar('PN') + '-modules' | ||
77 | d.appendVar('RDEPENDS_' + metapkg, ' ' + ' '.join(modules)) | ||
78 | } | ||
79 | |||
80 | RDEPENDS_${PN} = "${PN}-module-xt-standard" | ||
81 | RRECOMMENDS_${PN} = " \ | ||
82 | ${PN}-modules \ | ||
83 | kernel-module-x-tables \ | ||
84 | kernel-module-ip-tables \ | ||
85 | kernel-module-iptable-filter \ | ||
86 | kernel-module-iptable-nat \ | ||
87 | kernel-module-nf-defrag-ipv4 \ | ||
88 | kernel-module-nf-conntrack \ | ||
89 | kernel-module-nf-conntrack-ipv4 \ | ||
90 | kernel-module-nf-nat \ | ||
91 | kernel-module-ipt-masquerade \ | ||
92 | ${@bb.utils.contains('PACKAGECONFIG', 'ipv6', '\ | ||
93 | kernel-module-ip6table-filter \ | ||
94 | kernel-module-ip6-tables \ | ||
95 | ', '', d)} \ | ||
96 | " | ||
97 | |||
98 | FILES_${PN} += "${datadir}/xtables" | ||
99 | |||
100 | # Include the symlinks as well in respective packages | ||
101 | FILES_${PN}-module-xt-conntrack += "${libdir}/xtables/libxt_state.so" | ||
102 | FILES_${PN}-module-xt-ct += "${libdir}/xtables/libxt_NOTRACK.so" | ||
103 | |||
104 | ALLOW_EMPTY_${PN}-modules = "1" | ||
105 | |||
106 | INSANE_SKIP_${PN}-module-xt-conntrack = "dev-so" | ||
107 | INSANE_SKIP_${PN}-module-xt-ct = "dev-so" | ||