uclibc: Upgrade recipes from 0.9.32 -> 0.9.33

Prefer 0.9.33 by default
Delete recipes for 0.9.32

(From OE-Core rev: 5d2c0b051072b3cee510dcad8d20fb26d3843f62)

Signed-off-by: Khem Raj <raj.khem@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 39 insertions, 0 deletions

diff --git a/meta/recipes-core/uclibc/uclibc-initial_0.9.33.bb b/meta/recipes-core/uclibc/uclibc-initial_0.9.33.bb
new file mode 100644
index 0000000000..234b810074
--- /dev/null
+++ b/meta/recipes-core/uclibc/uclibc-initial_0.9.33.bb
@@ -0,0 +1,39 @@
+SECTION = "base"
+require uclibc_${PV}.bb
+
+DEPENDS = "linux-libc-headers ncurses-native virtual/${TARGET_PREFIX}gcc-initial"
+PROVIDES = "virtual/${TARGET_PREFIX}libc-initial"
+
+PACKAGES = ""
+PACKAGES_DYNAMIC = ""
+
+STAGINGCC = "gcc-cross-initial"
+STAGINGCC_virtclass-nativesdk = "gcc-crosssdk-initial"
+
+do_install() {
+        # Install initial headers into the cross dir
+        make PREFIX=${D} DEVEL_PREFIX=${prefix}/ RUNTIME_PREFIX=/ \
+                install_headers install_startfiles
+        ${CC} -nostdlib -nostartfiles -shared -x c /dev/null \
+                -o lib/libc.so
+        ${CC} -nostdlib -nostartfiles -shared -x c /dev/null \
+                -o lib/libm.so
+        install -d ${D}${libdir}
+        install -m 755 lib/lib[cm].so ${D}${libdir}
+        # add links to linux-libc-headers: gcc-{cross,crossdk}-intermediate need this.
+        for t in linux asm asm-generic; do
+                if [ -d ${D}${includedir}/$t ]; then
+                    rm -rf ${D}${includedir}/$t
+                fi
+                ln -sf ${STAGING_DIR_TARGET}${includedir}/$t ${D}${includedir}/
+        done
+}
+do_compile() {
+        :
+}
+
+do_siteconfig () {
+        :
+}
+
+do_populate_sysroot[sstate-outputdirs] = "${STAGING_DIR_TCBOOTSTRAP}"