iptables: upgrade to ver. 1.4.14

(From OE-Core rev: 2afc6203baec508043d5ad672756b527f9d81111)

Signed-off-by: Cristian Iorga <cristian.iorga@intel.com>
Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 39 insertions, 0 deletions

diff --git a/meta/recipes-extended/iptables/iptables_1.4.14.bb b/meta/recipes-extended/iptables/iptables_1.4.14.bb
new file mode 100644
index 0000000000..4396ccf2d6
--- /dev/null
+++ b/meta/recipes-extended/iptables/iptables_1.4.14.bb
@@ -0,0 +1,39 @@
+SUMMARY = "Tools for managing kernel packaet filtering capabilities"
+DESCRIPTION = "iptables is the userspace command line program used to configure and control network packet \
+filtering code in Linux."
+HOMEPAGE = "http://www.netfilter.org/"
+BUGTRACKER = "http://bugzilla.netfilter.org/"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263\
+                    file://iptables/iptables.c;firstline=13;endline=25;md5=f1028f2401da1c120df27594b2be50ef"
+
+PR = "r0"
+
+RRECOMMENDS_${PN} = "kernel-module-x-tables \
+                     kernel-module-ip-tables \
+                     kernel-module-iptable-filter \
+                     kernel-module-iptable-nat \
+                     kernel-module-nf-defrag-ipv4 \
+                     kernel-module-nf-conntrack \
+                     kernel-module-nf-conntrack-ipv4 \
+                     kernel-module-nf-nat \
+                     kernel-module-ipt-masquerade"
+FILES_${PN} =+ "${libdir}/xtables/"
+FILES_${PN}-dbg =+ "${libdir}/xtables/.debug"
+
+SRC_URI = "http://netfilter.org/projects/iptables/files/iptables-${PV}.tar.bz2 \
+           file://types.h-add-defines-that-are-required-for-if_packet.patch"
+
+SRC_URI[md5sum] = "5ab24ad683f76689cfe7e0c73f44855d"
+SRC_URI[sha256sum] = "9be675696f41cd4f35cc332b667d285fe9489ca93c8e1f77804bd04b3315a522"
+
+inherit autotools
+
+EXTRA_OECONF = "--with-kernel=${STAGING_INCDIR} \
+                ${@base_contains('DISTRO_FEATURES', 'ipv6', '', '--disable-ipv6', d)}"
+
+do_configure_prepend() {
+        # Remove some libtool m4 files
+        # Keep ax_check_linker_flags.m4 which belongs to autoconf-archive.
+        rm -f libtool.m4 lt~obsolete.m4 ltoptions.m4 ltsugar.m4 ltversion.m4
+}