nfs-utils: upgrade to version 1.2.2

from 1.0.6

changes:
  - there are several new dependencies: tirpc, libcap libgss,
    libnfsimap, libevent and libwrap. disable tirpc, libgss, libwrap
  - several changes are in upstream now, include the bzero change
    and stat-include change, remove the patches
  - a new build system is used, custom macros are now moved to aclocal/,
    acinclude and rpcgen fixes are not necessary any more
  - rebase uclibc patch
  - enable nfsv41, nfsv3 and nfsv4 are default turned on
  - do_compile is no longer needed
  - the install target has changed a lot, instead of updating the file
    list manually, try to use oe_runmake install for installation.
    Several files are built against build environment, they are removed
    from the packages.

Signed-off-by: Qing He <qing.he@intel.com>

1 files changed, 54 insertions, 0 deletions

diff --git a/meta/packages/nfs-utils/nfs-utils_1.2.2.bb b/meta/packages/nfs-utils/nfs-utils_1.2.2.bb
new file mode 100644
index 0000000000..cbcddd8c74
--- /dev/null
+++ b/meta/packages/nfs-utils/nfs-utils_1.2.2.bb
@@ -0,0 +1,54 @@
+DESCRIPTION = "userspace utilities for kernel nfs"
+HOMEPAGE = "http://nfs.sourceforge.net/"
+SECTION = "console/network"
+PRIORITY = "optional"
+
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3"
+
+# util-linux for libblkid
+DEPENDS = "libcap libnfsidmap libevent util-linux"
+RDEPENDS = "portmap"
+RRECOMMENDS = "kernel-module-nfsd"
+
+PR = "r0"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/nfs/nfs-utils-${PV}.tar.bz2 \
+           file://nfs-utils-1.0.6-uclibc.patch \
+           file://nfsserver"
+
+S = "${WORKDIR}/nfs-utils-${PV}/"
+
+PARALLEL_MAKE = ""
+
+# Only kernel-module-nfsd is required here (but can be built-in)  - the nfsd module will
+# pull in the remainder of the dependencies.
+
+INITSCRIPT_NAME = "nfsserver"
+# The server has no dependencies at the user run levels, so just put
+# it in at the default levels.  It must be terminated before the network
+# in the shutdown levels, but that works fine.
+INITSCRIPT_PARAMS = "defaults"
+
+inherit autotools update-rc.d
+
+# --enable-uuid is need for cross-compiling
+EXTRA_OECONF = "--with-statduser=nobody \
+                --enable-nfsv41 \
+                --enable-uuid \
+                --disable-gss \
+                --disable-tirpc \
+                --without-tcp-wrappers \
+                --with-statedir=/var/lib/nfs"
+
+INHIBIT_AUTO_STAGE = "1"
+
+do_install_append () {
+        install -d ${D}${sysconfdir}/init.d
+        install -m 0755 ${WORKDIR}/nfsserver ${D}${sysconfdir}/init.d/nfsserver
+
+        # the following are built by CC_FOR_BUILD
+        rm -f ${D}${sbindir}/rpcdebug
+        rm -f ${D}${sbindir}/rpcgen
+        rm -f ${D}${sbindir}/locktest
+}