diff options
author | Hongxu Jia <hongxu.jia@windriver.com> | 2018-11-28 15:02:54 +0800 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2018-12-01 11:38:36 +0000 |
commit | 93db812f0c8a5612e95464d29f04f2e48e9879bc (patch) | |
tree | e0fc3cd466c3c4197beb4d02b5e437fe88f12b75 /meta/recipes-extended/ghostscript/ghostscript_9.26.bb | |
parent | 407138c7e59d1fe871cc563d57311e1223edd5c2 (diff) | |
download | poky-93db812f0c8a5612e95464d29f04f2e48e9879bc.tar.gz |
ghostscript: 9.25 -> 9.26
- Drop backported CVE fixes
000[1-8]*.patch
(From OE-Core rev: f30bd6bf01dbf81f0872382be44d507fb981f953)
Signed-off-by: Hongxu Jia <hongxu.jia@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-extended/ghostscript/ghostscript_9.26.bb')
-rw-r--r-- | meta/recipes-extended/ghostscript/ghostscript_9.26.bb | 125 |
1 files changed, 125 insertions, 0 deletions
diff --git a/meta/recipes-extended/ghostscript/ghostscript_9.26.bb b/meta/recipes-extended/ghostscript/ghostscript_9.26.bb new file mode 100644 index 0000000000..5ca978f86c --- /dev/null +++ b/meta/recipes-extended/ghostscript/ghostscript_9.26.bb | |||
@@ -0,0 +1,125 @@ | |||
1 | SUMMARY = "The GPL Ghostscript PostScript/PDF interpreter" | ||
2 | DESCRIPTION = "Ghostscript is used for PostScript/PDF preview and printing. Usually as \ | ||
3 | a back-end to a program such as ghostview, it can display PostScript and PDF \ | ||
4 | documents in an X11 environment. \ | ||
5 | \ | ||
6 | Furthermore, it can render PostScript and PDF files as graphics to be printed \ | ||
7 | on non-PostScript printers. Supported printers include common \ | ||
8 | dot-matrix, inkjet and laser models. \ | ||
9 | " | ||
10 | HOMEPAGE = "http://www.ghostscript.com" | ||
11 | SECTION = "console/utils" | ||
12 | |||
13 | LICENSE = "GPLv3" | ||
14 | LIC_FILES_CHKSUM = "file://LICENSE;md5=70dc2bac4d0ce4448da873cd86b123fc" | ||
15 | |||
16 | DEPENDS = "ghostscript-native tiff jpeg fontconfig cups libpng" | ||
17 | DEPENDS_class-native = "libpng-native" | ||
18 | |||
19 | UPSTREAM_CHECK_URI = "https://github.com/ArtifexSoftware/ghostpdl-downloads/releases" | ||
20 | UPSTREAM_CHECK_REGEX = "(?P<pver>\d+(\.\d+)+)\.tar" | ||
21 | |||
22 | SRC_URI_BASE = "https://github.com/ArtifexSoftware/ghostpdl-downloads/releases/download/gs926/${BPN}-${PV}.tar.gz \ | ||
23 | file://ghostscript-9.15-parallel-make.patch \ | ||
24 | file://ghostscript-9.16-Werror-return-type.patch \ | ||
25 | file://do-not-check-local-libpng-source.patch \ | ||
26 | file://avoid-host-contamination.patch \ | ||
27 | file://mkdir-p.patch \ | ||
28 | " | ||
29 | |||
30 | SRC_URI = "${SRC_URI_BASE} \ | ||
31 | file://ghostscript-9.21-prevent_recompiling.patch \ | ||
32 | file://ghostscript-9.02-genarch.patch \ | ||
33 | file://objarch.h \ | ||
34 | file://cups-no-gcrypt.patch \ | ||
35 | " | ||
36 | |||
37 | SRC_URI_class-native = "${SRC_URI_BASE} \ | ||
38 | file://ghostscript-9.21-native-fix-disable-system-libtiff.patch \ | ||
39 | file://base-genht.c-add-a-preprocessor-define-to-allow-fope.patch \ | ||
40 | " | ||
41 | |||
42 | SRC_URI[md5sum] = "806bc2dedbc7f69b003f536658e08d4a" | ||
43 | SRC_URI[sha256sum] = "831fc019bd477f7cc2d481dc5395ebfa4a593a95eb2fe1eb231a97e450d7540d" | ||
44 | |||
45 | # Put something like | ||
46 | # | ||
47 | # PACKAGECONFIG_append_pn-ghostscript = " x11" | ||
48 | # | ||
49 | # in local.conf to enable building with X11. Be careful. The order | ||
50 | # of the overrides matters! | ||
51 | # | ||
52 | #PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)}" | ||
53 | PACKAGECONFIG_class-native = "" | ||
54 | |||
55 | PACKAGECONFIG[x11] = "--with-x --x-includes=${STAGING_INCDIR} --x-libraries=${STAGING_LIBDIR}, \ | ||
56 | --without-x, virtual/libx11 libxext libxt gtk+3\ | ||
57 | " | ||
58 | |||
59 | EXTRA_OECONF = "--with-system-libtiff --without-jbig2dec \ | ||
60 | --with-fontpath=${datadir}/fonts \ | ||
61 | --without-libidn --with-cups-serverbin=${exec_prefix}/lib/cups \ | ||
62 | --with-cups-datadir=${datadir}/cups \ | ||
63 | CUPSCONFIG="${STAGING_BINDIR_CROSS}/cups-config" \ | ||
64 | " | ||
65 | |||
66 | EXTRA_OECONF_append_mipsarcho32 = " --with-large_color_index=0" | ||
67 | |||
68 | # Explicity disable libtiff, fontconfig, | ||
69 | # freetype, cups for ghostscript-native | ||
70 | EXTRA_OECONF_class-native = "--without-x --with-system-libtiff=no \ | ||
71 | --without-jbig2dec \ | ||
72 | --with-fontpath=${datadir}/fonts \ | ||
73 | --without-libidn --disable-fontconfig \ | ||
74 | --disable-freetype --disable-cups" | ||
75 | |||
76 | # This has been fixed upstream but for now we need to subvert the check for time.h | ||
77 | # http://bugs.ghostscript.com/show_bug.cgi?id=692443 | ||
78 | # http://bugs.ghostscript.com/show_bug.cgi?id=692426 | ||
79 | CFLAGS += "-DHAVE_SYS_TIME_H=1" | ||
80 | BUILD_CFLAGS += "-DHAVE_SYS_TIME_H=1" | ||
81 | |||
82 | inherit autotools | ||
83 | |||
84 | do_configure_prepend () { | ||
85 | mkdir -p obj | ||
86 | mkdir -p soobj | ||
87 | if [ -e ${WORKDIR}/objarch.h ]; then | ||
88 | cp ${WORKDIR}/objarch.h obj/arch.h | ||
89 | fi | ||
90 | } | ||
91 | |||
92 | do_configure_append () { | ||
93 | # copy tools from the native ghostscript build | ||
94 | if [ "${PN}" != "ghostscript-native" ]; then | ||
95 | mkdir -p obj/aux soobj | ||
96 | for i in genarch genconf mkromfs echogs gendev genht packps; do | ||
97 | cp ${STAGING_BINDIR_NATIVE}/ghostscript-${PV}/$i obj/aux/$i | ||
98 | done | ||
99 | fi | ||
100 | } | ||
101 | |||
102 | do_install_append () { | ||
103 | mkdir -p ${D}${datadir}/ghostscript/${PV}/ | ||
104 | cp -r ${S}/Resource ${D}${datadir}/ghostscript/${PV}/ | ||
105 | cp -r ${S}/iccprofiles ${D}${datadir}/ghostscript/${PV}/ | ||
106 | } | ||
107 | |||
108 | do_compile_class-native () { | ||
109 | mkdir -p obj | ||
110 | for i in genarch genconf mkromfs echogs gendev genht packps; do | ||
111 | oe_runmake obj/aux/$i | ||
112 | done | ||
113 | } | ||
114 | |||
115 | do_install_class-native () { | ||
116 | install -d ${D}${bindir}/ghostscript-${PV} | ||
117 | for i in genarch genconf mkromfs echogs gendev genht packps; do | ||
118 | install -m 755 obj/aux/$i ${D}${bindir}/ghostscript-${PV}/$i | ||
119 | done | ||
120 | } | ||
121 | |||
122 | BBCLASSEXTEND = "native" | ||
123 | |||
124 | # ghostscript does not supports "arc" | ||
125 | COMPATIBLE_HOST = "^(?!arc).*" | ||