diff options
author | Chen Qi <Qi.Chen@windriver.com> | 2014-01-02 14:28:32 +0800 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2014-01-06 11:13:55 +0000 |
commit | 663dad63a3a0807266e62c64525f4e66c5651308 (patch) | |
tree | 3b610da11fb6dea5721f28715349bb9740ada7b1 /meta/recipes-core/coreutils/coreutils_8.22.bb | |
parent | e65fc0eb4d489ff0b950a85bb873d8324632e68b (diff) | |
download | poky-663dad63a3a0807266e62c64525f4e66c5651308.tar.gz |
coreutils: upgrade to 8.22
Upgrade coreutils to 8.22.
Changes since 8.21:
1) Remove the acl patch as it's not needed now.
2) Add a new patch to fix the following compile error.
"dummy-man: too many non-option arguments"
(From OE-Core rev: 144a48e34d17fd8736a482bae4ee69efc37b8a1f)
Signed-off-by: Chen Qi <Qi.Chen@windriver.com>
Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-core/coreutils/coreutils_8.22.bb')
-rw-r--r-- | meta/recipes-core/coreutils/coreutils_8.22.bb | 103 |
1 files changed, 103 insertions, 0 deletions
diff --git a/meta/recipes-core/coreutils/coreutils_8.22.bb b/meta/recipes-core/coreutils/coreutils_8.22.bb new file mode 100644 index 0000000000..6b222b5ae0 --- /dev/null +++ b/meta/recipes-core/coreutils/coreutils_8.22.bb | |||
@@ -0,0 +1,103 @@ | |||
1 | SUMMARY = "The basic file, shell and text manipulation utilities." | ||
2 | DESCRIPTION = "The GNU Core Utilities provide the basic file, shell and text \ | ||
3 | manipulation utilities. These are the core utilities which are expected to exist on \ | ||
4 | every system." | ||
5 | HOMEPAGE = "http://www.gnu.org/software/coreutils/" | ||
6 | BUGTRACKER = "http://debbugs.gnu.org/coreutils" | ||
7 | LICENSE = "GPLv3+" | ||
8 | LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504\ | ||
9 | file://src/ls.c;beginline=5;endline=16;md5=38b79785ca88537b75871782a2a3c6b8" | ||
10 | DEPENDS = "gmp libcap" | ||
11 | DEPENDS_class-native = "" | ||
12 | |||
13 | inherit autotools gettext | ||
14 | |||
15 | SRC_URI = "${GNU_MIRROR}/coreutils/${BP}.tar.xz \ | ||
16 | file://remove-usr-local-lib-from-m4.patch \ | ||
17 | file://dummy_help2man.patch \ | ||
18 | file://fix-for-dummy-man-usage.patch \ | ||
19 | " | ||
20 | |||
21 | SRC_URI[md5sum] = "8fb0ae2267aa6e728958adc38f8163a2" | ||
22 | SRC_URI[sha256sum] = "5b3e94998152c017e6c75d56b9b994188eb71bf46d4038a642cb9141f6ff1212" | ||
23 | |||
24 | EXTRA_OECONF_class-native = "--without-gmp" | ||
25 | EXTRA_OECONF_class-target = "--enable-install-program=arch" | ||
26 | |||
27 | # acl is not a default feature | ||
28 | # | ||
29 | PACKAGECONFIG_class-target ??= "${@base_contains('DISTRO_FEATURES', 'acl', 'acl', '', d)}" | ||
30 | PACKAGECONFIG_class-native ??= "" | ||
31 | |||
32 | # with, without, depends, rdepends | ||
33 | # | ||
34 | PACKAGECONFIG[acl] = "--enable-acl,--disable-acl,acl," | ||
35 | |||
36 | # [ df mktemp base64 gets a special treatment and is not included in this | ||
37 | bindir_progs = "arch basename chcon cksum comm csplit cut dir dircolors dirname du \ | ||
38 | env expand expr factor fmt fold groups head hostid id install \ | ||
39 | join link logname md5sum mkfifo nice nl nohup nproc od paste pathchk \ | ||
40 | pinky pr printenv printf ptx readlink realpath runcon seq sha1sum sha224sum sha256sum \ | ||
41 | sha384sum sha512sum shred shuf sort split stat stdbuf sum tac tail tee test timeout\ | ||
42 | tr truncate tsort tty unexpand uniq unlink uptime users vdir wc who whoami yes" | ||
43 | |||
44 | # hostname gets a special treatment and is not included in this | ||
45 | base_bindir_progs = "cat chgrp chmod chown cp date dd echo false kill ln ls mkdir \ | ||
46 | mknod mv pwd rm rmdir sleep stty sync touch true uname" | ||
47 | |||
48 | sbindir_progs= "chroot" | ||
49 | |||
50 | # Let aclocal use the relative path for the m4 file rather than the | ||
51 | # absolute since coreutils has a lot of m4 files, otherwise there might | ||
52 | # be an "Argument list too long" error when it is built in a long/deep | ||
53 | # directory. | ||
54 | acpaths = "-I ./m4" | ||
55 | |||
56 | # Deal with a separate builddir failure if src doesn't exist when creating version.c/version.h | ||
57 | do_compile_prepend () { | ||
58 | mkdir -p ${B}/src | ||
59 | } | ||
60 | |||
61 | do_install_append() { | ||
62 | for i in df mktemp base64; do mv ${D}${bindir}/$i ${D}${bindir}/$i.${BPN}; done | ||
63 | |||
64 | install -d ${D}${base_bindir} | ||
65 | [ "${base_bindir}" != "${bindir}" ] && for i in ${base_bindir_progs}; do mv ${D}${bindir}/$i ${D}${base_bindir}/$i.${BPN}; done | ||
66 | |||
67 | install -d ${D}${sbindir} | ||
68 | [ "${sbindir}" != "${bindir}" ] && for i in ${sbindir_progs}; do mv ${D}${bindir}/$i ${D}${sbindir}/$i.${BPN}; done | ||
69 | |||
70 | # [ requires special handling because [.coreutils will cause the sed stuff | ||
71 | # in update-alternatives to fail, therefore use lbracket - the name used | ||
72 | # for the actual source file. | ||
73 | mv ${D}${bindir}/[ ${D}${bindir}/lbracket.${BPN} | ||
74 | install -d ${D}${libdir}/coreutils | ||
75 | mv ${D}${libexecdir}/coreutils/libstdbuf.so ${D}${libdir}/coreutils | ||
76 | } | ||
77 | |||
78 | inherit update-alternatives | ||
79 | |||
80 | ALTERNATIVE_PRIORITY = "100" | ||
81 | ALTERNATIVE_${PN} = "lbracket ${bindir_progs} ${base_bindir_progs} ${sbindir_progs} base64 mktemp df" | ||
82 | |||
83 | ALTERNATIVE_LINK_NAME[base64] = "${base_bindir}/base64" | ||
84 | ALTERNATIVE_TARGET[base64] = "${bindir}/base64.${BPN}" | ||
85 | |||
86 | ALTERNATIVE_LINK_NAME[mktemp] = "${base_bindir}/mktemp" | ||
87 | ALTERNATIVE_TARGET[mktemp] = "${bindir}/mktemp.${BPN}" | ||
88 | |||
89 | ALTERNATIVE_LINK_NAME[df] = "${base_bindir}/df" | ||
90 | ALTERNATIVE_TARGET[df] = "${bindir}/df.${BPN}" | ||
91 | |||
92 | ALTERNATIVE_LINK_NAME[lbracket] = "${bindir}/[" | ||
93 | ALTERNATIVE_TARGET[lbracket] = "${bindir}/lbracket.${BPN}" | ||
94 | |||
95 | python __anonymous() { | ||
96 | for prog in d.getVar('base_bindir_progs', True).split(): | ||
97 | d.setVarFlag('ALTERNATIVE_LINK_NAME', prog, '%s/%s' % (d.getVar('base_bindir', True), prog)) | ||
98 | |||
99 | for prog in d.getVar('sbindir_progs', True).split(): | ||
100 | d.setVarFlag('ALTERNATIVE_LINK_NAME', prog, '%s/%s' % (d.getVar('sbindir', True), prog)) | ||
101 | } | ||
102 | |||
103 | BBCLASSEXTEND = "native" | ||