util-linux: Update to 2.20.1

Add patch remove setting CC, LD and LDFLAGS on commandline
since they are passed correctly via configure. Those setting
also caused the configure information about -std=gnu99 from
being passed correctly.

Removed patch that was fixed upstream
Added scanf configuration, since this is a cross-compile target check

libuuid removed an API that e2fsprogs uuidd used (uuid__generate_*),
thus we disable it in this patch and will now provide uuidd from
util-linux.

See http://sourceforge.net/projects/e2fsprogs/forums/forum/7053/topic/4639484

(From OE-Core rev: fdaf4e791fcacb48ea430ec768ad9a6919c65ce0)

Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 49 insertions, 0 deletions

diff --git a/meta/recipes-core/util-linux/util-linux_2.20.1.bb b/meta/recipes-core/util-linux/util-linux_2.20.1.bb
new file mode 100644
index 0000000000..a569131eab
--- /dev/null
+++ b/meta/recipes-core/util-linux/util-linux_2.20.1.bb
@@ -0,0 +1,49 @@
+MAJOR_VERSION = "2.20"
+PR = "r0"
+require util-linux.inc
+
+# note that `lscpu' is under GPLv3+
+LICENSE_util-linux-lscpu = "GPLv3+"
+
+SRC_URI += "file://util-linux-ng-replace-siginterrupt.patch \
+            file://util-linux-ng-2.16-mount_lock_path.patch \
+            file://uclibc-__progname-conflict.patch \      
+"
+
+SRC_URI[md5sum] = "079b37517fd4e002a2e6e992e8b4e361"
+SRC_URI[sha256sum] = "d16ebcda3e64ab88ed363d9c1242cdb7ccfd5e1f56c83d0c3b0638c23793bbe0"
+
+# Only lscpu part is gplv3; rest of the code is not, 
+# so take out the lscpu parts while running non-gplv3 build.
+python () {
+    d.setVar("REMOVELSCPU", "no")
+    if (d.getVar("INCOMPATIBLE_LICENSE", True) or "").find("GPLv3") != -1:
+        # avoid GPLv3 
+        d.setVar("REMOVELSCPU", "yes")
+        packages = (d.getVar("PACKAGES", False) or "").split()
+        if "util-linux-lscpu" in packages:
+            packages.remove("util-linux-lscpu")
+        d.setVar("PACKAGES", " ".join(packages))
+
+        src_uri = (d.getVar("SRC_URI", False) or "").split()
+        src_uri.append("file://remove-lscpu.patch")
+        d.setVar("SRC_URI", " ".join(src_uri))
+}       
+
+do_remove_lscpu() {
+    if [ "x${REMOVELSCPU}" = "xyes" ]; then
+         rm -f sys-utils/lscpu.c sys-utils/lscpu.1
+         rm -rf tests/ts/lscpu tests/expected/lscpu
+    fi
+}
+
+addtask remove_lscpu before do_configure after do_patch
+
+# fallocate is glibc 2.10, fallocate64 is glibc 2.11
+# we need to disable it for older versions
+EXTRA_OECONF += "ac_cv_func_fallocate=no scanf_cv_type_modifier=as"
+EXTRA_OECONF_virtclass-native += "--disable-fallocate --disable-use-tty-group"
+
+do_install_append () {
+        sed -i -e '1s,.*,#!${bindir}/env perl,' ${D}${bindir}/chkdupexe
+}