diff options
author | Yue Tao <Yue.Tao@windriver.com> | 2015-05-26 12:55:42 +0800 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2015-05-29 10:17:15 +0100 |
commit | 46bca1b82908a4bfca310b1d8d951c3331924c4d (patch) | |
tree | 435eaffaa59bf19bfe2b356409896980678efa98 /meta/recipes-connectivity/wpa-supplicant/wpa-supplicant_2.4.bb | |
parent | 2d2d5e69776113aa6d8b4b3204d5bc70310d3858 (diff) | |
download | poky-46bca1b82908a4bfca310b1d8d951c3331924c4d.tar.gz |
wpa-supplicant: upgrade to 2.4
1. upgrade to 2.4
2. update the checksum, and license checksum since date in it is changed
3. Backport a patch to fix CVE-2015-1863
4. remove two deprecated patches
(From OE-Core rev: fd0880c2b0958b72d641a6821ddd6d6790a92b7a)
Signed-off-by: Roy Li <rongqing.li@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-connectivity/wpa-supplicant/wpa-supplicant_2.4.bb')
-rw-r--r-- | meta/recipes-connectivity/wpa-supplicant/wpa-supplicant_2.4.bb | 110 |
1 files changed, 110 insertions, 0 deletions
diff --git a/meta/recipes-connectivity/wpa-supplicant/wpa-supplicant_2.4.bb b/meta/recipes-connectivity/wpa-supplicant/wpa-supplicant_2.4.bb new file mode 100644 index 0000000000..b7c7033d63 --- /dev/null +++ b/meta/recipes-connectivity/wpa-supplicant/wpa-supplicant_2.4.bb | |||
@@ -0,0 +1,110 @@ | |||
1 | SUMMARY = "Client for Wi-Fi Protected Access (WPA)" | ||
2 | HOMEPAGE = "http://hostap.epitest.fi/wpa_supplicant/" | ||
3 | BUGTRACKER = "http://hostap.epitest.fi/bugz/" | ||
4 | SECTION = "network" | ||
5 | LICENSE = "BSD" | ||
6 | LIC_FILES_CHKSUM = "file://COPYING;md5=36b27801447e0662ee0138d17fe93880 \ | ||
7 | file://README;beginline=1;endline=56;md5=7f393579f8b109fe91f3b9765d26c7d3 \ | ||
8 | file://wpa_supplicant/wpa_supplicant.c;beginline=1;endline=12;md5=3430fda79f2ba1dd545f0b3c4d6e4d24 " | ||
9 | DEPENDS = "dbus libnl libgcrypt" | ||
10 | RRECOMMENDS_${PN} = "wpa-supplicant-passphrase wpa-supplicant-cli" | ||
11 | |||
12 | PACKAGECONFIG ??= "gnutls" | ||
13 | PACKAGECONFIG[gnutls] = ",,gnutls" | ||
14 | PACKAGECONFIG[openssl] = ",,openssl" | ||
15 | |||
16 | inherit systemd | ||
17 | |||
18 | SYSTEMD_SERVICE_${PN} = "wpa_supplicant.service wpa_supplicant-nl80211@.service wpa_supplicant-wired@.service" | ||
19 | SYSTEMD_AUTO_ENABLE = "disable" | ||
20 | |||
21 | SRC_URI = "http://hostap.epitest.fi/releases/wpa_supplicant-${PV}.tar.gz \ | ||
22 | file://defconfig \ | ||
23 | file://wpa-supplicant.sh \ | ||
24 | file://wpa_supplicant.conf \ | ||
25 | file://wpa_supplicant.conf-sane \ | ||
26 | file://99_wpa_supplicant \ | ||
27 | file://0001-P2P-Validate-SSID-element-length-before-copying-it-C.patch \ | ||
28 | " | ||
29 | SRC_URI[md5sum] = "f0037dbe03897dcaf2ad2722e659095d" | ||
30 | SRC_URI[sha256sum] = "058dc832c096139a059e6df814080f50251a8d313c21b13364c54a1e70109122" | ||
31 | |||
32 | S = "${WORKDIR}/wpa_supplicant-${PV}" | ||
33 | |||
34 | PACKAGES_prepend = "wpa-supplicant-passphrase wpa-supplicant-cli " | ||
35 | FILES_wpa-supplicant-passphrase = "${bindir}/wpa_passphrase" | ||
36 | FILES_wpa-supplicant-cli = "${sbindir}/wpa_cli" | ||
37 | FILES_${PN} += "${datadir}/dbus-1/system-services/*" | ||
38 | CONFFILES_${PN} += "${sysconfdir}/wpa_supplicant.conf" | ||
39 | |||
40 | do_configure () { | ||
41 | ${MAKE} -C wpa_supplicant clean | ||
42 | install -m 0755 ${WORKDIR}/defconfig wpa_supplicant/.config | ||
43 | echo "CFLAGS +=\"-I${STAGING_INCDIR}/libnl3\"" >> wpa_supplicant/.config | ||
44 | echo "DRV_CFLAGS +=\"-I${STAGING_INCDIR}/libnl3\"" >> wpa_supplicant/.config | ||
45 | |||
46 | if echo "${PACKAGECONFIG}" | grep -qw "openssl"; then | ||
47 | ssl=openssl | ||
48 | elif echo "${PACKAGECONFIG}" | grep -qw "gnutls"; then | ||
49 | ssl=gnutls | ||
50 | fi | ||
51 | if [ -n "$ssl" ]; then | ||
52 | sed -i "s/%ssl%/$ssl/" wpa_supplicant/.config | ||
53 | fi | ||
54 | |||
55 | # For rebuild | ||
56 | rm -f wpa_supplicant/*.d wpa_supplicant/dbus/*.d | ||
57 | } | ||
58 | |||
59 | export EXTRA_CFLAGS = "${CFLAGS}" | ||
60 | export BINDIR = "${sbindir}" | ||
61 | |||
62 | do_compile () { | ||
63 | unset CFLAGS CPPFLAGS CXXFLAGS | ||
64 | sed -e "s:CFLAGS\ =.*:& \$(EXTRA_CFLAGS):g" -i ${S}/src/lib.rules | ||
65 | oe_runmake -C wpa_supplicant | ||
66 | } | ||
67 | |||
68 | do_install () { | ||
69 | install -d ${D}${sbindir} | ||
70 | install -m 755 wpa_supplicant/wpa_supplicant ${D}${sbindir} | ||
71 | install -m 755 wpa_supplicant/wpa_cli ${D}${sbindir} | ||
72 | |||
73 | install -d ${D}${bindir} | ||
74 | install -m 755 wpa_supplicant/wpa_passphrase ${D}${bindir} | ||
75 | |||
76 | install -d ${D}${docdir}/wpa_supplicant | ||
77 | install -m 644 wpa_supplicant/README ${WORKDIR}/wpa_supplicant.conf ${D}${docdir}/wpa_supplicant | ||
78 | |||
79 | install -d ${D}${sysconfdir} | ||
80 | install -m 600 ${WORKDIR}/wpa_supplicant.conf-sane ${D}${sysconfdir}/wpa_supplicant.conf | ||
81 | |||
82 | install -d ${D}${sysconfdir}/network/if-pre-up.d/ | ||
83 | install -d ${D}${sysconfdir}/network/if-post-down.d/ | ||
84 | install -d ${D}${sysconfdir}/network/if-down.d/ | ||
85 | install -m 755 ${WORKDIR}/wpa-supplicant.sh ${D}${sysconfdir}/network/if-pre-up.d/wpa-supplicant | ||
86 | cd ${D}${sysconfdir}/network/ && \ | ||
87 | ln -sf ../if-pre-up.d/wpa-supplicant if-post-down.d/wpa-supplicant | ||
88 | |||
89 | install -d ${D}/${datadir}/dbus-1/system-services | ||
90 | install -m 644 ${S}/wpa_supplicant/dbus/*.service ${D}/${datadir}/dbus-1/system-services | ||
91 | |||
92 | if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then | ||
93 | install -d ${D}/${sysconfdir}/dbus-1/system.d | ||
94 | install -m 644 ${S}/wpa_supplicant/dbus/dbus-wpa_supplicant.conf ${D}/${sysconfdir}/dbus-1/system.d | ||
95 | |||
96 | install -d ${D}/${systemd_unitdir}/system | ||
97 | install -m 644 ${S}/wpa_supplicant/systemd/*.service ${D}/${systemd_unitdir}/system | ||
98 | fi | ||
99 | |||
100 | install -d ${D}/etc/default/volatiles | ||
101 | install -m 0644 ${WORKDIR}/99_wpa_supplicant ${D}/etc/default/volatiles | ||
102 | } | ||
103 | |||
104 | pkg_postinst_wpa-supplicant () { | ||
105 | # If we're offline, we don't need to do this. | ||
106 | if [ "x$D" = "x" ]; then | ||
107 | killall -q -HUP dbus-daemon || true | ||
108 | fi | ||
109 | |||
110 | } | ||