Add Pango 1.16 (from OE)

git-svn-id: https://svn.o-hand.com/repos/poky/trunk@1308 311d38ba-8fff-0310-9ca6-ca027cbcb966

1 files changed, 51 insertions, 0 deletions

diff --git a/meta/packages/pango/pango.inc b/meta/packages/pango/pango.inc
new file mode 100644
index 0000000000..e73fecbfb2
--- /dev/null
+++ b/meta/packages/pango/pango.inc
@@ -0,0 +1,51 @@
+DESCRIPTION = "The goal of the Pango project is to provide an \
+Open Source framework for the layout and rendering of \
+internationalized text."
+LICENSE = "LGPL"
+
+inherit gnome
+EXTRA_AUTORECONF = ""
+
+SECTION = "x11/libs"
+
+DEPENDS = "glib-2.0 fontconfig freetype zlib virtual/libx11 libxft gtk-doc cairo"
+
+PACKAGES_DYNAMIC = "pango-module-*"
+
+RRECOMMENDS_${PN} = "pango-module-basic-x pango-module-basic-fc" 
+
+# seems to go wrong with default cflags
+FULL_OPTIMIZATION_arm = "-O2"
+
+SRC_URI += "file://no-tests.patch;patch=1 \
+           "
+
+EXTRA_OECONF = "--disable-glibtest \
+                --enable-explicit-deps=no \
+                --disable-debug"
+
+LEAD_SONAME = "libpango-1.0*"
+LIBV = "1.6.0"
+
+FILES_${PN} = "/etc ${bindir}/* ${libdir}/libpango*.so.*"
+FILES_${PN}-dbg += "${libdir}/pango/${LIBV}/modules/.debug"
+FILES_${PN}-dev += "${libdir}/pango/${LIBV}/modules/*.la"
+
+do_stage () {
+        autotools_stage_all
+}
+
+postinst_prologue() {
+if [ "x$D" != "x" ]; then
+  exit 1
+fi
+
+}
+
+python populate_packages_prepend () {
+        prologue = bb.data.getVar("postinst_prologue", d, 1)
+
+        modules_root = bb.data.expand('${libdir}/pango/${LIBV}/modules', d)
+
+        do_split_packages(d, modules_root, '^pango-(.*)\.so$', 'pango-module-%s', 'Pango module %s', prologue + 'pango-querymodules > /etc/pango/pango.modules')
+}