python: upgrade from 2.7.2 to 2.7.3

bin/python2 link is provided by the python install process,
so no need to create it.

rebase these patches to the newer code:
 fix_for_using_different_libdir.patch
 04-default-is-optimized.patch
remove this patch as it is upstream now:
 sys_platform_is_now_always_linux2.patch

Change default python version to 2.7.3 in the distro config

(From OE-Core rev: 5d92a95ea9b480235b7c9ca5949a681376eba725)

Signed-off-by: Nitin A Kamble <nitin.a.kamble@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 0 insertions, 170 deletions

diff --git a/meta/recipes-devtools/python/python_2.7.2.bb b/meta/recipes-devtools/python/python_2.7.2.bb
deleted file mode 100644
index bd5c1ffde8..0000000000
--- a/meta/recipes-devtools/python/python_2.7.2.bb
+++ /dev/null
@@ -1,170 +0,0 @@
-require python.inc
-DEPENDS = "python-native bzip2 db gdbm openssl readline sqlite3 zlib"
-PR = "${INC_PR}.20"
-
-DISTRO_SRC_URI ?= "file://sitecustomize.py"
-DISTRO_SRC_URI_linuxstdbase = ""
-SRC_URI += "\
-  file://01-use-proper-tools-for-cross-build.patch \
-  file://03-fix-tkinter-detection.patch \
-  file://04-default-is-optimized.patch \
-  file://05-enable-ctypes-cross-build.patch \
-  file://06-ctypes-libffi-fix-configure.patch \
-  file://06-avoid_usr_lib_termcap_path_in_linking.patch \
-  file://99-ignore-optimization-flag.patch \
-  ${DISTRO_SRC_URI} \
-  file://multilib.patch \
-  file://cgi_py.patch \
-  file://remove_sqlite_rpath.patch \
-  file://setup_py_skip_cross_import_check.patch \
-  file://add-md5module-support.patch \
-  file://host_include_contamination.patch \
-  file://sys_platform_is_now_always_linux2.patch \
-  file://fix_for_using_different_libdir.patch \
-  file://setuptweaks.patch \
-  file://check-if-target-is-64b-not-host.patch \
-  file://search_db_h_in_inc_dirs_and_avoid_warning.patch \
-  file://avoid_warning_about_bsddb.patch \
-  file://avoid_warning_about_tkinter.patch \
-  file://avoid_warning_for_sunos_specific_module.patch \
-"
-
-S = "${WORKDIR}/Python-${PV}"
-
-inherit autotools multilib_header
-
-# The 3 lines below are copied from the libffi recipe, ctypes ships its own copy of the libffi sources
-#Somehow gcc doesn't set __SOFTFP__ when passing -mfloatabi=softp :(
-TARGET_CC_ARCH_append_armv6 = " -D__SOFTFP__"
-TARGET_CC_ARCH_append_armv7a = " -D__SOFTFP__"
-
-do_configure_prepend() {
-        rm -f ${S}/Makefile.orig
-        autoreconf -Wcross --verbose --install --force --exclude=autopoint Modules/_ctypes/libffi || bbnote "_ctypes failed to autoreconf"
-}
-
-do_compile() {
-        # regenerate platform specific files, because they depend on system headers
-        cd Lib/plat-linux2
-        include=${STAGING_INCDIR} ${STAGING_BINDIR_NATIVE}/python \
-                ${S}/Tools/scripts/h2py.py -i '(u_long)' \
-                ${STAGING_INCDIR}/dlfcn.h \
-                ${STAGING_INCDIR}/linux/cdrom.h \
-                ${STAGING_INCDIR}/netinet/in.h \
-                ${STAGING_INCDIR}/sys/types.h
-        sed -e 's,${STAGING_DIR_HOST},,g' -i *.py
-        cd -
-
-        #
-        # Copy config.h and an appropriate Makefile for distutils.sysconfig,
-        # which laters uses the information out of these to compile extensions
-        #
-        # The following part (until python compilation) should probably moved to an
-        # -initial recipe to handle staging better
-        #
-        install -d ${STAGING_INCDIR}/python${PYTHON_MAJMIN}/
-        install -d ${STAGING_LIBDIR}/python${PYTHON_MAJMIN}/config/
-        install -m 0644 pyconfig.h ${STAGING_INCDIR}/python${PYTHON_MAJMIN}/
-
-        # remove hardcoded ccache, see http://bugs.openembedded.net/show_bug.cgi?id=4144
-        sed -i -e s,ccache,'$(CCACHE)', Makefile
-
-        # remove any bogus LD_LIBRARY_PATH
-        sed -i -e s,RUNSHARED=.*,RUNSHARED=, Makefile
-
-        if [ ! -f Makefile.orig ]; then
-                install -m 0644 Makefile Makefile.orig
-        fi
-        sed -i -e 's,^LDFLAGS=.*,LDFLAGS=-L. -L${STAGING_LIBDIR},g' \
-                -e 's,libdir=${libdir},libdir=${STAGING_LIBDIR},g' \
-                -e 's,libexecdir=${libexecdir},libexecdir=${STAGING_DIR_HOST}${libexecdir},g' \
-                -e 's,^LIBDIR=.*,LIBDIR=${STAGING_LIBDIR},g' \
-                -e 's,includedir=${includedir},includedir=${STAGING_INCDIR},g' \
-                -e 's,^INCLUDEDIR=.*,INCLUDE=${STAGING_INCDIR},g' \
-                -e 's,^CONFINCLUDEDIR=.*,CONFINCLUDE=${STAGING_INCDIR},g' \
-                Makefile
-        install -m 0644 Makefile ${STAGING_LIBDIR}/python${PYTHON_MAJMIN}/config/
-        # save copy of it now, because if we do it in do_install and 
-        # then call do_install twice we get Makefile.orig == Makefile.sysroot
-        install -m 0644 Makefile Makefile.sysroot
-
-        export CROSS_COMPILE="${TARGET_PREFIX}"
-
-        oe_runmake HOSTPGEN=${STAGING_BINDIR_NATIVE}/pgen \
-                HOSTPYTHON=${STAGING_BINDIR_NATIVE}/python \
-                STAGING_LIBDIR=${STAGING_LIBDIR} \
-                STAGING_BASELIBDIR=${STAGING_BASELIBDIR} \
-                STAGING_INCDIR=${STAGING_INCDIR} \
-                BUILD_SYS=${BUILD_SYS} HOST_SYS=${HOST_SYS} \
-                OPT="${CFLAGS}" libpython${PYTHON_MAJMIN}.so
-
-        oe_libinstall -so libpython${PYTHON_MAJMIN} ${STAGING_LIBDIR}
-
-        oe_runmake HOSTPGEN=${STAGING_BINDIR_NATIVE}/pgen \
-                HOSTPYTHON=${STAGING_BINDIR_NATIVE}/python \
-                STAGING_LIBDIR=${STAGING_LIBDIR} \
-                STAGING_INCDIR=${STAGING_INCDIR} \
-                STAGING_BASELIBDIR=${STAGING_BASELIBDIR} \
-                BUILD_SYS=${BUILD_SYS} HOST_SYS=${HOST_SYS} \
-                OPT="${CFLAGS}"
-}
-
-do_install() {
-        # make install needs the original Makefile, or otherwise the inclues would
-        # go to ${D}${STAGING...}/...
-        install -m 0644 Makefile.orig Makefile
-
-        export CROSS_COMPILE="${TARGET_PREFIX}"
-        
-        oe_runmake HOSTPGEN=${STAGING_BINDIR_NATIVE}/pgen \
-                HOSTPYTHON=${STAGING_BINDIR_NATIVE}/python \
-                CROSSPYTHONPATH=${STAGING_LIBDIR_NATIVE}/python${PYTHON_MAJMIN}/lib-dynload/ \
-                STAGING_LIBDIR=${STAGING_LIBDIR} \
-                STAGING_INCDIR=${STAGING_INCDIR} \
-                STAGING_BASELIBDIR=${STAGING_BASELIBDIR} \
-                BUILD_SYS=${BUILD_SYS} HOST_SYS=${HOST_SYS} \
-                DESTDIR=${D} LIBDIR=${libdir} install
-
-        install -m 0644 Makefile.sysroot ${D}/${libdir}/python${PYTHON_MAJMIN}/config/Makefile
-
-        if [ -e ${WORKDIR}/sitecustomize.py ]; then
-                install -m 0644 ${WORKDIR}/sitecustomize.py ${D}/${libdir}/python${PYTHON_MAJMIN}
-        fi
-
-        oe_multilib_header python${PYTHON_MAJMIN}/pyconfig.h
-}
-
-SSTATE_SCAN_FILES += "Makefile"
-PACKAGE_PREPROCESS_FUNCS += "py_package_preprocess"
-
-py_package_preprocess () {
-        # copy back the old Makefile to fix target package
-        install -m 0644 Makefile.orig ${PKGD}/${libdir}/python${PYTHON_MAJMIN}/config/Makefile
-}
-
-require python-${PYTHON_MAJMIN}-manifest.inc
-
-# manual dependency additions
-RPROVIDES_${PN}-core = "${PN}"
-RRECOMMENDS_${PN}-core = "${PN}-readline"
-RRECOMMENDS_${PN}-crypt = "openssl"
-
-# package libpython2
-PACKAGES =+ "lib${BPN}2${PKGSUFFIX}"
-FILES_lib${BPN}2${PKGSUFFIX} = "${libdir}/libpython*.so.*"
-
-# catch debug extensions (isn't that already in python-core-dbg?)
-FILES_${PN}-dbg += "${libdir}/python${PYTHON_MAJMIN}/lib-dynload/.debug"
-
-# catch all the rest (unsorted)
-PACKAGES += "${PN}-misc"
-FILES_${PN}-misc = "${libdir}/python${PYTHON_MAJMIN}"
-
-# catch manpage
-PACKAGES += "${PN}-man"
-FILES_${PN}-man = "${datadir}/man"
-
-BBCLASSEXTEND = "nativesdk"
-
-PKGSUFFIX = ""
-PKGSUFFIX_virtclass-nativesdk = "-nativesdk"