diff options
author | Ross Burton <ross.burton@intel.com> | 2019-07-17 21:54:32 +0100 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2019-07-18 12:16:19 +0100 |
commit | d64c2ad24d9e2972db23561df3c22adbb613c2a3 (patch) | |
tree | c31361cf2bc868bd5241e7017526b41f1171b6d5 /meta/recipes-devtools/pkgconf/pkgconf_1.6.3.bb | |
parent | 1a2f9898f68dc6467b207f3a55a245c146c0b3b6 (diff) | |
download | poky-d64c2ad24d9e2972db23561df3c22adbb613c2a3.tar.gz |
pkgconf: upgrade 1.6.1 -> 1.6.3
(From OE-Core rev: 4a69bf5ae3328d124a7607a52333643ebf7ec0b3)
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-devtools/pkgconf/pkgconf_1.6.3.bb')
-rw-r--r-- | meta/recipes-devtools/pkgconf/pkgconf_1.6.3.bb | 69 |
1 files changed, 69 insertions, 0 deletions
diff --git a/meta/recipes-devtools/pkgconf/pkgconf_1.6.3.bb b/meta/recipes-devtools/pkgconf/pkgconf_1.6.3.bb new file mode 100644 index 0000000000..94bc112b9f --- /dev/null +++ b/meta/recipes-devtools/pkgconf/pkgconf_1.6.3.bb | |||
@@ -0,0 +1,69 @@ | |||
1 | SUMMARY = "pkgconf provides compiler and linker configuration for development frameworks." | ||
2 | DESCRIPTION = "pkgconf is a program which helps to configure compiler and linker \ | ||
3 | flags for development frameworks. It is similar to pkg-config from \ | ||
4 | freedesktop.org, providing additional functionality while also maintaining \ | ||
5 | compatibility." | ||
6 | HOMEPAGE = "http://pkgconf.org" | ||
7 | BUGTRACKER = "https://github.com/pkgconf/pkgconf/issues" | ||
8 | SECTION = "devel" | ||
9 | PROVIDES += "pkgconfig" | ||
10 | RPROVIDES_${PN} += "pkgconfig" | ||
11 | DEFAULT_PREFERENCE = "-1" | ||
12 | |||
13 | # The pkgconf license seems to be functionally equivalent to BSD-2-Clause or | ||
14 | # ISC, but has different wording, so needs its own name. | ||
15 | LICENSE = "pkgconf" | ||
16 | LIC_FILES_CHKSUM = "file://COPYING;md5=2214222ec1a820bd6cc75167a56925e0" | ||
17 | |||
18 | SRC_URI = "\ | ||
19 | https://distfiles.dereferenced.org/pkgconf/pkgconf-${PV}.tar.xz \ | ||
20 | file://pkg-config-wrapper \ | ||
21 | file://pkg-config-native.in \ | ||
22 | file://pkg-config-esdk.in \ | ||
23 | " | ||
24 | SRC_URI[md5sum] = "f93fb1be95a5cb62e43c219c82b5791a" | ||
25 | SRC_URI[sha256sum] = "61f0b31b0d5ea0e862b454a80c170f57bad47879c0c42bd8de89200ff62ea210" | ||
26 | |||
27 | inherit autotools | ||
28 | |||
29 | EXTRA_OECONF += "--with-pkg-config-dir='${libdir}/pkgconfig:${datadir}/pkgconfig'" | ||
30 | |||
31 | do_install_append () { | ||
32 | # Install a wrapper which deals, as much as possible with pkgconf vs | ||
33 | # pkg-config compatibility issues. | ||
34 | install -m 0755 "${WORKDIR}/pkg-config-wrapper" "${D}${bindir}/pkg-config" | ||
35 | } | ||
36 | |||
37 | do_install_append_class-native () { | ||
38 | # Install a pkg-config-native wrapper that will use the native sysroot instead | ||
39 | # of the MACHINE sysroot, for using pkg-config when building native tools. | ||
40 | sed -e "s|@PATH_NATIVE@|${PKG_CONFIG_PATH}|" \ | ||
41 | < ${WORKDIR}/pkg-config-native.in > ${B}/pkg-config-native | ||
42 | install -m755 ${B}/pkg-config-native ${D}${bindir}/pkg-config-native | ||
43 | sed -e "s|@PATH_NATIVE@|${PKG_CONFIG_PATH}|" \ | ||
44 | -e "s|@LIBDIR_NATIVE@|${PKG_CONFIG_LIBDIR}|" \ | ||
45 | < ${WORKDIR}/pkg-config-esdk.in > ${B}/pkg-config-esdk | ||
46 | install -m755 ${B}/pkg-config-esdk ${D}${bindir}/pkg-config-esdk | ||
47 | } | ||
48 | |||
49 | # When using the RPM generated automatic package dependencies, some packages | ||
50 | # will end up requiring 'pkgconfig(pkg-config)'. Allow this behavior by | ||
51 | # specifying an appropriate provide. | ||
52 | RPROVIDES_${PN} += "pkgconfig(pkg-config)" | ||
53 | |||
54 | # Include pkg.m4 in the main package, leaving libpkgconf dev files in -dev | ||
55 | FILES_${PN}-dev_remove = "${datadir}/aclocal" | ||
56 | FILES_${PN} += "${datadir}/aclocal" | ||
57 | |||
58 | BBCLASSEXTEND += "native nativesdk" | ||
59 | |||
60 | pkgconf_sstate_fixup_esdk () { | ||
61 | if [ "${BB_CURRENTTASK}" = "populate_sysroot_setscene" -a "${WITHIN_EXT_SDK}" = "1" ] ; then | ||
62 | pkgconfdir="${SSTATE_INSTDIR}/recipe-sysroot-native/${bindir_native}" | ||
63 | mv $pkgconfdir/pkg-config $pkgconfdir/pkg-config.real | ||
64 | lnr $pkgconfdir/pkg-config-esdk $pkgconfdir/pkg-config | ||
65 | sed -i -e "s|^pkg-config|pkg-config.real|" $pkgconfdir/pkg-config-native | ||
66 | fi | ||
67 | } | ||
68 | |||
69 | SSTATEPOSTUNPACKFUNCS_append_class-native = " pkgconf_sstate_fixup_esdk" | ||