strace: Upgrade to 4.9

Remove two backported patches:
0001-Work-around-conflict-between-sys-ptrace.h-and-linux-.patch
strace-fix-64-bit-process-detection.patch

Update two patches to fit new version:
Makefile-ptest.patch
strace-add-configure-options.patch

Add coreutils, grep and gawk to RDEPENDS_${PN}-ptest for making
ptest pass.

(From OE-Core rev: 826e36643a3fcb8b4ee4ed79612c63c3a9cc1536)

Signed-off-by: Chong Lu <Chong.Lu@windriver.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/meta/recipes-devtools/strace/strace_4.9.bb b/meta/recipes-devtools/strace/strace_4.9.bb
new file mode 100644
index 0000000000..f64c6ecac4
--- /dev/null
+++ b/meta/recipes-devtools/strace/strace_4.9.bb
@@ -0,0 +1,46 @@
+SUMMARY = "System call tracing tool"
+HOMEPAGE = "http://strace.sourceforge.net"
+SECTION = "console/utils"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://COPYING;md5=124500c21e856f0912df29295ba104c7"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/strace/strace-${PV}.tar.xz \
+           file://git-version-gen \
+           file://strace-add-configure-options.patch \
+           file://Makefile-ptest.patch \
+           file://run-ptest \
+          "
+
+SRC_URI[md5sum] = "885eafadb10f6c60464a266d3929a2a4"
+SRC_URI[sha256sum] = "095bfea5c540b91d297ccac73b21b92fd54a24599fd70395db87ff9eb7fd6f65"
+
+inherit autotools ptest
+RDEPENDS_${PN}-ptest += "make coreutils grep gawk"
+
+PACKAGECONFIG_class-target ?= "libaio ${@bb.utils.contains('DISTRO_FEATURES', 'acl', 'acl', '', d)}"
+
+PACKAGECONFIG[libaio] = "--enable-aio,--disable-aio,libaio"
+PACKAGECONFIG[acl] = "--enable-acl,--disable-acl,acl"
+
+export INCLUDES = "-I. -I./linux"
+
+TESTDIR = "tests"
+
+do_configure_prepend() {
+        cp ${WORKDIR}/git-version-gen ${S}
+}
+
+do_install_append() {
+        # We don't ship strace-graph here because it needs perl
+        rm ${D}${bindir}/strace-graph
+}
+
+do_compile_ptest() {
+        oe_runmake -C ${TESTDIR} buildtest-TESTS
+}
+
+do_install_ptest() {
+        oe_runmake -C ${TESTDIR} install-ptest BUILDDIR=${B} DESTDIR=${D}${PTEST_PATH} TESTDIR=${TESTDIR}
+}
+
+BBCLASSEXTEND = "native"