opkg-arch-config: Renamed from opkg-config-base

The name 'opkg-arch-config' is much more descriptive.

(From OE-Core rev: d0cb4fb3aab1d6041f88fa564e5d745629316ae2)

Signed-off-by: Paul Barker <paul@paulbarker.me.uk>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 33 insertions, 0 deletions

diff --git a/meta/recipes-devtools/opkg/opkg-arch-config_1.0.bb b/meta/recipes-devtools/opkg/opkg-arch-config_1.0.bb
new file mode 100644
index 0000000000..4540de2daf
--- /dev/null
+++ b/meta/recipes-devtools/opkg/opkg-arch-config_1.0.bb
@@ -0,0 +1,33 @@
+SUMMARY = "Architecture-dependent configuration for opkg"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+PR = "r1"
+
+do_compile() {
+        mkdir -p ${S}/${sysconfdir}/opkg/
+
+        archconf=${S}/${sysconfdir}/opkg/arch.conf
+
+        rm -f $archconf
+        ipkgarchs="${ALL_MULTILIB_PACKAGE_ARCHS}"
+        priority=1
+        for arch in $ipkgarchs; do 
+                echo "arch $arch $priority" >> $archconf
+                priority=$(expr $priority + 5)
+        done
+}
+
+
+do_install () {
+        install -d ${D}${sysconfdir}/opkg
+        install -m 0644  ${S}/${sysconfdir}/opkg/* ${D}${sysconfdir}/opkg/
+}
+
+FILES_${PN} = "${sysconfdir}/opkg/ "
+
+CONFFILES_${PN} += "${sysconfdir}/opkg/arch.conf"
+
+RREPLACES_${PN} = "opkg-config-base"
+RCONFLICTS_${PN} = "opkg-config-base"
+RPROVIDES_${PN} = "opkg-config-base"