resolvconf: Update to 1.72

(From OE-Core rev: 6edee60964a1bc367229239175426bdf175efa62)

Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 33 insertions, 0 deletions

diff --git a/meta/recipes-connectivity/resolvconf/resolvconf_1.72.bb b/meta/recipes-connectivity/resolvconf/resolvconf_1.72.bb
new file mode 100644
index 0000000000..a96dbff949
--- /dev/null
+++ b/meta/recipes-connectivity/resolvconf/resolvconf_1.72.bb
@@ -0,0 +1,33 @@
+SUMMARY = "name server information handler"
+DESCRIPTION = "Resolvconf is a framework for keeping track of the system's \
+information about currently available nameservers. It sets \
+itself up as the intermediary between programs that supply \
+nameserver information and programs that need nameserver \
+information."
+SECTION = "console/network"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=c93c0550bd3173f4504b2cbd8991e50b"
+AUTHOR = "Thomas Hood"
+HOMEPAGE = "http://packages.debian.org/resolvconf"
+RDEPENDS_${PN} = "bash"
+
+SRC_URI = "${DEBIAN_MIRROR}/main/r/resolvconf/resolvconf_${PV}.tar.gz"
+
+SRC_URI[md5sum] = "6bf631213c97f89261d997c78f7b9506"
+SRC_URI[sha256sum] = "196e8b5ef0a0282bf99e156113b058e65dd7f889cf4aea16597cddeef7e7cd43"
+
+inherit allarch
+
+do_compile () {
+        :
+}
+
+do_install () {
+        install -d ${D}${sysconfdir} ${D}${base_sbindir} ${D}${localstatedir}/volatile/run/resolvconf/interface
+        install -d ${D}${mandir}/man8 ${D}${docdir}/${P}
+        cp -pPR etc/* ${D}${sysconfdir}/
+        chown -R root:root ${D}${sysconfdir}/
+        install -m 0755 bin/resolvconf ${D}${base_sbindir}/
+        install -m 0644 README ${D}${docdir}/${P}/
+        install -m 0644 man/resolvconf.8 ${D}${mandir}/man8/
+}