ifupdown: upgrade to 0.8.16

Refreshed the following patch:
 * inet-6-.defn-fix-inverted-checks-for-loopback.patch

(From OE-Core rev: 1daa09aa82c528dcc7682553dd6704a93aafdc88)

Signed-off-by: Maxin B. John <maxin.john@intel.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 49 insertions, 0 deletions

diff --git a/meta/recipes-core/ifupdown/ifupdown_0.8.16.bb b/meta/recipes-core/ifupdown/ifupdown_0.8.16.bb
new file mode 100644
index 0000000000..eb8426cb97
--- /dev/null
+++ b/meta/recipes-core/ifupdown/ifupdown_0.8.16.bb
@@ -0,0 +1,49 @@
+SUMMARY = "ifupdown: basic ifup and ifdown used by initscripts"
+DESCRIPTION = "High level tools to configure network interfaces \
+This package provides the tools ifup and ifdown which may be used to \
+configure (or, respectively, deconfigure) network interfaces, based on \
+the file /etc/network/interfaces."
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
+
+SRC_URI = "git://anonscm.debian.org/git/collab-maint/ifupdown.git \
+           file://defn2-c-man-don-t-rely-on-dpkg-architecture-to-set-a.patch \
+           file://inet-6-.defn-fix-inverted-checks-for-loopback.patch \
+           file://99_network \
+          "
+SRCREV = "11b9f99f7ecc7052497e6786156cfed531f11823"
+
+S = "${WORKDIR}/git"
+
+
+inherit update-rc.d update-alternatives
+
+do_compile () {
+        chmod a+rx *.pl *.sh
+        oe_runmake 'CC=${CC}' "CFLAGS=${CFLAGS} -Wall -W -D'IFUPDOWN_VERSION=\"${PV}\"'"
+}
+
+do_install () {
+        install -d ${D}${mandir}/man8 \
+                  ${D}${mandir}/man5 \
+                  ${D}${base_sbindir}
+
+        # If volatiles are used, then we'll also need /run/network there too.
+        install -d ${D}/etc/default/volatiles
+        install -m 0644 ${WORKDIR}/99_network ${D}/etc/default/volatiles
+
+        install -m 0755 ifup ${D}${base_sbindir}/
+        ln ${D}${base_sbindir}/ifup ${D}${base_sbindir}/ifdown
+        install -m 0644 ifup.8 ${D}${mandir}/man8
+        install -m 0644 interfaces.5 ${D}${mandir}/man5
+        cd ${D}${mandir}/man8 && ln -s ifup.8 ifdown.8
+}
+
+ALTERNATIVE_PRIORITY = "100"
+ALTERNATIVE_${PN} = "ifup ifdown"
+
+ALTERNATIVE_LINK_NAME[ifup] = "${base_sbindir}/ifup"
+ALTERNATIVE_LINK_NAME[ifdown] = "${base_sbindir}/ifdown"
+
+INITSCRIPT_NAME = "ifup"
+INITSCRIPT_PARAMS = "start 39 S . stop 39 0 6 1 ."