libtool: 2.4.5 -> 2.4.6

Drop patch merged upstream.

(From OE-Core rev: cd03ef79b50ed42b9d407ee45fc3e3321385281c)

Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 51 insertions, 0 deletions

diff --git a/meta/recipes-devtools/libtool/libtool-2.4.6.inc b/meta/recipes-devtools/libtool/libtool-2.4.6.inc
new file mode 100644
index 0000000000..ff5abcb239
--- /dev/null
+++ b/meta/recipes-devtools/libtool/libtool-2.4.6.inc
@@ -0,0 +1,51 @@
+SUMMARY = "Generic library support script"
+DESCRIPTION = "This is GNU libtool, a generic library support script. \
+Libtool hides the complexity of generating special library types \
+(such as shared libraries) behind a consistent interface."
+HOMEPAGE = "http://www.gnu.org/software/libtool/libtool.html"
+SECTION = "devel"
+LICENSE = "GPLv2 & LGPLv2.1"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+    file://libltdl/COPYING.LIB;md5=4fbd65380cdd255951079008b364516c "
+
+SRC_URI = "${GNU_MIRROR}/libtool/libtool-${PV}.tar.gz \
+           file://trailingslash.patch \
+           file://rename-with-sysroot.patch \
+           file://use-sysroot-in-libpath.patch \
+           file://fix-final-rpath.patch \
+           file://fix-rpath.patch \
+           file://norm-rpath.patch \
+           file://dont-depend-on-help2man.patch \
+           file://fix-resolve-lt-sysroot.patch \
+           file://nohardcodepaths.patch \
+           file://unwind-opt-parsing.patch \
+          "
+
+SRC_URI[md5sum] = "addf44b646ddb4e3919805aa88fa7c5e"
+SRC_URI[sha256sum] = "e3bd4d5d3d025a36c21dd6af7ea818a2afcd4dfc1ea5a17b39d7854bcd0c06e3"
+
+do_compile_prepend () {
+        # Sometimes this file doesn't get rebuilt, force the issue
+        rm -f ${S}/build-aux/ltmain.sh
+        make build-aux/ltmain.sh
+        ./config.status
+}
+
+inherit autotools texinfo
+EXTRA_AUTORECONF = "--exclude=libtoolize"
+
+DEPENDS = "libtool-native"
+
+PACKAGES =+ "libltdl libltdl-dev libltdl-dbg libltdl-staticdev"
+FILES_${PN} += "${datadir}/aclocal"
+FILES_${PN}-dev = "${includedir} ${FILES_SOLIBSDEV} ${libdir}/*.la \
+                ${libdir}/*.o ${libdir}/pkgconfig ${datadir}/pkgconfig \
+                ${base_libdir}/*.o ${libdir}/${BPN}/*.la ${base_libdir}/*.la"
+
+#FILES_${PN}-dev := "${@oe_filter_out('${datadir}/aclocal', '${FILES_libtool-dev}', d)}"
+FILES_libltdl = "${libdir}/libltdl${SOLIBS}"
+FILES_libltdl-dev = "${libdir}/libltdl${SOLIBSDEV} ${includedir}"
+FILES_libltdl-staticdev = "${libdir}/libltdl.a"
+FILES_libltdl-dbg = "${libdir}/.debug/"
+
+export CONFIG_SHELL="/bin/bash"