cmake: Upgrade to 3.9.3 release

This upgrades CMake from 3.8.2 to 3.9.3 release. The Copyright.txt
file checksum change was due the addition of a new contributor on the
contributors list.

(From OE-Core rev: 053ad4bbcb72a1783c7928c2f86285c15472314f)

Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 38 insertions, 0 deletions

diff --git a/meta/recipes-devtools/cmake/cmake-native_3.9.3.bb b/meta/recipes-devtools/cmake/cmake-native_3.9.3.bb
new file mode 100644
index 0000000000..e55e8b1cf6
--- /dev/null
+++ b/meta/recipes-devtools/cmake/cmake-native_3.9.3.bb
@@ -0,0 +1,38 @@
+require cmake.inc
+inherit native
+
+DEPENDS += "bzip2-replacement-native expat-native xz-native zlib-native curl-native"
+
+SRC_URI += "\
+    file://cmlibarchive-disable-ext2fs.patch \
+"
+
+B = "${WORKDIR}/build"
+do_configure[cleandirs] = "${B}"
+
+# Disable ccmake since we don't depend on ncurses
+CMAKE_EXTRACONF = "\
+    -DCMAKE_LIBRARY_PATH=${STAGING_LIBDIR_NATIVE} \
+    -DBUILD_CursesDialog=0 \
+    -DCMAKE_USE_SYSTEM_LIBRARIES=1 \
+    -DCMAKE_USE_SYSTEM_LIBRARY_JSONCPP=0 \
+    -DCMAKE_USE_SYSTEM_LIBRARY_LIBARCHIVE=0 \
+    -DCMAKE_USE_SYSTEM_LIBRARY_LIBUV=0 \
+    -DCMAKE_USE_SYSTEM_LIBRARY_LIBRHASH=0 \
+    -DENABLE_ACL=0 -DHAVE_ACL_LIBACL_H=0 \
+    -DHAVE_SYS_ACL_H=0 \
+"
+
+do_configure () {
+        ${S}/configure --verbose --prefix=${prefix} -- ${CMAKE_EXTRACONF}
+}
+
+do_compile() {
+        oe_runmake
+}
+
+do_install() {
+        oe_runmake 'DESTDIR=${D}' install
+}
+
+do_compile[progress] = "percent"