python3-hypothesis: revert back to 6.46.11

This package was broken since it was upgraded to 6.48, because
it started using 'exceptiongroup' since then, which is missing
in any meta layer. On target, when importing hypothesis, we meet
the following error:

  Traceback (most recent call last):
  File "/usr/lib64/python3.10/site-packages/hypothesis/internal/compat.py", line 18, in <module>
  BaseExceptionGroup = BaseExceptionGroup
  NameError: name 'BaseExceptionGroup' is not defined. Did you mean: 'BaseException'?
  ModuleNotFoundError: No module named 'exceptiongroup'

The related codes as below:
try:
    BaseExceptionGroup = BaseExceptionGroup
    ExceptionGroup = ExceptionGroup  # pragma: no cover
except NameError:
    from exceptiongroup import (
        BaseExceptionGroup as BaseExceptionGroup,
        ExceptionGroup as ExceptionGroup,
    )

We can see that it tries to use ExceptionGroup and falls back to
use an import from exceptiongroup module.

Looking at the https://github.com/agronholm/exceptiongroup, it says:
"""
This is a backport of the BaseExceptionGroup and ExceptionGroup classes from Python 3.11.
"""

So instead of adding a new recipe for exception group, it might be
better to revert to a working version and wait for python 3.11 to release.

(From OE-Core rev: 37c5b171d7de25b131e77b80d37f8481308bd6fe)

Signed-off-by: Chen Qi <Qi.Chen@windriver.com>
Signed-off-by: Luca Ceresoli <luca.ceresoli@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 38 insertions, 0 deletions

diff --git a/meta/recipes-devtools/python/python3-hypothesis_6.46.11.bb b/meta/recipes-devtools/python/python3-hypothesis_6.46.11.bb
new file mode 100644
index 0000000000..1d9772d4ff
--- /dev/null
+++ b/meta/recipes-devtools/python/python3-hypothesis_6.46.11.bb
@@ -0,0 +1,38 @@
+SUMMARY = "A library for property-based testing"
+HOMEPAGE = "https://github.com/HypothesisWorks/hypothesis/tree/master/hypothesis-python"
+LICENSE = "MPL-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=4ee62c16ebd0f4f99d906f36b7de8c3c"
+
+PYPI_PACKAGE = "hypothesis"
+
+inherit pypi setuptools3 ptest
+
+SRC_URI += " \
+    file://run-ptest \
+    file://test_binary_search.py \
+    file://test_rle.py \
+    "
+
+SRC_URI[sha256sum] = "f5c1cf61b24b094355577a6b8fbbb8eb54c1b0216fbc0519af97c46bddf43c42"
+
+RDEPENDS:${PN} += " \
+    python3-attrs \
+    python3-compression \
+    python3-core \
+    python3-json \
+    python3-sortedcontainers \
+    python3-statistics \
+    python3-unittest \
+    "
+
+RDEPENDS:${PN}-ptest += " \
+    ${PYTHON_PN}-pytest \
+    "
+
+do_install_ptest() {
+    install -d ${D}${PTEST_PATH}/examples
+    install -m 0755 ${WORKDIR}/test_binary_search.py ${D}${PTEST_PATH}/examples/
+    install -m 0755 ${WORKDIR}/test_rle.py ${D}${PTEST_PATH}/examples/
+}
+
+BBCLASSEXTEND = "native nativesdk"