diff options
author | Alejandro del Castillo <alejandro.delcastillo@ni.com> | 2017-06-16 14:48:27 -0500 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2017-06-28 15:52:18 +0100 |
commit | f1cf60006b8a798b30d5fcbbe6aaf3b713c40d59 (patch) | |
tree | a8148d31ba54c2ec1ebee962998c08a7c047e15f /meta/recipes-devtools/opkg-utils/opkg-utils_0.3.5.bb | |
parent | 4926943b722278bf84b04a4281f5e23cd6bfbfd2 (diff) | |
download | poky-f1cf60006b8a798b30d5fcbbe6aaf3b713c40d59.tar.gz |
opkg-utils: rename recipe to follow versioned releases
(From OE-Core rev: bd259bad336d9deb7b74b633c304f8c18fc84e71)
Signed-off-by: Alejandro del Castillo <alejandro.delcastillo@ni.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-devtools/opkg-utils/opkg-utils_0.3.5.bb')
-rw-r--r-- | meta/recipes-devtools/opkg-utils/opkg-utils_0.3.5.bb | 62 |
1 files changed, 62 insertions, 0 deletions
diff --git a/meta/recipes-devtools/opkg-utils/opkg-utils_0.3.5.bb b/meta/recipes-devtools/opkg-utils/opkg-utils_0.3.5.bb new file mode 100644 index 0000000000..646cc8ff9a --- /dev/null +++ b/meta/recipes-devtools/opkg-utils/opkg-utils_0.3.5.bb | |||
@@ -0,0 +1,62 @@ | |||
1 | SUMMARY = "Additional utilities for the opkg package manager" | ||
2 | SUMMARY_update-alternatives-opkg = "Utility for managing the alternatives system" | ||
3 | SECTION = "base" | ||
4 | HOMEPAGE = "http://git.yoctoproject.org/cgit/cgit.cgi/opkg-utils" | ||
5 | LICENSE = "GPLv2+" | ||
6 | LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \ | ||
7 | file://opkg.py;beginline=2;endline=18;md5=63ce9e6bcc445181cd9e4baf4b4ccc35" | ||
8 | PROVIDES += "${@bb.utils.contains('PACKAGECONFIG', 'update-alternatives', 'virtual/update-alternatives', '', d)}" | ||
9 | |||
10 | SRC_URI = "http://git.yoctoproject.org/cgit/cgit.cgi/${BPN}/snapshot/${BPN}-${PV}.tar.gz \ | ||
11 | file://0001-Switch-all-scripts-to-use-Python-3.x.patch \ | ||
12 | " | ||
13 | SRC_URI_append_class-native = " file://tar_ignore_error.patch" | ||
14 | |||
15 | SRC_URI[md5sum] = "a19e09c79bf1152aac62e8a120d679ff" | ||
16 | SRC_URI[sha256sum] = "7f4b08912e26a3f4f6f423f3b4e7157a73b1f3a7483fc59b216d1a80b50b0c38" | ||
17 | |||
18 | TARGET_CC_ARCH += "${LDFLAGS}" | ||
19 | |||
20 | # For native builds we use the host Python | ||
21 | PYTHONRDEPS = "python3 python3-shell python3-io python3-math python3-crypt python3-logging python3-fcntl python3-subprocess python3-pickle python3-compression python3-textutils python3-stringold" | ||
22 | PYTHONRDEPS_class-native = "" | ||
23 | |||
24 | PACKAGECONFIG = "python update-alternatives" | ||
25 | PACKAGECONFIG[python] = ",,,${PYTHONRDEPS}" | ||
26 | PACKAGECONFIG[update-alternatives] = ",,," | ||
27 | |||
28 | do_install() { | ||
29 | oe_runmake PREFIX=${prefix} DESTDIR=${D} install | ||
30 | if ! ${@bb.utils.contains('PACKAGECONFIG', 'update-alternatives', 'true', 'false', d)}; then | ||
31 | rm -f "${D}${bindir}/update-alternatives" | ||
32 | fi | ||
33 | |||
34 | if ! ${@bb.utils.contains('PACKAGECONFIG', 'python', 'true', 'false', d)}; then | ||
35 | grep -lZ "/usr/bin/env.*python" ${D}${bindir}/* | xargs -0 rm | ||
36 | fi | ||
37 | } | ||
38 | |||
39 | do_install_append_class-target() { | ||
40 | if [ -e "${D}${bindir}/update-alternatives" ]; then | ||
41 | sed -i ${D}${bindir}/update-alternatives -e 's,/usr/bin,${bindir},g; s,/usr/lib,${nonarch_libdir},g' | ||
42 | fi | ||
43 | } | ||
44 | |||
45 | # These are empty and will pull python3-dev into images where it wouldn't | ||
46 | # have been otherwise, so don't generate them. | ||
47 | PACKAGES_remove = "${PN}-dev ${PN}-staticdev" | ||
48 | |||
49 | PACKAGES =+ "update-alternatives-opkg" | ||
50 | FILES_update-alternatives-opkg = "${bindir}/update-alternatives" | ||
51 | RPROVIDES_update-alternatives-opkg = "update-alternatives update-alternatives-cworth" | ||
52 | RREPLACES_update-alternatives-opkg = "update-alternatives-cworth" | ||
53 | RCONFLICTS_update-alternatives-opkg = "update-alternatives-cworth" | ||
54 | |||
55 | pkg_postrm_update-alternatives-opkg() { | ||
56 | rm -rf $D${nonarch_libdir}/opkg/alternatives | ||
57 | rmdir $D${nonarch_libdir}/opkg || true | ||
58 | } | ||
59 | |||
60 | BBCLASSEXTEND = "native nativesdk" | ||
61 | |||
62 | CLEANBROKEN = "1" | ||