ifupdown: update 0.8.22 -> 0.8.35

Remove inet-6-.defn-fix-inverted-checks-for-loopback.patch as
it is difficult to rebase and not clear if still necessary.

(From OE-Core rev: 127cc7193a4d696ca7829fc0b36624ef8a1bc312)

Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 47 insertions, 0 deletions

diff --git a/meta/recipes-core/ifupdown/ifupdown_0.8.35.bb b/meta/recipes-core/ifupdown/ifupdown_0.8.35.bb
new file mode 100644
index 0000000000..0de97fe372
--- /dev/null
+++ b/meta/recipes-core/ifupdown/ifupdown_0.8.35.bb
@@ -0,0 +1,47 @@
+SUMMARY = "ifupdown: basic ifup and ifdown used by initscripts"
+DESCRIPTION = "High level tools to configure network interfaces \
+This package provides the tools ifup and ifdown which may be used to \
+configure (or, respectively, deconfigure) network interfaces, based on \
+the file /etc/network/interfaces."
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
+
+SRC_URI = "git://salsa.debian.org/debian/ifupdown.git;protocol=https \
+           file://defn2-c-man-don-t-rely-on-dpkg-architecture-to-set-a.patch \
+           file://99_network \
+           file://0001-Define-FNM_EXTMATCH-for-musl.patch \
+           file://0001-Makefile-do-not-use-dpkg-for-determining-OS-type.patch \
+           "
+SRCREV = "4af76318cfc57f8e4a44d357104188666213bd4b"
+
+S = "${WORKDIR}/git"
+
+
+inherit update-alternatives
+
+do_compile () {
+        chmod a+rx *.pl *.sh
+        oe_runmake 'CC=${CC}' "CFLAGS=${CFLAGS} -Wall -W -D'IFUPDOWN_VERSION=\"${PV}\"'"
+}
+
+do_install () {
+        install -d ${D}${mandir}/man8 \
+                  ${D}${mandir}/man5 \
+                  ${D}${base_sbindir}
+
+        # If volatiles are used, then we'll also need /run/network there too.
+        install -d ${D}/etc/default/volatiles
+        install -m 0644 ${WORKDIR}/99_network ${D}/etc/default/volatiles
+
+        install -m 0755 ifup ${D}${base_sbindir}/
+        ln ${D}${base_sbindir}/ifup ${D}${base_sbindir}/ifdown
+        install -m 0644 ifup.8 ${D}${mandir}/man8
+        install -m 0644 interfaces.5 ${D}${mandir}/man5
+        cd ${D}${mandir}/man8 && ln -s ifup.8 ifdown.8
+}
+
+ALTERNATIVE_PRIORITY = "100"
+ALTERNATIVE_${PN} = "ifup ifdown"
+
+ALTERNATIVE_LINK_NAME[ifup] = "${base_sbindir}/ifup"
+ALTERNATIVE_LINK_NAME[ifdown] = "${base_sbindir}/ifdown"