diff options
author | Khem Raj <raj.khem@gmail.com> | 2017-08-03 07:03:20 -0700 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2017-08-13 09:27:37 +0100 |
commit | 476edb2b472b5dc35bf00b02a629db2ada512df3 (patch) | |
tree | 895f73139fb7e4c4cf9c6b89edc3b0b617cf9e0c /meta/recipes-core/glibc/glibc_2.26.bb | |
parent | ffe6130bf6c8eed4ce1cc137ead47c0e293d98d2 (diff) | |
download | poky-476edb2b472b5dc35bf00b02a629db2ada512df3.tar.gz |
glibc: Upgrade to 2.26 final release
(From OE-Core rev: d6a0bc57fa07d887a78aa8ed76e3bf4558dc5127)
Signed-off-by: Khem Raj <raj.khem@gmail.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-core/glibc/glibc_2.26.bb')
-rw-r--r-- | meta/recipes-core/glibc/glibc_2.26.bb | 143 |
1 files changed, 143 insertions, 0 deletions
diff --git a/meta/recipes-core/glibc/glibc_2.26.bb b/meta/recipes-core/glibc/glibc_2.26.bb new file mode 100644 index 0000000000..d453d8f9bf --- /dev/null +++ b/meta/recipes-core/glibc/glibc_2.26.bb | |||
@@ -0,0 +1,143 @@ | |||
1 | require glibc.inc | ||
2 | |||
3 | LIC_FILES_CHKSUM = "file://LICENSES;md5=e9a558e243b36d3209f380deb394b213 \ | ||
4 | file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \ | ||
5 | file://posix/rxspencer/COPYRIGHT;md5=dc5485bb394a13b2332ec1c785f5d83a \ | ||
6 | file://COPYING.LIB;md5=4fbd65380cdd255951079008b364516c" | ||
7 | |||
8 | DEPENDS += "gperf-native" | ||
9 | |||
10 | SRCREV ?= "1c9a5c270d8b66f30dcfaf1cb2d6cf39d3e18369" | ||
11 | |||
12 | SRCBRANCH ?= "release/${PV}/master" | ||
13 | |||
14 | GLIBC_GIT_URI ?= "git://sourceware.org/git/glibc.git" | ||
15 | UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>\d+\.\d+(\.\d+)*)" | ||
16 | |||
17 | SRC_URI = "${GLIBC_GIT_URI};branch=${SRCBRANCH};name=glibc \ | ||
18 | file://etc/ld.so.conf \ | ||
19 | file://generate-supported.mk \ | ||
20 | \ | ||
21 | ${NATIVESDKFIXES} \ | ||
22 | file://0005-fsl-e500-e5500-e6500-603e-fsqrt-implementation.patch \ | ||
23 | file://0006-readlib-Add-OECORE_KNOWN_INTERPRETER_NAMES-to-known-.patch \ | ||
24 | file://0007-ppc-sqrt-Fix-undefined-reference-to-__sqrt_finite.patch \ | ||
25 | file://0008-__ieee754_sqrt-f-are-now-inline-functions-and-call-o.patch \ | ||
26 | file://0009-Quote-from-bug-1443-which-explains-what-the-patch-do.patch \ | ||
27 | file://0010-eglibc-run-libm-err-tab.pl-with-specific-dirs-in-S.patch \ | ||
28 | file://0011-__ieee754_sqrt-f-are-now-inline-functions-and-call-o.patch \ | ||
29 | file://0012-sysdeps-gnu-configure.ac-handle-correctly-libc_cv_ro.patch \ | ||
30 | file://0013-Add-unused-attribute.patch \ | ||
31 | file://0014-yes-within-the-path-sets-wrong-config-variables.patch \ | ||
32 | file://0015-timezone-re-written-tzselect-as-posix-sh.patch \ | ||
33 | file://0016-Remove-bash-dependency-for-nscd-init-script.patch \ | ||
34 | file://0017-eglibc-Cross-building-and-testing-instructions.patch \ | ||
35 | file://0018-eglibc-Help-bootstrap-cross-toolchain.patch \ | ||
36 | file://0019-eglibc-Clear-cache-lines-on-ppc8xx.patch \ | ||
37 | file://0020-eglibc-Resolve-__fpscr_values-on-SH4.patch \ | ||
38 | file://0021-eglibc-Install-PIC-archives.patch \ | ||
39 | file://0022-eglibc-Forward-port-cross-locale-generation-support.patch \ | ||
40 | file://0023-Define-DUMMY_LOCALE_T-if-not-defined.patch \ | ||
41 | file://0024-elf-dl-deps.c-Make-_dl_build_local_scope-breadth-fir.patch \ | ||
42 | file://0025-locale-fix-hard-coded-reference-to-gcc-E.patch \ | ||
43 | file://0026-assert-Suppress-pedantic-warning-caused-by-statement.patch \ | ||
44 | " | ||
45 | |||
46 | NATIVESDKFIXES ?= "" | ||
47 | NATIVESDKFIXES_class-nativesdk = "\ | ||
48 | file://0001-nativesdk-glibc-Look-for-host-system-ld.so.cache-as-.patch \ | ||
49 | file://0002-nativesdk-glibc-Fix-buffer-overrun-with-a-relocated-.patch \ | ||
50 | file://0003-nativesdk-glibc-Raise-the-size-of-arrays-containing-.patch \ | ||
51 | file://0004-nativesdk-glibc-Allow-64-bit-atomics-for-x86.patch \ | ||
52 | " | ||
53 | |||
54 | S = "${WORKDIR}/git" | ||
55 | B = "${WORKDIR}/build-${TARGET_SYS}" | ||
56 | |||
57 | PACKAGES_DYNAMIC = "" | ||
58 | |||
59 | # the -isystem in bitbake.conf screws up glibc do_stage | ||
60 | BUILD_CPPFLAGS = "-I${STAGING_INCDIR_NATIVE}" | ||
61 | TARGET_CPPFLAGS = "-I${STAGING_DIR_TARGET}${includedir}" | ||
62 | |||
63 | GLIBC_BROKEN_LOCALES = "" | ||
64 | # | ||
65 | # We will skip parsing glibc when target system C library selection is not glibc | ||
66 | # this helps in easing out parsing for non-glibc system libraries | ||
67 | # | ||
68 | COMPATIBLE_HOST_libc-musl_class-target = "null" | ||
69 | |||
70 | EXTRA_OECONF = "--enable-kernel=${OLDEST_KERNEL} \ | ||
71 | --without-cvs --disable-profile \ | ||
72 | --disable-debug --without-gd \ | ||
73 | --enable-clocale=gnu \ | ||
74 | --enable-add-ons=libidn \ | ||
75 | --with-headers=${STAGING_INCDIR} \ | ||
76 | --without-selinux \ | ||
77 | --enable-obsolete-rpc \ | ||
78 | --enable-obsolete-nsl \ | ||
79 | --enable-tunables \ | ||
80 | --enable-bind-now \ | ||
81 | --enable-stack-protector=strong \ | ||
82 | --enable-stackguard-randomization \ | ||
83 | ${GLIBC_EXTRA_OECONF}" | ||
84 | |||
85 | EXTRA_OECONF += "${@get_libc_fpu_setting(bb, d)}" | ||
86 | EXTRA_OECONF += "${@bb.utils.contains('DISTRO_FEATURES', 'libc-inet-anl', '--enable-nscd', '--disable-nscd', d)}" | ||
87 | |||
88 | |||
89 | do_patch_append() { | ||
90 | bb.build.exec_func('do_fix_readlib_c', d) | ||
91 | } | ||
92 | |||
93 | do_fix_readlib_c () { | ||
94 | sed -i -e 's#OECORE_KNOWN_INTERPRETER_NAMES#${EGLIBC_KNOWN_INTERPRETER_NAMES}#' ${S}/elf/readlib.c | ||
95 | } | ||
96 | |||
97 | do_configure () { | ||
98 | # override this function to avoid the autoconf/automake/aclocal/autoheader | ||
99 | # calls for now | ||
100 | # don't pass CPPFLAGS into configure, since it upsets the kernel-headers | ||
101 | # version check and doesn't really help with anything | ||
102 | (cd ${S} && gnu-configize) || die "failure in running gnu-configize" | ||
103 | find ${S} -name "configure" | xargs touch | ||
104 | CPPFLAGS="" oe_runconf | ||
105 | } | ||
106 | |||
107 | rpcsvc = "bootparam_prot.x nlm_prot.x rstat.x \ | ||
108 | yppasswd.x klm_prot.x rex.x sm_inter.x mount.x \ | ||
109 | rusers.x spray.x nfs_prot.x rquota.x key_prot.x" | ||
110 | |||
111 | do_compile () { | ||
112 | # -Wl,-rpath-link <staging>/lib in LDFLAGS can cause breakage if another glibc is in staging | ||
113 | unset LDFLAGS | ||
114 | base_do_compile | ||
115 | ( | ||
116 | cd ${S}/sunrpc/rpcsvc | ||
117 | for r in ${rpcsvc}; do | ||
118 | h=`echo $r|sed -e's,\.x$,.h,'` | ||
119 | rm -f $h | ||
120 | ${B}/sunrpc/cross-rpcgen -h $r -o $h || bbwarn "${PN}: unable to generate header for $r" | ||
121 | done | ||
122 | ) | ||
123 | echo "Adjust ldd script" | ||
124 | if [ -n "${RTLDLIST}" ] | ||
125 | then | ||
126 | prevrtld=`cat ${B}/elf/ldd | grep "^RTLDLIST=" | sed 's#^RTLDLIST="\?\([^"]*\)"\?$#\1#'` | ||
127 | if [ "${prevrtld}" != "${RTLDLIST}" ] | ||
128 | then | ||
129 | sed -i ${B}/elf/ldd -e "s#^RTLDLIST=.*\$#RTLDLIST=\"${prevrtld} ${RTLDLIST}\"#" | ||
130 | fi | ||
131 | fi | ||
132 | |||
133 | } | ||
134 | |||
135 | # Use the host locale archive when built for nativesdk so that we don't need to | ||
136 | # ship a complete (100MB) locale set. | ||
137 | do_compile_prepend_class-nativesdk() { | ||
138 | echo "complocaledir=/usr/lib/locale" >> ${S}/configparms | ||
139 | } | ||
140 | |||
141 | require glibc-package.inc | ||
142 | |||
143 | BBCLASSEXTEND = "nativesdk" | ||