libtool-nativesdk: rename to nativesdk-libtool

Rename nativesdk item to prefix vs suffix. Some minor changes for
getting it works after renamed:

    * append patches dir 'libtool/' to FILESEXTRAPATHS
    * update ${S}, append '${datadir}/libtool/*' to FILES_${PN}

(From OE-Core rev: cc7deb8b8dbc58975b8f55cd63f237aa0ded0887)

Signed-off-by: Wenzong Fan <wenzong.fan@windriver.com>
Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 33 insertions, 0 deletions

diff --git a/meta/recipes-devtools/libtool/nativesdk-libtool_2.4.2.bb b/meta/recipes-devtools/libtool/nativesdk-libtool_2.4.2.bb
new file mode 100644
index 0000000000..7b5c97a97a
--- /dev/null
+++ b/meta/recipes-devtools/libtool/nativesdk-libtool_2.4.2.bb
@@ -0,0 +1,33 @@
+require libtool-${PV}.inc
+
+PR = "${INC_PR}.0"
+
+FILESEXTRAPATHS =. "${FILE_DIRNAME}/libtool:"
+
+SRC_URI += "file://prefix.patch"
+SRC_URI += "file://fixinstall.patch"
+
+inherit nativesdk
+
+S = "${WORKDIR}/libtool-${PV}"
+FILES_${PN} += "${datadir}/libtool/*"
+
+do_configure_prepend () {
+        # Remove any existing libtool m4 since old stale versions would break
+        # any upgrade
+        rm -f ${STAGING_DATADIR}/aclocal/libtool.m4
+        rm -f ${STAGING_DATADIR}/aclocal/lt*.m4
+}
+
+do_install () {
+        autotools_do_install
+        install -d ${D}${bindir}/
+        install -m 0755 ${HOST_SYS}-libtool ${D}${bindir}/
+}
+
+SYSROOT_PREPROCESS_FUNCS += "libtoolnativesdk_sysroot_preprocess"
+
+libtoolnativesdk_sysroot_preprocess () {
+        install -d ${SYSROOT_DESTDIR}${bindir_crossscripts}/
+        install -m 755 ${D}${bindir}/${HOST_SYS}-libtool ${SYSROOT_DESTDIR}${bindir_crossscripts}/${HOST_SYS}-libtool
+}