summaryrefslogtreecommitdiffstats
path: root/meta/classes/kernel-arch.bbclass
diff options
context:
space:
mode:
authorTudor Florea <tudor.florea@enea.com>2014-10-16 03:05:19 +0200
committerTudor Florea <tudor.florea@enea.com>2014-10-16 03:05:19 +0200
commitc527fd1f14c27855a37f2e8ac5346ce8d940ced2 (patch)
treebb002c1fdf011c41dbd2f0927bed23ecb5f83c97 /meta/classes/kernel-arch.bbclass
downloadpoky-daisy-140929.tar.gz
initial commit for Enea Linux 4.0-140929daisy-140929
Migrated from the internal git server on the daisy-enea-point-release branch Signed-off-by: Tudor Florea <tudor.florea@enea.com>
Diffstat (limited to 'meta/classes/kernel-arch.bbclass')
-rw-r--r--meta/classes/kernel-arch.bbclass60
1 files changed, 60 insertions, 0 deletions
diff --git a/meta/classes/kernel-arch.bbclass b/meta/classes/kernel-arch.bbclass
new file mode 100644
index 0000000000..bbcfa15b84
--- /dev/null
+++ b/meta/classes/kernel-arch.bbclass
@@ -0,0 +1,60 @@
1#
2# set the ARCH environment variable for kernel compilation (including
3# modules). return value must match one of the architecture directories
4# in the kernel source "arch" directory
5#
6
7valid_archs = "alpha cris ia64 \
8 i386 x86 \
9 m68knommu m68k ppc powerpc powerpc64 ppc64 \
10 sparc sparc64 \
11 arm aarch64 \
12 m32r mips \
13 sh sh64 um h8300 \
14 parisc s390 v850 \
15 avr32 blackfin \
16 microblaze"
17
18def map_kernel_arch(a, d):
19 import re
20
21 valid_archs = d.getVar('valid_archs', True).split()
22
23 if re.match('(i.86|athlon|x86.64)$', a): return 'x86'
24 elif re.match('armeb$', a): return 'arm'
25 elif re.match('aarch64$', a): return 'arm64'
26 elif re.match('aarch64_be$', a): return 'arm64'
27 elif re.match('mips(el|64|64el)$', a): return 'mips'
28 elif re.match('p(pc|owerpc)(|64)', a): return 'powerpc'
29 elif re.match('sh(3|4)$', a): return 'sh'
30 elif re.match('bfin', a): return 'blackfin'
31 elif re.match('microblazeel', a): return 'microblaze'
32 elif a in valid_archs: return a
33 else:
34 bb.error("cannot map '%s' to a linux kernel architecture" % a)
35
36export ARCH = "${@map_kernel_arch(d.getVar('TARGET_ARCH', True), d)}"
37
38def map_uboot_arch(a, d):
39 import re
40
41 if re.match('p(pc|owerpc)(|64)', a): return 'ppc'
42 elif re.match('i.86$', a): return 'x86'
43 elif re.match('arm64$', a): return 'arm'
44 return a
45
46export UBOOT_ARCH = "${@map_uboot_arch(d.getVar('ARCH', True), d)}"
47
48# Set TARGET_??_KERNEL_ARCH in the machine .conf to set architecture
49# specific options necessary for building the kernel and modules.
50TARGET_CC_KERNEL_ARCH ?= ""
51HOST_CC_KERNEL_ARCH ?= "${TARGET_CC_KERNEL_ARCH}"
52TARGET_LD_KERNEL_ARCH ?= ""
53HOST_LD_KERNEL_ARCH ?= "${TARGET_LD_KERNEL_ARCH}"
54TARGET_AR_KERNEL_ARCH ?= ""
55HOST_AR_KERNEL_ARCH ?= "${TARGET_AR_KERNEL_ARCH}"
56
57KERNEL_CC = "${CCACHE}${HOST_PREFIX}gcc ${HOST_CC_KERNEL_ARCH}"
58KERNEL_LD = "${CCACHE}${HOST_PREFIX}ld.bfd ${HOST_LD_KERNEL_ARCH}"
59KERNEL_AR = "${CCACHE}${HOST_PREFIX}ar ${HOST_AR_KERNEL_ARCH}"
60