diff options
author | Robert Yang <liezhi.yang@windriver.com> | 2015-07-08 00:23:47 -0700 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2015-07-09 18:00:18 +0100 |
commit | f9ac3f3e200e4fd0dfe0f45ddc606ce945ea0143 (patch) | |
tree | 1df34d2b324d1f23a136f58509912ea892311c61 /meta/recipes-devtools/elfutils/elfutils_0.163.bb | |
parent | d32b383c3a7af0212cf6bfc942f4f8d6ae08d986 (diff) | |
download | poky-f9ac3f3e200e4fd0dfe0f45ddc606ce945ea0143.tar.gz |
elfutils: 0.162 -> 0.163
(From OE-Core rev: cb8fc7521cdaaa7b8f82a0c6dfc6526778c99099)
Signed-off-by: Robert Yang <liezhi.yang@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-devtools/elfutils/elfutils_0.163.bb')
-rw-r--r-- | meta/recipes-devtools/elfutils/elfutils_0.163.bb | 96 |
1 files changed, 96 insertions, 0 deletions
diff --git a/meta/recipes-devtools/elfutils/elfutils_0.163.bb b/meta/recipes-devtools/elfutils/elfutils_0.163.bb new file mode 100644 index 0000000000..b34bfdd4b9 --- /dev/null +++ b/meta/recipes-devtools/elfutils/elfutils_0.163.bb | |||
@@ -0,0 +1,96 @@ | |||
1 | SUMMARY = "Utilities and libraries for handling compiled object files" | ||
2 | HOMEPAGE = "https://fedorahosted.org/elfutils" | ||
3 | SECTION = "base" | ||
4 | LICENSE = "(GPLv3 & Elfutils-Exception)" | ||
5 | LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504" | ||
6 | DEPENDS = "libtool bzip2 zlib virtual/libintl" | ||
7 | |||
8 | SRC_URI = "https://fedorahosted.org/releases/e/l/elfutils/${PV}/${BP}.tar.bz2" | ||
9 | |||
10 | SRC_URI[md5sum] = "77ce87f259987d2e54e4d87b86cbee41" | ||
11 | SRC_URI[sha256sum] = "7c774f1eef329309f3b05e730bdac50013155d437518a2ec0e24871d312f2e23" | ||
12 | |||
13 | SRC_URI += "\ | ||
14 | file://mempcpy.patch \ | ||
15 | file://dso-link-change.patch \ | ||
16 | file://Fix_elf_cvt_gunhash.patch \ | ||
17 | file://fixheadercheck.patch \ | ||
18 | file://0001-elf_getarsym-Silence-Werror-maybe-uninitialized-fals.patch \ | ||
19 | file://0001-remove-the-unneed-checking.patch \ | ||
20 | " | ||
21 | |||
22 | # pick the patch from debian | ||
23 | # http://ftp.de.debian.org/debian/pool/main/e/elfutils/elfutils_0.159-4.debian.tar.xz | ||
24 | SRC_URI += "\ | ||
25 | file://redhat-portability.diff \ | ||
26 | file://hppa_backend.diff \ | ||
27 | file://arm_backend.diff \ | ||
28 | file://mips_backend.diff \ | ||
29 | file://m68k_backend.diff \ | ||
30 | file://testsuite-ignore-elflint.diff \ | ||
31 | file://scanf-format.patch \ | ||
32 | file://mips_readelf_w.patch \ | ||
33 | file://arm_func_value.patch \ | ||
34 | file://arm_unwind_ret_mask.patch \ | ||
35 | file://non_linux.patch \ | ||
36 | " | ||
37 | |||
38 | # Only apply when building uclibc based target recipe | ||
39 | SRC_URI_append_libc-uclibc = " file://uclibc-support-for-elfutils-0.161.patch" | ||
40 | |||
41 | # The buildsystem wants to generate 2 .h files from source using a binary it just built, | ||
42 | # which can not pass the cross compiling, so let's work around it by adding 2 .h files | ||
43 | # along with the do_configure_prepend() | ||
44 | |||
45 | SRC_URI += "\ | ||
46 | file://i386_dis.h \ | ||
47 | file://x86_64_dis.h \ | ||
48 | " | ||
49 | inherit autotools gettext | ||
50 | |||
51 | EXTRA_OECONF = "--program-prefix=eu- --without-lzma" | ||
52 | EXTRA_OECONF_append_class-native = " --without-bzlib" | ||
53 | EXTRA_OECONF_append_libc-uclibc = " --enable-uclibc" | ||
54 | |||
55 | do_configure_prepend() { | ||
56 | sed -i '/^i386_dis.h:/,+4 {/.*/d}' ${S}/libcpu/Makefile.am | ||
57 | |||
58 | cp ${WORKDIR}/*dis.h ${S}/libcpu | ||
59 | } | ||
60 | |||
61 | do_install_append() { | ||
62 | if [ "${TARGET_ARCH}" != "x86_64" ] && [ -z `echo "${TARGET_ARCH}"|grep 'i.86'` ];then | ||
63 | rm ${D}${bindir}/eu-objdump | ||
64 | fi | ||
65 | } | ||
66 | |||
67 | # we can not build complete elfutils when using uclibc | ||
68 | # but some recipes e.g. gcc 4.5 depends on libelf so we | ||
69 | # build only libelf for uclibc case | ||
70 | |||
71 | EXTRA_OEMAKE_libc-uclibc = "-C libelf" | ||
72 | EXTRA_OEMAKE_class-native = "" | ||
73 | EXTRA_OEMAKE_class-nativesdk = "" | ||
74 | |||
75 | BBCLASSEXTEND = "native nativesdk" | ||
76 | |||
77 | # Package utilities separately | ||
78 | PACKAGES =+ "${PN}-binutils libelf libasm libdw" | ||
79 | FILES_${PN}-binutils = "\ | ||
80 | ${bindir}/eu-addr2line \ | ||
81 | ${bindir}/eu-ld \ | ||
82 | ${bindir}/eu-nm \ | ||
83 | ${bindir}/eu-readelf \ | ||
84 | ${bindir}/eu-size \ | ||
85 | ${bindir}/eu-strip" | ||
86 | |||
87 | FILES_libelf = "${libdir}/libelf-${PV}.so ${libdir}/libelf.so.*" | ||
88 | FILES_libasm = "${libdir}/libasm-${PV}.so ${libdir}/libasm.so.*" | ||
89 | FILES_libdw = "${libdir}/libdw-${PV}.so ${libdir}/libdw.so.* ${libdir}/elfutils/lib*" | ||
90 | # Some packages have the version preceeding the .so instead properly | ||
91 | # versioned .so.<version>, so we need to reorder and repackage. | ||
92 | #FILES_${PN} += "${libdir}/*-${PV}.so ${base_libdir}/*-${PV}.so" | ||
93 | #FILES_SOLIBSDEV = "${libdir}/libasm.so ${libdir}/libdw.so ${libdir}/libelf.so" | ||
94 | |||
95 | # The package contains symlinks that trip up insane | ||
96 | INSANE_SKIP_${MLPREFIX}libdw = "dev-so" | ||