diff options
author | Hongxu Jia <hongxu.jia@windriver.com> | 2014-06-17 19:03:02 +0800 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2014-06-17 17:56:21 +0100 |
commit | 24ca3ae7c68c76d8f1a132bb7442d47ff725227c (patch) | |
tree | 19ff860587a8b0b9700f43931bb3e7e52ae93514 /meta/recipes-extended/ghostscript/ghostscript_9.14.bb | |
parent | 1709ec7db747332777093bbb12901315d44b1798 (diff) | |
download | poky-24ca3ae7c68c76d8f1a132bb7442d47ff725227c.tar.gz |
ghostscript: upgrade to 9.14
- The LICENSE added AGPL for the font files (in Resource/Font);
- Rebase ghostscript-9.02-parallel-make.patch to 9.14
- Rebase ghostscript-native-fix-disable-system-libtiff.patch
since base/configure.ac has been moved to configure.ac.
http://git.ghostscript.com/?p=ghostpdl.git;a=commitdiff;h=f1488c5aff54f37ee67759827d4298592af5dbc8
- Obsolete ghostscript-9.05-NOT-check-endian.patch, and add option
'--enable-little-endian'/'--enable-big-endian' conditionally to
intead.
http://git.ghostscript.com/?p=ghostpdl.git;a=commitdiff;h=e76dc46756e89a14a3348bce12a633d32e4fa831
- Add base-genht.c-add-a-preprocessor-define-to-allow-fope.patch
for native, since the upstream replace all fopen calls with
gp_fopen and add a preprocessor define so that any unintential
calls directly to fopen will cause an error. This patch add a
preprocessor define to allow fopen calling in base/genht.c as
exceptions.
http://git.ghostscript.com/?p=ghostpdl.git;a=commitdiff;h=773c69e46e70bdd5482676437dafd2ca83397643
- Remove package ghostscript-cups, since CUPS filters
gstoraster and gstopxl has been moved to cups-filters
which is a free software package hosted by OpenPrinting.
http://git.ghostscript.com/?p=ghostpdl.git;a=commitdiff;h=9304a21699a6c17579fae32f44f5c92a37c13e2d
http://www.linuxfoundation.org/collaborate/workgroups/openprinting/cups-filters
(From OE-Core rev: 44ad25519b8e290f9a98b88eeec52ba199e76431)
Signed-off-by: Hongxu Jia <hongxu.jia@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-extended/ghostscript/ghostscript_9.14.bb')
-rw-r--r-- | meta/recipes-extended/ghostscript/ghostscript_9.14.bb | 104 |
1 files changed, 104 insertions, 0 deletions
diff --git a/meta/recipes-extended/ghostscript/ghostscript_9.14.bb b/meta/recipes-extended/ghostscript/ghostscript_9.14.bb new file mode 100644 index 0000000000..73cebbc86a --- /dev/null +++ b/meta/recipes-extended/ghostscript/ghostscript_9.14.bb | |||
@@ -0,0 +1,104 @@ | |||
1 | SUMMARY = "The GPL Ghostscript PostScript/PDF interpreter" | ||
2 | DESCRIPTION = "Ghostscript is used for PostScript/PDF preview and printing. Usually as \ | ||
3 | a back-end to a program such as ghostview, it can display PostScript and PDF \ | ||
4 | documents in an X11 environment. \ | ||
5 | \ | ||
6 | Furthermore, it can render PostScript and PDF files as graphics to be printed \ | ||
7 | on non-PostScript printers. Supported printers include common \ | ||
8 | dot-matrix, inkjet and laser models. \ | ||
9 | \ | ||
10 | Package gsfonts contains a set of standard fonts for Ghostscript. \ | ||
11 | " | ||
12 | HOMEPAGE = "http://www.ghostscript.com" | ||
13 | SECTION = "console/utils" | ||
14 | |||
15 | LICENSE = "GPLv3" | ||
16 | LIC_FILES_CHKSUM = "file://LICENSE;md5=aad21ea85123608e6a0a58d54ee23567" | ||
17 | |||
18 | DEPENDS = "ghostscript-native tiff jpeg fontconfig cups" | ||
19 | DEPENDS_class-native = "" | ||
20 | |||
21 | SRC_URI_BASE = "http://downloads.ghostscript.com/public/ghostscript-${PV}.tar.gz" | ||
22 | |||
23 | SRC_URI = "${SRC_URI_BASE} \ | ||
24 | file://ghostscript-9.02-prevent_recompiling.patch \ | ||
25 | file://ghostscript-9.02-genarch.patch \ | ||
26 | file://objarch.h \ | ||
27 | file://ghostscript-9.02-parallel-make.patch \ | ||
28 | " | ||
29 | |||
30 | SRC_URI_class-native = "${SRC_URI_BASE} \ | ||
31 | file://ghostscript-native-fix-disable-system-libtiff.patch \ | ||
32 | file://base-genht.c-add-a-preprocessor-define-to-allow-fope.patch \ | ||
33 | " | ||
34 | |||
35 | SRC_URI[md5sum] = "586494befb443363338c1b6379f13973" | ||
36 | SRC_URI[sha256sum] = "ab2ba5ce11c8db396c9acf774a497182d7686d04670976cc3e690ada7db9f0d4" | ||
37 | |||
38 | EXTRA_OECONF = "--without-x --with-system-libtiff --without-jbig2dec \ | ||
39 | --with-fontpath=${datadir}/fonts \ | ||
40 | --without-libidn --with-cups-serverbin=${exec_prefix}/lib/cups \ | ||
41 | --with-cups-datadir=${datadir}/cups \ | ||
42 | ${@base_conditional('SITEINFO_ENDIANNESS', 'le', '--enable-little-endian', '--enable-big-endian', d)} \ | ||
43 | " | ||
44 | |||
45 | # Explicity disable libtiff, fontconfig, | ||
46 | # freetype, cups for ghostscript-native | ||
47 | EXTRA_OECONF_class-native = "--without-x --with-system-libtiff=no \ | ||
48 | --without-jbig2dec \ | ||
49 | --with-fontpath=${datadir}/fonts \ | ||
50 | --without-libidn --disable-fontconfig \ | ||
51 | --disable-freetype --disable-cups" | ||
52 | |||
53 | # This has been fixed upstream but for now we need to subvert the check for time.h | ||
54 | # http://bugs.ghostscript.com/show_bug.cgi?id=692443 | ||
55 | # http://bugs.ghostscript.com/show_bug.cgi?id=692426 | ||
56 | CFLAGS += "-DHAVE_SYS_TIME_H=1" | ||
57 | BUILD_CFLAGS += "-DHAVE_SYS_TIME_H=1" | ||
58 | |||
59 | inherit autotools-brokensep | ||
60 | |||
61 | do_configure_prepend () { | ||
62 | mkdir -p obj | ||
63 | mkdir -p soobj | ||
64 | if [ -e ${WORKDIR}/objarch.h ]; then | ||
65 | cp ${WORKDIR}/objarch.h obj/arch.h | ||
66 | fi | ||
67 | } | ||
68 | |||
69 | do_configure_append () { | ||
70 | # copy tools from the native ghostscript build | ||
71 | if [ "${PN}" != "ghostscript-native" ]; then | ||
72 | mkdir -p obj/aux soobj | ||
73 | for i in genarch genconf mkromfs echogs gendev genht; do | ||
74 | cp ${STAGING_BINDIR_NATIVE}/ghostscript-${PV}/$i obj/aux/$i | ||
75 | done | ||
76 | fi | ||
77 | } | ||
78 | |||
79 | do_install_append () { | ||
80 | mkdir -p ${D}${datadir}/ghostscript/${PV}/ | ||
81 | cp -r Resource ${D}${datadir}/ghostscript/${PV}/ | ||
82 | cp -r iccprofiles ${D}${datadir}/ghostscript/${PV}/ | ||
83 | } | ||
84 | |||
85 | do_compile_class-native () { | ||
86 | mkdir -p obj | ||
87 | for i in genarch genconf mkromfs echogs gendev genht; do | ||
88 | oe_runmake obj/aux/$i | ||
89 | done | ||
90 | } | ||
91 | |||
92 | do_install_class-native () { | ||
93 | install -d ${D}${bindir}/ghostscript-${PV} | ||
94 | for i in genarch genconf mkromfs echogs gendev genht; do | ||
95 | install -m 755 obj/aux/$i ${D}${bindir}/ghostscript-${PV}/$i | ||
96 | done | ||
97 | } | ||
98 | |||
99 | BBCLASSEXTEND = "native" | ||
100 | |||
101 | # Ghostscript install tool 'instcopy' tries to remove already created | ||
102 | # directories during install and parallel make causes problems. | ||
103 | PARALLEL_MAKEINST="" | ||
104 | |||