binutils: Upgrade to binutils 2.32

Changes
https://sourceware.org/ml/binutils/2019-02/msg00010.html

0007-Add-the-armv5e-architecture-to-binutils.patch is dropped since we
armv5 is not a used option anymore in OE armv5te is default, and gcc9
will drop it completely anyway

CVE patches were backports from master which is already past of 2.32
release

Other dropped patches were partial or full backports as well

(From OE-Core rev: b71294c4decf35d544a2c8adb4e67d141841fc68)

Signed-off-by: Khem Raj <raj.khem@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 49 insertions, 0 deletions

diff --git a/meta/recipes-devtools/binutils/binutils_2.32.bb b/meta/recipes-devtools/binutils/binutils_2.32.bb
new file mode 100644
index 0000000000..51a9748906
--- /dev/null
+++ b/meta/recipes-devtools/binutils/binutils_2.32.bb
@@ -0,0 +1,49 @@
+require binutils.inc
+require binutils-${PV}.inc
+
+DEPENDS += "flex bison zlib"
+
+EXTRA_OECONF += "--with-sysroot=/ \
+                --enable-install-libbfd \
+                --enable-install-libiberty \
+                --enable-shared \
+                --with-system-zlib \
+                "
+
+EXTRA_OEMAKE_append_libc-musl = "\
+                                 gt_cv_func_gnugettext1_libc=yes \
+                                 gt_cv_func_gnugettext2_libc=yes \
+                                "
+EXTRA_OECONF_class-native = "--enable-targets=all \
+                             --enable-64-bit-bfd \
+                             --enable-install-libiberty \
+                             --enable-install-libbfd \
+                             --disable-werror"
+
+do_install_class-native () {
+        autotools_do_install
+
+        # Install the libiberty header
+        install -d ${D}${includedir}
+        install -m 644 ${S}/include/ansidecl.h ${D}${includedir}
+        install -m 644 ${S}/include/libiberty.h ${D}${includedir}
+
+        # We only want libiberty, libbfd and libopcodes
+        rm -rf ${D}${bindir}
+        rm -rf ${D}${prefix}/${TARGET_SYS}
+        rm -rf ${D}${prefix}/lib/ldscripts
+        rm -rf ${D}${prefix}/share/info
+        rm -rf ${D}${prefix}/share/locale
+        rm -rf ${D}${prefix}/share/man
+        rmdir ${D}${prefix}/share || :
+        rmdir ${D}/${libdir}/gcc-lib || :
+        rmdir ${D}/${libdir}64/gcc-lib || :
+        rmdir ${D}/${libdir} || :
+        rmdir ${D}/${libdir}64 || :
+}
+
+# Split out libbfd-*.so so including perf doesn't include extra stuff
+PACKAGE_BEFORE_PN += "libbfd"
+FILES_libbfd = "${libdir}/libbfd-*.so"
+
+BBCLASSEXTEND = "native nativesdk"