u-boot: Upgrade to 2017.07 release

This patch upgrades the U-Boot to the 2017.07 release.

(From OE-Core rev: b322e1b1cb4cd4d4cc53f868b53ca9b069772755)

Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 34 insertions, 0 deletions

diff --git a/meta/recipes-bsp/u-boot/u-boot-fw-utils_2017.07.bb b/meta/recipes-bsp/u-boot/u-boot-fw-utils_2017.07.bb
new file mode 100644
index 0000000000..c2e8f0fb84
--- /dev/null
+++ b/meta/recipes-bsp/u-boot/u-boot-fw-utils_2017.07.bb
@@ -0,0 +1,34 @@
+require u-boot-common_${PV}.inc
+
+SUMMARY = "U-Boot bootloader fw_printenv/setenv utilities"
+DEPENDS = "mtd-utils"
+
+INSANE_SKIP_${PN} = "already-stripped"
+EXTRA_OEMAKE_class-target = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" V=1'
+EXTRA_OEMAKE_class-cross = 'ARCH=${TARGET_ARCH} CC="${CC} ${CFLAGS} ${LDFLAGS}" V=1'
+
+inherit uboot-config
+
+do_compile () {
+        oe_runmake ${UBOOT_MACHINE}
+        oe_runmake env
+}
+
+do_install () {
+        install -d ${D}${base_sbindir}
+        install -d ${D}${sysconfdir}
+        install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_printenv
+        install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_setenv
+        install -m 0644 ${S}/tools/env/fw_env.config ${D}${sysconfdir}/fw_env.config
+}
+
+do_install_class-cross () {
+        install -d ${D}${bindir_cross}
+        install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_printenv
+        install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_setenv
+}
+
+SYSROOT_DIRS_append_class-cross = " ${bindir_cross}"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+BBCLASSEXTEND = "cross"