connman: Updates and a recipe for the latest release

Split much of the recipe into connman.inc and created a recipe for the
latest 0.47 release.
Update the fixed revision and dropped unneeded patches.

Signed-off-by: Joshua Lock <josh@linux.intel.com>

3 files changed, 54 insertions, 45 deletions

diff --git a/meta/packages/connman/connman.inc b/meta/packages/connman/connman.inc
new file mode 100644
index 0000000000..e7fde858b8
--- /dev/null
+++ b/meta/packages/connman/connman.inc
@@ -0,0 +1,43 @@
+HOMEPAGE = "http://www.moblin.org/projects/projects_connman.php"
+SUMMARY  = "Moblin Connection Manager"
+LICENSE  = "GPL"
+
+DEPENDS  = "libgdbus dbus glib-2.0 hal"
+RDEPENDS_${PN} = "dhcp-client wpa-supplicant resolvconf"
+
+EXTRA_OECONF += " \
+    --enable-ethernet=builtin --enable-wifi=builtin --enable-dhclient=builtin \
+    --enable-bluetooth=builtin --enable-udev --enable-loopback=builtin \
+    --enable-dnsproxy=builtin --enable-threads --enable-resolvconf=builtin \
+    --enable-client --enable-fake --with-dhclient=/sbin/dhclient \
+    --enable-test \
+    ac_cv_path_WPASUPPLICANT=/usr/sbin/wpa_supplicant"
+
+INITSCRIPT_NAME = "connman"
+INITSCRIPT_PARAMS = "start 05 5 2 . stop 22 0 1 6 ."
+
+inherit autotools_stage pkgconfig update-rc.d
+
+do_install_append() {
+    install -d ${D}${sysconfdir}/init.d/
+    install -m 0755 ${WORKDIR}/connman ${D}${sysconfdir}/init.d/connman
+}
+
+PACKAGES_DYNAMIC = "${PN}-plugin-*"
+FILES_${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*.so.* \
+            ${sysconfdir} ${sharedstatedir} ${localstatedir} \
+            ${base_bindir}/* ${base_sbindir}/* ${base_libdir}/*.so* ${datadir}/${PN} \
+            ${datadir}/pixmaps ${datadir}/applications \
+            ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
+            ${libdir}/bonobo/servers \
+            ${libdir}/${PN}/test/* \
+            ${datadir}/dbus-1/system-services/* \
+            ${libdir}/connman/scripts/dhclient*"
+FILES_${PN}-dbg += "${libdir}/connman/plugins/.debug \
+                    ${libdir}/connman/scripts/.debug"
+
+python populate_packages_prepend() {
+        plugin_dir = bb.data.expand('${libdir}/connman/plugins/', d)
+        plugin_name = bb.data.expand('${PN}-plugin-%s', d)
+        do_split_packages(d, plugin_dir, '^lib(.*).so$', plugin_name, '${PN} plugin for %s', extra_depends='' )
+}
\ No newline at end of file
diff --git a/meta/packages/connman/connman_0.47.bb b/meta/packages/connman/connman_0.47.bb
new file mode 100644
index 0000000000..4cf903dfee
--- /dev/null
+++ b/meta/packages/connman/connman_0.47.bb
@@ -0,0 +1,7 @@
+require connman.inc
+PV       = "0.47"
+
+SRC_URI  = "http://www.kernel.org/pub/linux/network/connman/${P}.tar.bz2 \
+            file://dbusperms.patch \
+            file://connman "
+
diff --git a/meta/packages/connman/connman_git.bb b/meta/packages/connman/connman_git.bb
index 7520202e2e..31fe1662c1 100644
--- a/meta/packages/connman/connman_git.bb
+++ b/meta/packages/connman/connman_git.bb
@@ -1,51 +1,10 @@
-HOMEPAGE = "http://www.moblin.org/projects/projects_connman.php"
-SUMMARY  = "Moblin Connection Manager"
-PV       = "0.34+git${SRCPV}"
+require connman.inc
+
+PV       = "0.47+git${SRCPV}"
 PR       = "r16"
 S        = "${WORKDIR}/git"
-LICENSE  = "GPL"
-
-DEPENDS  = "libgdbus dbus glib-2.0 hal"
-RDEPENDS_${PN} = "dhcp-client wpa-supplicant resolvconf"
-
-EXTRA_OECONF += " \
-    --enable-ethernet=builtin --enable-wifi=builtin --enable-dhclient=builtin \
-    --enable-bluetooth=builtin --enable-udev --enable-loopback=builtin \
-    --enable-dnsproxy=builtin --enable-threads --enable-resolvconf=builtin \
-    --enable-client --enable-fake --with-dhclient=/sbin/dhclient \
-    --enable-test \
-    ac_cv_path_WPASUPPLICANT=/usr/sbin/wpa_supplicant"
 
 SRC_URI  = "git://git.kernel.org/pub/scm/network/connman/connman.git;protocol=git \
-            file://connman-install-tests-d52de88aff4771283b2ebee4f48a7af15862d0ae.patch;patch=1;rev=d52de88aff4771283b2ebee4f48a7af15862d0ae \
-            file://connman-install-tests.patch;patch=1;rev=fd401dcd103a309e22c00d66f5c91375bfc9cce4 \
-            file://dbusperms.patch;patch=1 \
+            file://dbusperms.patch \
             file://connman "
 
-INITSCRIPT_NAME = "connman"
-INITSCRIPT_PARAMS = "start 05 5 2 . stop 22 0 1 6 ."
-
-inherit autotools_stage pkgconfig update-rc.d
-
-do_install_append() {
-    install -d ${D}${sysconfdir}/init.d/
-    install -m 0755 ${WORKDIR}/connman ${D}${sysconfdir}/init.d/connman
-}
-
-PACKAGES_DYNAMIC = "${PN}-plugin-*"
-FILES_${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*.so.* \
-            ${sysconfdir} ${sharedstatedir} ${localstatedir} \
-            ${base_bindir}/* ${base_sbindir}/* ${base_libdir}/*.so* ${datadir}/${PN} \
-            ${datadir}/pixmaps ${datadir}/applications \
-            ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
-            ${libdir}/bonobo/servers \
-            ${datadir}/dbus-1/system-services/* \
-            ${libdir}/connman/scripts/dhclient*"
-FILES_${PN}-dbg += "${libdir}/connman/plugins/.debug \
-                    ${libdir}/connman/scripts/.debug"
-
-python populate_packages_prepend() {
-        plugin_dir = bb.data.expand('${libdir}/connman/plugins/', d)
-        plugin_name = bb.data.expand('${PN}-plugin-%s', d)
-        do_split_packages(d, plugin_dir, '^lib(.*).so$', plugin_name, '${PN} plugin for %s', extra_depends='' )
-}