u-boot: renamed dir from uboot to the more appropriate u-boot

recipe dirs normally have the name of the (main) package and the official name is u-boot

(From OE-Core rev: e9899d52ade2181bd97dcf79bec64650e8b0f718)

Signed-off-by: Frans Meulenbroeks <fransmeulenbroeks@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 50 insertions, 0 deletions

diff --git a/meta/recipes-bsp/u-boot/u-boot.inc b/meta/recipes-bsp/u-boot/u-boot.inc
new file mode 100644
index 0000000000..544acd23b2
--- /dev/null
+++ b/meta/recipes-bsp/u-boot/u-boot.inc
@@ -0,0 +1,50 @@
+DESCRIPTION = "U-boot bootloader"
+HOMEPAGE = "http://u-boot.sf.net"
+SECTION = "bootloaders"
+PROVIDES = "virtual/bootloader"
+
+inherit deploy
+
+PARALLEL_MAKE=""
+
+# GCC 4.5.1 builds unusable binaries using -Os, remove it from OPTFLAGS
+EXTRA_OEMAKE = "CROSS_COMPILE=${TARGET_PREFIX} OPTFLAGS='-O2'"
+
+python () {
+        if not d.getVar("UBOOT_MACHINE", True):
+                PN = d.getVar("PN", True)
+                FILE = os.path.basename(d.getVar("FILE", True))
+                bb.debug(1, "To build %s, see %s for instructions on \
+                             setting up your machine config" % (PN, FILE))
+                raise bb.parse.SkipPackage("because UBOOT_MACHINE is not set")
+}
+
+UBOOT_IMAGE ?= "u-boot-${MACHINE}-${PV}-${PR}.bin"
+UBOOT_BINARY ?= "u-boot.bin"
+UBOOT_SYMLINK ?= "u-boot-${MACHINE}.bin"
+UBOOT_MAKE_TARGET ?= "all"
+
+do_compile () {
+        unset LDFLAGS
+        unset CFLAGS
+        unset CPPFLAGS
+        oe_runmake ${UBOOT_MACHINE}
+        oe_runmake ${UBOOT_MAKE_TARGET}
+}
+
+do_install () {
+    install -d ${D}/boot
+    install ${S}/${UBOOT_BINARY} ${D}/boot/${UBOOT_IMAGE}
+    ln -sf ${UBOOT_IMAGE} ${D}/boot/${UBOOT_BINARY}
+}
+
+FILES_${PN} = "/boot"
+
+do_deploy () {
+        install ${S}/u-boot.bin ${DEPLOYDIR}/${UBOOT_IMAGE}
+
+        cd ${DEPLOYDIR}
+        rm -f ${UBOOT_SYMLINK}
+        ln -sf ${UBOOT_IMAGE} ${UBOOT_SYMLINK}
+}
+addtask deploy before do_build after do_compile