automake: upgrade to 1.12.3

(From OE-Core rev: 1110da87a2395e1d516f092553e6ed542bb34805)

Signed-off-by: Constantin Musca <constantinx.musca@intel.com>
Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 62 insertions, 0 deletions

diff --git a/meta/recipes-devtools/automake/automake_1.12.3.bb b/meta/recipes-devtools/automake/automake_1.12.3.bb
new file mode 100644
index 0000000000..25069d72b5
--- /dev/null
+++ b/meta/recipes-devtools/automake/automake_1.12.3.bb
@@ -0,0 +1,62 @@
+require automake.inc
+LICENSE="GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe" 
+DEPENDS_virtclass-native = "autoconf-native"
+
+RDEPENDS_${PN} += "\
+    autoconf \
+    perl \
+    perl-module-bytes \
+    perl-module-constant \
+    perl-module-cwd \
+    perl-module-data-dumper \
+    perl-module-dynaloader \
+    perl-module-errno \
+    perl-module-exporter-heavy \
+    perl-module-file-basename \
+    perl-module-file-compare \
+    perl-module-file-copy \
+    perl-module-file-glob \
+    perl-module-file-spec-unix \
+    perl-module-file-stat \
+    perl-module-getopt-long \
+    perl-module-io \
+    perl-module-io-file \
+    perl-module-posix \
+    perl-module-strict \
+    perl-module-text-parsewords \
+    perl-module-vars "
+
+RDEPENDS_${PN}_virtclass-native = "autoconf-native perl-native-runtime"
+RDEPENDS_${PN}_virtclass-nativesdk = "nativesdk-autoconf"
+
+PATHFIXPATCH = "file://path_prog_fixes.patch"
+PATHFIXPATCH_virtclass-native = ""
+PATHFIXPATCH_virtclass-nativesdk = ""
+
+SRC_URI += "${PATHFIXPATCH} \
+            file://prefer-cpio-over-pax-for-ustar-archives.patch \
+            file://python-libdir.patch \
+            file://py-compile-compile-only-optimized-byte-code.patch"
+
+SRC_URI[md5sum] = "d2af8484de94cdee16d89c50aaa1c729"
+SRC_URI[sha256sum] = "095ffaa3ac887d1eb3511bf13d7f1fc9ec0503c6a06aeae05c93730cdda9a5a0"
+
+PR = "r0"
+
+do_install () {
+    oe_runmake 'DESTDIR=${D}' install
+    install -d ${D}${datadir}
+
+    # Some distros have both /bin/perl and /usr/bin/perl, but we set perl location
+    # for target as /usr/bin/perl, so fix it to /usr/bin/perl.
+    for i in aclocal aclocal-1.12 automake automake-1.12; do
+        if [ -f ${D}${bindir}/$i ]; then
+            sed -i -e '1s,#!.*perl,#! ${USRBINPATH}/perl,' \
+            -e 's,exec .*/bin/perl \(.*\) exec .*/bin/perl \(.*\),exec ${USRBINPATH}/perl \1 exec ${USRBINPATH}/perl \2,' \
+            ${D}${bindir}/$i
+        fi
+    done
+}
+
+BBCLASSEXTEND = "native nativesdk"