gtk+: Add gtk+ 2.14.2

(with rebased hardcoded_libtool.patch and new disable-gio-png-sniff-test.diff)

git-svn-id: https://svn.o-hand.com/repos/poky/trunk@5250 311d38ba-8fff-0310-9ca6-ca027cbcb966

1 files changed, 48 insertions, 0 deletions

diff --git a/meta/packages/gtk+/gtk+_2.14.2.bb b/meta/packages/gtk+/gtk+_2.14.2.bb
new file mode 100644
index 0000000000..adcd1c2bd9
--- /dev/null
+++ b/meta/packages/gtk+/gtk+_2.14.2.bb
@@ -0,0 +1,48 @@
+require gtk+.inc
+
+PR = "r1"
+
+SRC_URI = "http://download.gnome.org/sources/gtk+/2.14/gtk+-${PV}.tar.bz2 \
+           file://xsettings.patch;patch=1 \
+           file://run-iconcache.patch;patch=1 \
+           file://hardcoded_libtool.patch;patch=1 \
+           file://no-demos.patch;patch=1 \
+           file://cellrenderer-cairo.patch;patch=1;pnum=0 \
+           file://entry-cairo.patch;patch=1;pnum=0 \
+           file://toggle-font.diff;patch=1;pnum=0 \
+# TO MERGE
+#           file://filesystem-volumes.patch;patch=1 \
+#           file://filechooser-props.patch;patch=1 \
+#           file://filechooser-default.patch;patch=1 \
+#           file://filechooser-sizefix.patch;patch=1 \
+# temporary
+#           file://gtklabel-resize-patch;patch=1 \
+#           file://menu-deactivate.patch;patch=1 \
+#        file://combo-arrow-size.patch;patch=1;pnum=0 \
+            file://disable-gio-png-sniff-test.diff;patch=1 \
+          "
+
+EXTRA_OECONF = "--without-libtiff --without-libjasper --disable-xkb --disable-glibtest --disable-cups"
+
+LIBV = "2.10.0"
+
+PACKAGES_DYNAMIC = "gdk-pixbuf-loader-* gtk-immodule-* gtk-printbackend-*"
+
+python populate_packages_prepend () {
+        import os.path
+
+        prologue = bb.data.getVar("postinst_prologue", d, 1)
+        postinst_pixbufloader = bb.data.getVar("postinst_pixbufloader", d, 1)
+
+        gtk_libdir = bb.data.expand('${libdir}/gtk-2.0/${LIBV}', d)
+        loaders_root = os.path.join(gtk_libdir, 'loaders')
+        immodules_root = os.path.join(gtk_libdir, 'immodules')
+        printmodules_root = os.path.join(gtk_libdir, 'printbackends');
+
+        do_split_packages(d, loaders_root, '^libpixbufloader-(.*)\.so$', 'gdk-pixbuf-loader-%s', 'GDK pixbuf loader for %s', postinst_pixbufloader)
+        do_split_packages(d, immodules_root, '^im-(.*)\.so$', 'gtk-immodule-%s', 'GTK input module for %s', prologue + 'gtk-query-immodules-2.0 > /etc/gtk-2.0/gtk.immodules')
+        do_split_packages(d, printmodules_root, '^libprintbackend-(.*)\.so$', 'gtk-printbackend-%s', 'GTK printbackend module for %s')
+
+        if (bb.data.getVar('DEBIAN_NAMES', d, 1)):
+                bb.data.setVar('PKG_${PN}', 'libgtk-2.0', d)
+}