diff options
author | Alexander Kanavin <alex.kanavin@gmail.com> | 2019-11-29 14:11:48 +0100 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2019-12-04 12:30:58 +0000 |
commit | e8543db1c6e4a3ae6d6ed4481114090fdd43fa8f (patch) | |
tree | d78534e05a359d4d3b33157d90a30ac2c34794f7 /meta/recipes-devtools/flex/flex_2.6.4.bb | |
parent | fb5037bbc50d298aa319bb6825de50b741413555 (diff) | |
download | poky-e8543db1c6e4a3ae6d6ed4481114090fdd43fa8f.tar.gz |
flex: update to 2.6.4
Add a backport patch that addresses segfaults on newer glibc versions.
Remove:
CVE-2016-6354.patch (backport)
0002-avoid-c-comments-in-c-code-fails-with-gcc-6.patch (issue fixed upstream)
do_not_create_pdf_doc.patch (issue fixed upstream)
ptest pass rate is 100%.
(From OE-Core rev: a0fe05f3ffd67dc42e053c20bd019bb9d463d0ad)
Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-devtools/flex/flex_2.6.4.bb')
-rw-r--r-- | meta/recipes-devtools/flex/flex_2.6.4.bb | 71 |
1 files changed, 71 insertions, 0 deletions
diff --git a/meta/recipes-devtools/flex/flex_2.6.4.bb b/meta/recipes-devtools/flex/flex_2.6.4.bb new file mode 100644 index 0000000000..d8e2f7f28c --- /dev/null +++ b/meta/recipes-devtools/flex/flex_2.6.4.bb | |||
@@ -0,0 +1,71 @@ | |||
1 | SUMMARY = "Flex (The Fast Lexical Analyzer)" | ||
2 | DESCRIPTION = "Flex is a fast lexical analyser generator. Flex is a tool for generating programs that recognize \ | ||
3 | lexical patterns in text." | ||
4 | HOMEPAGE = "http://sourceforge.net/projects/flex/" | ||
5 | SECTION = "devel" | ||
6 | LICENSE = "BSD-2-Clause" | ||
7 | |||
8 | DEPENDS = "${@bb.utils.contains('PTEST_ENABLED', '1', 'bison-native flex-native', '', d)}" | ||
9 | BBCLASSEXTEND = "native nativesdk" | ||
10 | |||
11 | LIC_FILES_CHKSUM = "file://COPYING;md5=e4742cf92e89040b39486a6219b68067" | ||
12 | |||
13 | SRC_URI = "https://github.com/westes/flex/releases/download/v${PV}/flex-${PV}.tar.gz \ | ||
14 | file://run-ptest \ | ||
15 | file://0001-tests-add-a-target-for-building-tests-without-runnin.patch \ | ||
16 | ${@bb.utils.contains('PTEST_ENABLED', '1', '', 'file://disable-tests.patch', d)} \ | ||
17 | file://0001-build-AC_USE_SYSTEM_EXTENSIONS-in-configure.ac.patch \ | ||
18 | " | ||
19 | |||
20 | SRC_URI[md5sum] = "2882e3179748cc9f9c23ec593d6adc8d" | ||
21 | SRC_URI[sha256sum] = "e87aae032bf07c26f85ac0ed3250998c37621d95f8bd748b31f15b33c45ee995" | ||
22 | |||
23 | # Flex has moved to github from 2.6.1 onwards | ||
24 | UPSTREAM_CHECK_URI = "https://github.com/westes/flex/releases" | ||
25 | UPSTREAM_CHECK_REGEX = "flex-(?P<pver>\d+(\.\d+)+)\.tar" | ||
26 | |||
27 | inherit autotools gettext texinfo ptest | ||
28 | |||
29 | M4 = "${bindir}/m4" | ||
30 | M4_class-native = "${STAGING_BINDIR_NATIVE}/m4" | ||
31 | EXTRA_OECONF += "ac_cv_path_M4=${M4} ac_cv_func_reallocarray=no" | ||
32 | EXTRA_OEMAKE += "m4=${STAGING_BINDIR_NATIVE}/m4" | ||
33 | |||
34 | EXTRA_OEMAKE += "${@bb.utils.contains('PTEST_ENABLED', '1', 'FLEX=${STAGING_BINDIR_NATIVE}/flex', '', d)}" | ||
35 | |||
36 | do_install_append_class-native() { | ||
37 | create_wrapper ${D}/${bindir}/flex M4=${M4} | ||
38 | } | ||
39 | |||
40 | do_install_append_class-nativesdk() { | ||
41 | create_wrapper ${D}/${bindir}/flex M4=${M4} | ||
42 | } | ||
43 | |||
44 | PACKAGES =+ "${PN}-libfl" | ||
45 | |||
46 | FILES_${PN}-libfl = "${libdir}/libfl.so.* ${libdir}/libfl_pic.so.*" | ||
47 | |||
48 | RDEPENDS_${PN} += "m4" | ||
49 | RDEPENDS_${PN}-ptest += "bash gawk make" | ||
50 | |||
51 | do_compile_ptest() { | ||
52 | oe_runmake -C ${B}/tests -f ${B}/tests/Makefile top_builddir=${B} INCLUDES=-I${S}/src buildtests | ||
53 | } | ||
54 | |||
55 | do_install_ptest() { | ||
56 | mkdir -p ${D}${PTEST_PATH}/build-aux/ | ||
57 | cp ${S}/build-aux/test-driver ${D}${PTEST_PATH}/build-aux/ | ||
58 | cp -r ${S}/tests/* ${D}${PTEST_PATH} | ||
59 | cp -r ${B}/tests/* ${D}${PTEST_PATH} | ||
60 | sed -e 's,--sysroot=${STAGING_DIR_TARGET},,g' \ | ||
61 | -e 's|${DEBUG_PREFIX_MAP}||g' \ | ||
62 | -e 's:${HOSTTOOLS_DIR}/::g' \ | ||
63 | -e 's:${RECIPE_SYSROOT_NATIVE}::g' \ | ||
64 | -e 's:${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}::g' \-e 's/^Makefile:/_Makefile:/' \ | ||
65 | -e 's/^srcdir = \(.*\)/srcdir = ./' -e 's/^top_srcdir = \(.*\)/top_srcdir = ./' \ | ||
66 | -e 's/^builddir = \(.*\)/builddir = ./' -e 's/^top_builddir = \(.*\)/top_builddir = ./' \ | ||
67 | -i ${D}${PTEST_PATH}/Makefile | ||
68 | } | ||
69 | |||
70 | # Not Apache Flex, or Adobe Flex, or IBM Flex. | ||
71 | CVE_PRODUCT = "flex_project:flex" | ||