rpm/rpm-native: Add recipe for 4.4.2.3

git-svn-id: https://svn.o-hand.com/repos/poky/trunk@5069 311d38ba-8fff-0310-9ca6-ca027cbcb966

1 files changed, 84 insertions, 0 deletions

diff --git a/meta/packages/rpm/rpm_4.4.2.3.bb b/meta/packages/rpm/rpm_4.4.2.3.bb
new file mode 100644
index 0000000000..b04b500b86
--- /dev/null
+++ b/meta/packages/rpm/rpm_4.4.2.3.bb
@@ -0,0 +1,84 @@
+DESCRIPTION = "The RPM Package Manager."
+HOMEPAGE = "http://rpm.org/"
+LICENSE = "LGPL GPL"
+DEPENDS = "zlib beecrypt file popt"
+PR = "r1"
+
+SRC_URI = "http://www.rpm.org/releases/rpm-4.4.x/rpm-4.4.2.3.tar.gz \
+           file://external-tools.patch;patch=1 \
+           file://cross_libpaths.patch;patch=1"
+
+inherit autotools gettext
+
+S = "${WORKDIR}/rpm-${PV}"
+
+acpaths = "-I ${S}/db/dist/aclocal -I ${S}/db/dist/aclocal_java"
+
+EXTRA_OECONF = "--without-python \
+                --without-apidocs \
+                --without-selinux \
+                --without-lua \
+                --without-dmalloc \
+                --without-efence"
+
+# Handle the db MUTEX settings here, the POSIX library is
+# the default - "POSIX/pthreads/library".
+# Don't ignore the nice SWP instruction on the ARM:
+# These enable the ARM assembler mutex code, this won't
+# work with thumb compilation...
+ARM_MUTEX = "--with-mutex=ARM/gcc-assembly"
+MUTEX = ""
+MUTEX_arm = "${ARM_MUTEX}"
+MUTEX_armeb = "${ARM_MUTEX}"
+EXTRA_OECONF += "${MUTEX}"
+
+do_configure () {
+        rm ${S}/popt/ -Rf
+        rm ${S}/db/dist/configure.in -f
+        cd ${S}/db/dist/aclocal
+        rm libtool* -f
+        for i in `ls *.ac`; do
+            j=`echo $i | sed 's/.ac/.m4/g'`
+            mv $i $j
+        done
+        cd ${S}/db/dist/aclocal_java
+        for i in `ls *.ac`; do
+            j=`echo $i | sed 's/.ac/.m4/g'`
+            mv $i $j
+        done
+        cd ${S}
+        autotools_do_configure
+        cd ${S}/db/dist
+        . ./RELEASE
+        # Edit version information we couldn't pre-compute.
+        (echo "1,\$s/__EDIT_DB_VERSION_MAJOR__/$DB_VERSION_MAJOR/g" &&
+         echo "1,\$s/__EDIT_DB_VERSION_MINOR__/$DB_VERSION_MINOR/g" &&
+         echo "1,\$s/__EDIT_DB_VERSION_PATCH__/$DB_VERSION_PATCH/g" &&
+         echo "1,\$s/__EDIT_DB_VERSION_STRING__/$DB_VERSION_STRING/g" &&
+         echo "1,\$s/__EDIT_DB_VERSION_UNIQUE_NAME__/$DB_VERSION_UNIQUE_NAME/g" &&
+         echo "1,\$s/__EDIT_DB_VERSION__/$DB_VERSION/g" &&
+         echo "w" &&
+         echo "q") | ed configure
+        cd ${S}/db3
+        ${S}/db3/configure \
+                    --build=${BUILD_SYS} \
+                    --host=${HOST_SYS} \
+                    --target=${TARGET_SYS} \
+                    --prefix=${prefix} \
+                    --exec_prefix=${exec_prefix} \
+                    --bindir=${bindir} \
+                    --sbindir=${sbindir} \
+                    --libexecdir=${libexecdir} \
+                    --datadir=${datadir} \
+                    --sysconfdir=${sysconfdir} \
+                    --sharedstatedir=${sharedstatedir} \
+                    --localstatedir=${localstatedir} \
+                    --libdir=${libdir} \
+                    --includedir=${includedir} \
+                    --oldincludedir=${oldincludedir} \
+                    --infodir=${infodir} \
+                    --mandir=${mandir} \
+                    ${EXTRA_OECONF} \
+                    --with-pic
+
+}