file: 5.23 -> 5.24

* Remove backported patch:
- 0001-Fix-bug-with-long-options-and-explicitly-number-them.patch \
- 0002-fix-bug-with-5.23-long-options.patch \

* Use git repo rather than tarball since the original SRC_URI is not
  stable, it is not reachable sometimes.

(From OE-Core rev: 18d52e57299043953757e78c23205570440f039c)

Signed-off-by: Robert Yang <liezhi.yang@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 36 insertions, 0 deletions

diff --git a/meta/recipes-devtools/file/file_5.24.bb b/meta/recipes-devtools/file/file_5.24.bb
new file mode 100644
index 0000000000..08b95d7b61
--- /dev/null
+++ b/meta/recipes-devtools/file/file_5.24.bb
@@ -0,0 +1,36 @@
+SUMMARY = "File classification tool"
+DESCRIPTION = "File attempts to classify files depending \
+on their contents and prints a description if a match is found."
+HOMEPAGE = "http://www.darwinsys.com/file/"
+SECTION = "console/utils"
+
+# two clause BSD
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://COPYING;beginline=2;md5=6a7382872edb68d33e1a9398b6e03188"
+
+DEPENDS = "zlib file-native"
+DEPENDS_class-native = "zlib-native"
+
+SRC_URI = "git://github.com/file/file.git \
+        file://debian-742262.patch \
+        file://0001-Add-P-prompt-into-Usage-info.patch \
+        "
+
+SRCREV = "3c0874be4d3232d672b20f513451a39cfd7c585a"
+S = "${WORKDIR}/git"
+
+inherit autotools
+
+FILES_${PN} += "${datadir}/misc/*.mgc"
+
+do_install_append_class-native() {
+        create_cmdline_wrapper ${D}/${bindir}/file \
+                --magic-file ${datadir}/misc/magic.mgc
+}
+
+do_install_append_class-nativesdk() {
+        create_cmdline_wrapper ${D}/${bindir}/file \
+                --magic-file ${datadir}/misc/magic.mgc
+}
+
+BBCLASSEXTEND = "native nativesdk"