gnu-config: update to 2012.08.14 to get support for AArch64 architecture

(From OE-Core rev: fd082d328f1312847097794dea588ed670206cb4)

Signed-off-by: Marcin Juszkiewicz <marcin.juszkiewicz@linaro.org>
Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 41 insertions, 0 deletions

diff --git a/meta/recipes-devtools/gnu-config/gnu-config_20120814.bb b/meta/recipes-devtools/gnu-config/gnu-config_20120814.bb
new file mode 100644
index 0000000000..dd9248f2eb
--- /dev/null
+++ b/meta/recipes-devtools/gnu-config/gnu-config_20120814.bb
@@ -0,0 +1,41 @@
+SUMMARY = "gnu-configize"
+DESCRIPTION = "Tool that installs the GNU config.guess / config.sub into a directory tree"
+SECTION = "devel"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://config.guess;endline=39;md5=b79a4663475f4d724846463277817e0d"
+
+DEPENDS_virtclass-native = "perl-native-runtime"
+
+INHIBIT_DEFAULT_DEPS = "1"
+
+PR = "r0"
+
+SRC_URI = "http://downloads.yoctoproject.org/releases/gnu-config/gnu-config-${PV}.tar.bz2 \
+           file://config-guess-uclibc.patch \
+           file://gnu-configize.in"
+
+SRC_URI[md5sum] = "bcfca5a2bb39edad4aae5a65efc84094"
+SRC_URI[sha256sum] = "44f99a8e76f3e8e4fec0bb5ad4762f8e44366168554ce66cb85afbe2ed3efd8b"
+
+do_compile() {
+        :
+}
+
+do_install () {
+        install -d ${D}${datadir}/gnu-config \
+                   ${D}${bindir}
+        cat ${WORKDIR}/gnu-configize.in | \
+                sed -e 's,@gnu-configdir@,${datadir}/gnu-config,g' \
+                    -e 's,@autom4te_perllibdir@,${datadir}/autoconf,g' > ${D}${bindir}/gnu-configize
+        # In the native case we want the system perl as perl-native can't have built yet
+        if [ "${PN}" != "gnu-config-native" -a "${PN}" != "nativesdk-gnu-config" ]; then
+                sed -i -e 's,/usr/bin/env,${bindir}/env,g' ${D}${bindir}/gnu-configize
+        fi
+        chmod 755 ${D}${bindir}/gnu-configize
+        install -m 0644 config.guess config.sub ${D}${datadir}/gnu-config/
+}
+
+PACKAGES = "${PN}"
+FILES_${PN} = "${bindir} ${datadir}/gnu-config"
+
+BBCLASSEXTEND = "native nativesdk"