Major layout change to the packages directory

Having one monolithic packages directory makes it hard to find things
and is generally overwhelming. This commit splits it into several
logical sections roughly based on function, recipes.txt gives more
information about the classifications used.

The opportunity is also used to switch from "packages" to "recipes"
as used in OpenEmbedded as the term "packages" can be confusing to
people and has many different meanings.

Not all recipes have been classified yet, this is just a first pass
at separating things out. Some packages are moved to meta-extras as
they're no longer actively used or maintained.

Signed-off-by: Richard Purdie <rpurdie@linux.intel.com>

1 files changed, 38 insertions, 0 deletions

diff --git a/meta/recipes-devtools/gnu-config/gnu-config_20080123.bb b/meta/recipes-devtools/gnu-config/gnu-config_20080123.bb
new file mode 100644
index 0000000000..66d027e933
--- /dev/null
+++ b/meta/recipes-devtools/gnu-config/gnu-config_20080123.bb
@@ -0,0 +1,38 @@
+DESCRIPTION = "gnu-configize"
+SECTION = "devel"
+LICENSE = "GPL"
+DEPENDS = ""
+INHIBIT_DEFAULT_DEPS = "1"
+
+FIXEDSRCDATE = "${@bb.data.getVar('FILE', d, 1).split('_')[-1].split('.')[0]}"
+PV = "0.1+cvs${FIXEDSRCDATE}"
+PR = "r0"
+
+SRC_URI = "cvs://anonymous@cvs.sv.gnu.org/cvsroot/config;module=config;method=pserver;date=${FIXEDSRCDATE} \
+           file://config-guess-uclibc.patch \
+           file://gnu-configize.in"
+S = "${WORKDIR}/config"
+
+do_compile() {
+        :
+}
+
+do_install () {
+        install -d ${D}${datadir}/gnu-config \
+                   ${D}${bindir}
+        cat ${WORKDIR}/gnu-configize.in | \
+                sed -e 's,@gnu-configdir@,${datadir}/gnu-config,g' \
+                    -e 's,@autom4te_perllibdir@,${datadir}/autoconf,g' > ${D}${bindir}/gnu-configize
+        # In the native case we want the system perl as perl-native can't have built yet
+        if [ "${BUILD_ARCH}" != "${TARGET_ARCH}" ]; then
+                cat ${WORKDIR}/gnu-configize.in | \
+                        sed -e 's,/usr/bin/perl,${bindir}/perl,g' > ${D}${bindir}/gnu-configize
+        fi
+        chmod 755 ${D}${bindir}/gnu-configize
+        install -m 0644 config.guess config.sub ${D}${datadir}/gnu-config/
+}
+
+PACKAGES = "${PN}"
+FILES_${PN} = "${bindir} ${datadir}/gnu-config"
+
+BBCLASSEXTEND = "native"