automake: update to upstream version 1.12.6

python-libdir.patch and py-compile-only-optimized-byte-code.patch
updated to apply to new codebase.

(From OE-Core rev: f2a530be5941ddf708720b920d0213d7d3928cd1)

Signed-off-by: Marko Lindqvist <cazfi74@gmail.com>
Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 49 insertions, 0 deletions

diff --git a/meta/recipes-devtools/automake/automake_1.12.6.bb b/meta/recipes-devtools/automake/automake_1.12.6.bb
new file mode 100644
index 0000000000..59bbdd8bfd
--- /dev/null
+++ b/meta/recipes-devtools/automake/automake_1.12.6.bb
@@ -0,0 +1,49 @@
+require automake.inc
+LICENSE="GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe" 
+DEPENDS_class-native = "autoconf-native"
+
+RDEPENDS_${PN} += "\
+    autoconf \
+    perl \
+    perl-module-bytes \
+    perl-module-data-dumper \
+    perl-module-strict \
+    perl-module-text-parsewords \
+    perl-module-thread-queue \
+    perl-module-threads \
+    perl-module-vars "
+
+RDEPENDS_${PN}_class-native = "autoconf-native perl-native-runtime"
+
+PATHFIXPATCH = "file://path_prog_fixes.patch"
+PATHFIXPATCH_class-native = ""
+PATHFIXPATCH_class-nativesdk = ""
+
+SRC_URI += "${PATHFIXPATCH} \
+            file://prefer-cpio-over-pax-for-ustar-archives.patch \
+            file://python-libdir.patch \
+            file://py-compile-compile-only-optimized-byte-code.patch \
+            file://buildtest.patch"
+
+SRC_URI[md5sum] = "199d39ece2e6070d64ac20d45ac86026"
+SRC_URI[sha256sum] = "0cbe570db487908e70af7119da85ba04f7e28656b26f717df0265ae08defd9ef"
+
+PR = "r0"
+
+do_install () {
+    oe_runmake 'DESTDIR=${D}' install
+    install -d ${D}${datadir}
+
+    # Some distros have both /bin/perl and /usr/bin/perl, but we set perl location
+    # for target as /usr/bin/perl, so fix it to /usr/bin/perl.
+    for i in aclocal aclocal-1.12 automake automake-1.12; do
+        if [ -f ${D}${bindir}/$i ]; then
+            sed -i -e '1s,#!.*perl,#! ${USRBINPATH}/perl,' \
+            -e 's,exec .*/bin/perl \(.*\) exec .*/bin/perl \(.*\),exec ${USRBINPATH}/perl \1 exec ${USRBINPATH}/perl \2,' \
+            ${D}${bindir}/$i
+        fi
+    done
+}
+
+BBCLASSEXTEND = "native nativesdk"