Major layout change to the packages directory

Having one monolithic packages directory makes it hard to find things
and is generally overwhelming. This commit splits it into several
logical sections roughly based on function, recipes.txt gives more
information about the classifications used.

The opportunity is also used to switch from "packages" to "recipes"
as used in OpenEmbedded as the term "packages" can be confusing to
people and has many different meanings.

Not all recipes have been classified yet, this is just a first pass
at separating things out. Some packages are moved to meta-extras as
they're no longer actively used or maintained.

Signed-off-by: Richard Purdie <rpurdie@linux.intel.com>

1 files changed, 58 insertions, 0 deletions

diff --git a/meta/recipes-core/udev/udev_092.bb b/meta/recipes-core/udev/udev_092.bb
new file mode 100644
index 0000000000..0e94d1f6c8
--- /dev/null
+++ b/meta/recipes-core/udev/udev_092.bb
@@ -0,0 +1,58 @@
+DESCRIPTION = "udev is a daemon which dynamically creates and removes device nodes from \
+/dev/, handles hotplug events and loads drivers at boot time. It replaces \
+the hotplug package and requires a kernel not older than 2.6.12."
+RPROVIDES_${PN} = "hotplug"
+
+PR = "r17"
+
+SRC_URI = "http://kernel.org/pub/linux/utils/kernel/hotplug/udev-${PV}.tar.gz \
+           file://noasmlinkage.patch;patch=1 \
+           file://flags.patch;patch=1 \
+           file://udevsynthesize.patch;patch=1 \
+           file://udevsynthesize.sh \
+           file://arm_inotify_fix.patch;patch=1 \
+           "
+
+SRC_URI_append_h2200 = " file://50-hostap_cs.rules "
+PACKAGE_ARCH_h2200 = "h2200"
+
+require udev.inc
+
+INITSCRIPT_PARAMS = "start 03 S ."
+
+FILES_${PN} += "${base_libdir}/udev/*"
+FILES_${PN}-dbg += "${base_libdir}/udev/.debug"
+UDEV_EXTRAS = "extras/firmware/ extras/scsi_id/ extras/volume_id/ extras/run_directory/"
+EXTRA_OEMAKE += "libudevdir=/lib/udev libdir=${base_libdir} prefix="
+
+do_install () {
+        install -d ${D}${usrsbindir} \
+                   ${D}${sbindir}
+        oe_runmake 'DESTDIR=${D}' INSTALL=install install
+        install -d ${D}${sysconfdir}/init.d
+        install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/udev
+        install -m 0755 ${WORKDIR}/udev-cache ${D}${sysconfdir}/init.d/udev-cache
+
+        install -d ${D}${sysconfdir}/udev/rules.d/
+
+        install -m 0644 ${WORKDIR}/local.rules         ${D}${sysconfdir}/udev/rules.d/local.rules
+        install -m 0644 ${WORKDIR}/permissions.rules   ${D}${sysconfdir}/udev/rules.d/permissions.rules
+        install -m 0644 ${WORKDIR}/udev.rules          ${D}${sysconfdir}/udev/rules.d/udev.rules
+        install -m 0644 ${WORKDIR}/links.conf          ${D}${sysconfdir}/udev/links.conf
+        if [ "${UDEV_DEVFS_RULES}" = "1" ]; then
+                install -m 0644 ${WORKDIR}/devfs-udev.rules ${D}${sysconfdir}/udev/rules.d/devfs-udev.rules
+        fi
+
+        install -d ${D}${sysconfdir}/udev/scripts/
+
+        install -m 0755 ${WORKDIR}/mount.sh ${D}${sysconfdir}/udev/scripts/mount.sh
+        install -m 0755 ${WORKDIR}/network.sh ${D}${sysconfdir}/udev/scripts
+
+        install -d ${D}${base_libdir}/udev/
+        install -m 0755 ${S}/udevsynthesize ${D}${base_libdir}/udev/udevsynthesize
+        install -m 0755 ${WORKDIR}/udevsynthesize.sh ${D}${sbindir}/udevsynthesize
+}
+
+do_install_append_h2200() {
+        install -m 0644 ${WORKDIR}/50-hostap_cs.rules         ${D}${sysconfdir}/udev/rules.d/50-hostap_cs.rules
+}