diff options
author | Tudor Florea <tudor.florea@enea.com> | 2015-10-09 22:59:03 +0200 |
---|---|---|
committer | Tudor Florea <tudor.florea@enea.com> | 2015-10-09 22:59:03 +0200 |
commit | 972dcfcdbfe75dcfeb777150c136576cf1a71e99 (patch) | |
tree | 97a61cd7e293d7ae9d56ef7ed0f81253365bb026 /meta/recipes-devtools/git | |
download | poky-972dcfcdbfe75dcfeb777150c136576cf1a71e99.tar.gz |
initial commit for Enea Linux 5.0 arm
Signed-off-by: Tudor Florea <tudor.florea@enea.com>
Diffstat (limited to 'meta/recipes-devtools/git')
-rw-r--r-- | meta/recipes-devtools/git/git.inc | 115 | ||||
-rw-r--r-- | meta/recipes-devtools/git/git_2.0.1.bb | 9 |
2 files changed, 124 insertions, 0 deletions
diff --git a/meta/recipes-devtools/git/git.inc b/meta/recipes-devtools/git/git.inc new file mode 100644 index 0000000000..5396628790 --- /dev/null +++ b/meta/recipes-devtools/git/git.inc | |||
@@ -0,0 +1,115 @@ | |||
1 | SUMMARY = "Distributed version control system" | ||
2 | SECTION = "console/utils" | ||
3 | LICENSE = "GPLv2" | ||
4 | DEPENDS = "openssl curl zlib expat" | ||
5 | |||
6 | PROVIDES_append_class-native = " git-replacement-native" | ||
7 | |||
8 | SRC_URI = "${KERNELORG_MIRROR}/software/scm/git/git-${PV}.tar.gz" | ||
9 | S = "${WORKDIR}/git-${PV}" | ||
10 | |||
11 | LIC_FILES_CHKSUM = "file://COPYING;md5=7c0d7ef03a7eb04ce795b0f60e68e7e1" | ||
12 | |||
13 | EXTRA_OECONF = "--with-perl=${STAGING_BINDIR_NATIVE}/perl-native/perl \ | ||
14 | --without-tcltk \ | ||
15 | " | ||
16 | |||
17 | inherit autotools-brokensep perlnative | ||
18 | |||
19 | EXTRA_OEMAKE = "NO_PYTHON=1 CFLAGS='${CFLAGS}' LDFLAGS='${LDFLAGS}'" | ||
20 | EXTRA_OEMAKE += "'PERL_PATH=/usr/bin/env perl'" | ||
21 | EXTRA_OEMAKE_append_class-native = " NO_CROSS_DIRECTORY_HARDLINKS=1" | ||
22 | |||
23 | do_compile_prepend () { | ||
24 | # Remove perl/perl.mak to fix the out-of-date perl.mak error | ||
25 | # during rebuild | ||
26 | rm -f perl/perl.mak | ||
27 | } | ||
28 | |||
29 | do_install () { | ||
30 | oe_runmake install DESTDIR="${D}" bindir=${bindir} \ | ||
31 | template_dir=${datadir}/git-core/templates \ | ||
32 | GIT_PYTHON_DIR=${D}${datadir}/git-core/python | ||
33 | } | ||
34 | |||
35 | perl_native_fixup () { | ||
36 | sed -i -e 's#${STAGING_BINDIR_NATIVE}/perl-native/#${bindir}/#' \ | ||
37 | -e 's#${libdir}/perl-native/#${libdir}/#' \ | ||
38 | ${@d.getVar("PERLTOOLS", True).replace(' /',d.getVar('D', True) + '/')} | ||
39 | |||
40 | # ${libdir} is not applicable here, perl-native files are always | ||
41 | # installed to /usr/lib on both 32/64 bits targets. | ||
42 | mv ${D}${exec_prefix}/lib/perl-native/perl ${D}${libdir} | ||
43 | rmdir -p ${D}${exec_prefix}/lib/perl-native || true | ||
44 | } | ||
45 | |||
46 | REL_GIT_EXEC_PATH = "${@os.path.relpath(libexecdir, bindir)}/git-core" | ||
47 | REL_GIT_TEMPLATE_DIR = "${@os.path.relpath(datadir, bindir)}/git-core/templates" | ||
48 | |||
49 | do_install_append_class-target () { | ||
50 | perl_native_fixup | ||
51 | } | ||
52 | |||
53 | do_install_append_class-native() { | ||
54 | create_wrapper ${D}${bindir}/git \ | ||
55 | GIT_EXEC_PATH='`dirname $''realpath`'/${REL_GIT_EXEC_PATH} \ | ||
56 | GIT_TEMPLATE_DIR='`dirname $''realpath`'/${REL_GIT_TEMPLATE_DIR} | ||
57 | } | ||
58 | |||
59 | do_install_append_class-nativesdk() { | ||
60 | create_wrapper ${D}${bindir}/git \ | ||
61 | GIT_EXEC_PATH='`dirname $''realpath`'/${REL_GIT_EXEC_PATH} \ | ||
62 | GIT_TEMPLATE_DIR='`dirname $''realpath`'/${REL_GIT_TEMPLATE_DIR} | ||
63 | perl_native_fixup | ||
64 | } | ||
65 | |||
66 | FILES_${PN} += "${datadir}/git-core ${libexecdir}/git-core/" | ||
67 | FILES_${PN}-dbg += "${libexecdir}/git-core/.debug" | ||
68 | |||
69 | PERLTOOLS = " \ | ||
70 | ${libexecdir}/git-core/git-add--interactive \ | ||
71 | ${libexecdir}/git-core/git-archimport \ | ||
72 | ${libexecdir}/git-core/git-cvsexportcommit \ | ||
73 | ${libexecdir}/git-core/git-cvsimport \ | ||
74 | ${libexecdir}/git-core/git-cvsserver \ | ||
75 | ${bindir}/git-cvsserver \ | ||
76 | ${libexecdir}/git-core/git-difftool \ | ||
77 | ${libexecdir}/git-core/git-relink \ | ||
78 | ${libexecdir}/git-core/git-send-email \ | ||
79 | ${libexecdir}/git-core/git-svn \ | ||
80 | ${libexecdir}/git-core/git-instaweb \ | ||
81 | ${libexecdir}/git-core/git-submodule \ | ||
82 | ${libexecdir}/git-core/git-am \ | ||
83 | ${libexecdir}/git-core/git-request-pull \ | ||
84 | ${datadir}/gitweb/gitweb.cgi \ | ||
85 | ${datadir}/git-core/templates/hooks/prepare-commit-msg.sample \ | ||
86 | ${datadir}/git-core/templates/hooks/pre-rebase.sample \ | ||
87 | " | ||
88 | |||
89 | # Git tools requiring perl | ||
90 | PACKAGES =+ "${PN}-perltools" | ||
91 | FILES_${PN}-perltools += " \ | ||
92 | ${PERLTOOLS} \ | ||
93 | ${libdir}/perl \ | ||
94 | ${datadir}/perl \ | ||
95 | " | ||
96 | RDEPENDS_${PN}-perltools = "${PN} perl perl-module-file-path findutils" | ||
97 | |||
98 | PACKAGES =+ "${PN}-python" | ||
99 | FILES_${PN}-python = "${libdir}/python*" | ||
100 | |||
101 | |||
102 | # git-tk package with gitk and git-gui | ||
103 | PACKAGES =+ "${PN}-tk" | ||
104 | #RDEPENDS_${PN}-tk = "${PN} tk tcl" | ||
105 | #EXTRA_OEMAKE = "TCL_PATH=${STAGING_BINDIR_CROSS}/tclsh" | ||
106 | FILES_${PN}-tk = " \ | ||
107 | ${bindir}/gitk \ | ||
108 | ${datadir}/gitk \ | ||
109 | " | ||
110 | |||
111 | PACKAGES =+ "gitweb" | ||
112 | FILES_gitweb = "${datadir}/gitweb/" | ||
113 | |||
114 | |||
115 | BBCLASSEXTEND = "native nativesdk" | ||
diff --git a/meta/recipes-devtools/git/git_2.0.1.bb b/meta/recipes-devtools/git/git_2.0.1.bb new file mode 100644 index 0000000000..dbf32e1a03 --- /dev/null +++ b/meta/recipes-devtools/git/git_2.0.1.bb | |||
@@ -0,0 +1,9 @@ | |||
1 | require git.inc | ||
2 | |||
3 | SRC_URI[md5sum] = "981f5937840716cb563be1cc6292c8d7" | ||
4 | SRC_URI[sha256sum] = "02609a06fb40db1f6a968867c0e82bcb959b85902747830de0fda53228712daf" | ||
5 | |||
6 | EXTRA_OECONF += "ac_cv_snprintf_returns_bogus=no ac_cv_c_c99_format=yes \ | ||
7 | ac_cv_fread_reads_directories=${ac_cv_fread_reads_directories=yes} \ | ||
8 | " | ||
9 | EXTRA_OEMAKE += "NO_GETTEXT=1" | ||