summaryrefslogtreecommitdiffstats
path: root/meta/recipes-devtools/elfutils/elfutils_0.182.bb
diff options
context:
space:
mode:
authorAlexander Kanavin <alex.kanavin@gmail.com>2020-12-04 21:07:21 +0100
committerRichard Purdie <richard.purdie@linuxfoundation.org>2020-12-09 12:20:32 +0000
commit9404999142c3a1476783cb6e2593c16a8ddcf133 (patch)
treea8aa31d9a6141c863c088e73e3b55e9e5e01aaa5 /meta/recipes-devtools/elfutils/elfutils_0.182.bb
parent4993815b4731814d48b5b00b85dd6e7926abe085 (diff)
downloadpoky-9404999142c3a1476783cb6e2593c16a8ddcf133.tar.gz
elfutils: upgrade 0.181 -> 0.182
(From OE-Core rev: f4cc0df90197e031326a3f823b37cc138950ca70) Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-devtools/elfutils/elfutils_0.182.bb')
-rw-r--r--meta/recipes-devtools/elfutils/elfutils_0.182.bb154
1 files changed, 154 insertions, 0 deletions
diff --git a/meta/recipes-devtools/elfutils/elfutils_0.182.bb b/meta/recipes-devtools/elfutils/elfutils_0.182.bb
new file mode 100644
index 0000000000..f63208d72b
--- /dev/null
+++ b/meta/recipes-devtools/elfutils/elfutils_0.182.bb
@@ -0,0 +1,154 @@
1SUMMARY = "Utilities and libraries for handling compiled object files"
2HOMEPAGE = "https://sourceware.org/elfutils"
3SECTION = "base"
4LICENSE = "GPLv2 & LGPLv3+ & GPLv3+"
5LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
6DEPENDS = "zlib virtual/libintl"
7DEPENDS_append_libc-musl = " argp-standalone fts musl-obstack "
8# The Debian patches below are from:
9# http://ftp.de.debian.org/debian/pool/main/e/elfutils/elfutils_0.176-1.debian.tar.xz
10SRC_URI = "https://sourceware.org/elfutils/ftp/${PV}/${BP}.tar.bz2 \
11 file://0001-dso-link-change.patch \
12 file://0002-Fix-elf_cvt_gunhash-if-dest-and-src-are-same.patch \
13 file://0003-fixheadercheck.patch \
14 file://0004-Disable-the-test-to-convert-euc-jp.patch \
15 file://0006-Fix-build-on-aarch64-musl.patch \
16 file://0001-libasm-may-link-with-libbz2-if-found.patch \
17 file://0001-libelf-elf_end.c-check-data_list.data.d.d_buf-before.patch \
18 file://0001-skip-the-test-when-gcc-not-deployed.patch \
19 file://0001-ppc_initreg.c-Incliude-asm-ptrace.h-for-pt_regs-defi.patch \
20 file://run-ptest \
21 file://ptest.patch \
22 file://0001-tests-Makefile.am-compile-test_nlist-with-standard-C.patch \
23 "
24SRC_URI_append_libc-musl = " \
25 file://0001-musl-obstack-fts.patch \
26 file://0002-musl-libs.patch \
27 file://0003-musl-utils.patch \
28 file://0004-Fix-error-on-musl.patch \
29 file://0015-config-eu.am-do-not-use-Werror.patch \
30 "
31SRC_URI[sha256sum] = "ecc406914edf335f0b7fc084ebe6c460c4d6d5175bfdd6688c1c78d9146b8858"
32
33inherit autotools gettext ptest pkgconfig
34
35EXTRA_OECONF = "--program-prefix=eu- --disable-debuginfod"
36
37DEPENDS_BZIP2 = "bzip2-replacement-native"
38DEPENDS_BZIP2_class-target = "bzip2"
39
40PACKAGECONFIG ??= ""
41PACKAGECONFIG[bzip2] = "--with-bzlib,--without-bzlib,${DEPENDS_BZIP2}"
42PACKAGECONFIG[xz] = "--with-lzma,--without-lzma,xz"
43PACKAGECONFIG[libdebuginfod] = "--enable-libdebuginfod,--disable-libdebuginfod,curl"
44
45RDEPENDS_${PN}-ptest += "libasm libelf bash make coreutils ${PN}-binutils"
46
47EXTRA_OECONF_append_class-target = " --disable-tests-rpath"
48
49RDEPENDS_${PN}-ptest_append_libc-glibc = " glibc-utils"
50
51do_compile_ptest() {
52 cd ${B}/tests
53 oe_runmake buildtest-TESTS oecheck
54}
55
56do_install_ptest() {
57 if [ ${PTEST_ENABLED} = "1" ]; then
58 # copy the files which needed by the cases
59 TEST_FILES="strip strip.o addr2line elfcmp objdump readelf size.o nm.o nm elflint elfcompress elfclassify stack unstrip"
60 install -d -m 755 ${D}${PTEST_PATH}/src
61 install -d -m 755 ${D}${PTEST_PATH}/libelf
62 install -d -m 755 ${D}${PTEST_PATH}/libdw
63 install -d -m 755 ${D}${PTEST_PATH}/libdwfl
64 install -d -m 755 ${D}${PTEST_PATH}/libdwelf
65 install -d -m 755 ${D}${PTEST_PATH}/libasm
66 for test_file in ${TEST_FILES}; do
67 if [ -f ${B}/src/${test_file} ]; then
68 cp -r ${B}/src/${test_file} ${D}${PTEST_PATH}/src
69 fi
70 done
71 cp ${D}${libdir}/libelf-${PV}.so ${D}${PTEST_PATH}/libelf/libelf.so
72 cp ${D}${libdir}/libdw-${PV}.so ${D}${PTEST_PATH}/libdw/libdw.so
73 cp ${D}${libdir}/libasm-${PV}.so ${D}${PTEST_PATH}/libasm/libasm.so
74 cp ${S}/libelf/*.h ${D}${PTEST_PATH}/libelf/
75 cp ${S}/libdw/*.h ${D}${PTEST_PATH}/libdw/
76 cp ${S}/libdwfl/*.h ${D}${PTEST_PATH}/libdwfl/
77 cp ${S}/libdwelf/*.h ${D}${PTEST_PATH}/libdwelf/
78 cp ${S}/libasm/*.h ${D}${PTEST_PATH}/libasm/
79 cp -r ${S}/tests/ ${D}${PTEST_PATH}
80 cp -r ${B}/tests/* ${D}${PTEST_PATH}/tests
81 cp -r ${B}/config.h ${D}${PTEST_PATH}
82 cp -r ${B}/backends ${D}${PTEST_PATH}
83 sed -i '/^Makefile:/c Makefile:' ${D}${PTEST_PATH}/tests/Makefile
84 find ${D}${PTEST_PATH} -type f -name *.[hoc] | xargs -i rm {}
85 fi
86}
87
88EXTRA_OEMAKE_class-native = ""
89EXTRA_OEMAKE_class-nativesdk = ""
90
91BBCLASSEXTEND = "native nativesdk"
92
93# Package utilities separately
94PACKAGES =+ "${PN}-binutils libelf libasm libdw"
95
96# shared libraries are licensed GPLv2 or GPLv3+, binaries GPLv3+
97# according to NEWS file:
98# "The license is now GPLv2/LGPLv3+ for the libraries and GPLv3+ for stand-alone
99# programs. There is now also a formal CONTRIBUTING document describing how to
100# submit patches."
101LICENSE_${PN}-binutils = "GPLv3+"
102LICENSE_${PN} = "GPLv3+"
103LICENSE_libelf = "GPLv2 | LGPLv3+"
104LICENSE_libasm = "GPLv2 | LGPLv3+"
105LICENSE_libdw = "GPLv2 | LGPLv3+"
106
107FILES_${PN}-binutils = "\
108 ${bindir}/eu-addr2line \
109 ${bindir}/eu-ld \
110 ${bindir}/eu-nm \
111 ${bindir}/eu-readelf \
112 ${bindir}/eu-size \
113 ${bindir}/eu-strip"
114
115FILES_libelf = "${libdir}/libelf-${PV}.so ${libdir}/libelf.so.*"
116FILES_libasm = "${libdir}/libasm-${PV}.so ${libdir}/libasm.so.*"
117FILES_libdw = "${libdir}/libdw-${PV}.so ${libdir}/libdw.so.* ${libdir}/elfutils/lib*"
118# Some packages have the version preceeding the .so instead properly
119# versioned .so.<version>, so we need to reorder and repackage.
120#FILES_${PN} += "${libdir}/*-${PV}.so ${base_libdir}/*-${PV}.so"
121#FILES_SOLIBSDEV = "${libdir}/libasm.so ${libdir}/libdw.so ${libdir}/libelf.so"
122
123# The package contains symlinks that trip up insane
124INSANE_SKIP_${MLPREFIX}libdw = "dev-so"
125# The nlist binary in the tests uses explicitly minimal compiler flags
126INSANE_SKIP_${PN}-ptest += "ldflags"
127
128# avoid stripping some generated binaries otherwise some of the tests such as test-nlist,
129# run-strip-reloc.sh, run-strip-strmerge.sh and so on will fail
130INHIBIT_PACKAGE_STRIP_FILES = "\
131 ${PKGD}${PTEST_PATH}/tests/test-nlist \
132 ${PKGD}${PTEST_PATH}/tests/elfstrmerge \
133 ${PKGD}${PTEST_PATH}/tests/backtrace-child \
134 ${PKGD}${PTEST_PATH}/tests/backtrace-data \
135 ${PKGD}${PTEST_PATH}/tests/backtrace-dwarf \
136 ${PKGD}${PTEST_PATH}/tests/deleted \
137 ${PKGD}${PTEST_PATH}/src/strip \
138 ${PKGD}${PTEST_PATH}/src/addr2line \
139 ${PKGD}${PTEST_PATH}/src/elfcmp \
140 ${PKGD}${PTEST_PATH}/src/objdump \
141 ${PKGD}${PTEST_PATH}/src/readelf \
142 ${PKGD}${PTEST_PATH}/src/nm \
143 ${PKGD}${PTEST_PATH}/src/elflint \
144 ${PKGD}${PTEST_PATH}/src/elfclassify \
145 ${PKGD}${PTEST_PATH}/src/stack \
146 ${PKGD}${PTEST_PATH}/src/unstrip \
147 ${PKGD}${PTEST_PATH}/libelf/libelf.so \
148 ${PKGD}${PTEST_PATH}/libdw/libdw.so \
149 ${PKGD}${PTEST_PATH}/libasm/libasm.so \
150 ${PKGD}${PTEST_PATH}/backends/libebl_i386.so \
151 ${PKGD}${PTEST_PATH}/backends/libebl_x86_64.so \
152"
153
154PRIVATE_LIBS_${PN}-ptest = "libdw.so.1 libelf.so.1 libasm.so.1"
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2024-10-06 18:31:33 +0000