diff options
author | Jonathan Liu <net147@gmail.com> | 2013-07-30 00:15:14 +1000 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2013-07-31 06:59:55 +0100 |
commit | 4b49ae13076f14eada447ad21022967d090941cd (patch) | |
tree | 22a59ab940ab19c4ae7e823efbf05036417ad68a /meta/recipes-devtools/syslinux/syslinux_4.07.bb | |
parent | 7b1fc1770fa6c680ccc94894a0d78304d95bd852 (diff) | |
download | poky-4b49ae13076f14eada447ad21022967d090941cd.tar.gz |
syslinux: update to 4.07
(From OE-Core rev: 1352eaa655cdf9887194ecc9d14194ab1b50a1b8)
Signed-off-by: Jonathan Liu <net147@gmail.com>
Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-devtools/syslinux/syslinux_4.07.bb')
-rw-r--r-- | meta/recipes-devtools/syslinux/syslinux_4.07.bb | 62 |
1 files changed, 62 insertions, 0 deletions
diff --git a/meta/recipes-devtools/syslinux/syslinux_4.07.bb b/meta/recipes-devtools/syslinux/syslinux_4.07.bb new file mode 100644 index 0000000000..bba5dda584 --- /dev/null +++ b/meta/recipes-devtools/syslinux/syslinux_4.07.bb | |||
@@ -0,0 +1,62 @@ | |||
1 | DESCRIPTION = "A multi-purpose linux bootloader" | ||
2 | HOMEPAGE = "http://syslinux.zytor.com/" | ||
3 | LICENSE = "GPLv2+" | ||
4 | LIC_FILES_CHKSUM = "file://COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \ | ||
5 | file://README;beginline=35;endline=41;md5=f7249a750bc692d1048b2626752aa415" | ||
6 | |||
7 | # If you really want to run syslinux, you need mtools. We just want the | ||
8 | # ldlinux.* stuff for now, so skip mtools-native | ||
9 | DEPENDS = "nasm-native util-linux" | ||
10 | PR = "r0" | ||
11 | |||
12 | SRC_URI = "${KERNELORG_MIRROR}/linux/utils/boot/syslinux/4.xx/syslinux-${PV}.tar.bz2" | ||
13 | |||
14 | SRC_URI[md5sum] = "9ff6e1b94efab931fb4717b600d88779" | ||
15 | SRC_URI[sha256sum] = "1240a4e4219b518bdaef78931b6e901befeff35e6894ac6db785115848a7a05a" | ||
16 | |||
17 | COMPATIBLE_HOST = '(x86_64|i.86).*-(linux|freebsd.*)' | ||
18 | |||
19 | EXTRA_OEMAKE = " \ | ||
20 | BINDIR=${bindir} SBINDIR=${sbindir} LIBDIR=${libdir} \ | ||
21 | DATADIR=${datadir} MANDIR=${mandir} INCDIR=${includedir} \ | ||
22 | " | ||
23 | # syslinux uses $LD for linking, strip `-Wl,' so it can work | ||
24 | export LDFLAGS = "`echo $LDFLAGS | sed 's/-Wl,//g'`" | ||
25 | |||
26 | do_configure() { | ||
27 | # drop win32 targets or build fails | ||
28 | sed -e 's,win32/\S*,,g' -i Makefile | ||
29 | |||
30 | # clean installer executables included in source tarball | ||
31 | oe_runmake clean | ||
32 | } | ||
33 | |||
34 | do_compile() { | ||
35 | # Rebuild only the installer; keep precompiled bootloaders | ||
36 | # as per author's request (doc/distrib.txt) | ||
37 | oe_runmake CC="${CC} ${CFLAGS}" LDFLAGS="${LDFLAGS}" installer | ||
38 | } | ||
39 | |||
40 | do_install() { | ||
41 | oe_runmake install INSTALLROOT="${D}" | ||
42 | |||
43 | install -d ${D}${datadir}/syslinux/ | ||
44 | install -m 644 ${S}/core/ldlinux.sys ${D}${datadir}/syslinux/ | ||
45 | install -m 644 ${S}/core/ldlinux.bss ${D}${datadir}/syslinux/ | ||
46 | } | ||
47 | |||
48 | PACKAGES += "${PN}-extlinux ${PN}-mbr ${PN}-chain ${PN}-pxelinux ${PN}-isolinux ${PN}-misc" | ||
49 | |||
50 | RDEPENDS_${PN} += "mtools" | ||
51 | |||
52 | FILES_${PN} = "${bindir}/syslinux" | ||
53 | FILES_${PN}-extlinux = "${sbindir}/extlinux" | ||
54 | FILES_${PN}-mbr = "${datadir}/${BPN}/mbr.bin" | ||
55 | FILES_${PN}-chain = "${datadir}/${BPN}/chain.c32" | ||
56 | FILES_${PN}-isolinux = "${datadir}/${BPN}/isolinux.bin" | ||
57 | FILES_${PN}-pxelinux = "${datadir}/${BPN}/pxelinux.0" | ||
58 | FILES_${PN}-dev += "${datadir}/${BPN}/com32/lib*${SOLIBS} ${datadir}/${BPN}/com32/include ${datadir}/${BPN}/com32/com32.ld" | ||
59 | FILES_${PN}-staticdev += "${datadir}/${BPN}/com32/lib*.a ${libdir}/${BPN}/com32/lib*.a" | ||
60 | FILES_${PN}-misc = "${datadir}/${BPN}/* ${libdir}/${BPN}/* ${bindir}/*" | ||
61 | |||
62 | BBCLASSEXTEND = "native" | ||