usbutils: upgrade to 010

Upgrade to 010.

usbutils uses libusb1 not the older libusb-compat library.

Refresh (and submit upstream) the bashism removal for usb-devices.

Fix LICENSE as lsusb.py is GPLv2 or v3, and set per-package LICENSE fields as
appropriate.  The actual license texts are missing from the 010 tarball (fixed
in git) so point at the SPDX statements in the source files instead.

Remove FILES_${PN}-dev as usbutils.pc doesn't exist anymore.

Remove lsusb.py hashbang change as this doesn't cause any problems now
(installed hashbang is /usr/bin/env python3).

Remove spurious zlib build dependency that isn't required.

Remove spurious RDEPENDS_${PN}-ptest, which doesn't exist.

(From OE-Core rev: 889a86d8c044c0a9c6064a542f25e7fecef48234)

Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 32 insertions, 0 deletions

diff --git a/meta/recipes-bsp/usbutils/usbutils_010.bb b/meta/recipes-bsp/usbutils/usbutils_010.bb
new file mode 100644
index 0000000000..e6d05b8e87
--- /dev/null
+++ b/meta/recipes-bsp/usbutils/usbutils_010.bb
@@ -0,0 +1,32 @@
+SUMMARY = "Host side USB console utilities"
+DESCRIPTION = "Contains the lsusb utility for inspecting the devices connected to the USB bus."
+HOMEPAGE = "http://www.linux-usb.org"
+SECTION = "base"
+
+LICENSE = "GPLv2+ & (GPLv2 | GPLv3)"
+# License files went missing in 010, when 011 is released add LICENSES/* back
+LIC_FILES_CHKSUM = "file://lsusb.c;endline=1;md5=7d4861d978ff5ba7cb2b319ed1d4afe3 \
+                    file://lsusb.py.in;beginline=2;endline=2;md5=194d6a0226bf90f4f683e8968878b6cd"
+
+DEPENDS = "libusb1 virtual/libiconv udev"
+
+SRC_URI = "${KERNELORG_MIRROR}/linux/utils/usb/usbutils/usbutils-${PV}.tar.gz \
+           file://usb-devices-avoid-dependency-on-bash.patch \
+          "
+SRC_URI[md5sum] = "5eb2d2d68f9ed6dc3e9659a5988f7ed6"
+SRC_URI[sha256sum] = "881ba47fb2df10c3ba54a4cd6755a90377180890788e476f99d480ea9bc8bb58"
+
+inherit autotools pkgconfig distro_features_check update-alternatives
+
+ALTERNATIVE_${PN} = "lsusb"
+ALTERNATIVE_PRIORITY = "100"
+
+# The binaries are mostly GPLv2+ apart from lsusb.py which is GPLv2 or v3.
+LICENSE_${PN} = "GPLv2+"
+LICENSE_${PN}-python = "GPLv2 | GPLv3"
+
+RRECOMMENDS_${PN} = "udev-hwdb"
+
+PACKAGE_BEFORE_PN =+ "${PN}-python"
+FILES_${PN}-python += "${bindir}/lsusb.py"
+RDEPENDS_${PN}-python = "python3-core"