qt-tools-native: add QT4 tool to build qt application

QT4 provides tools like moc (meta object compiler), uic (user interface compiler) etc.. to build qt application. This commit add the qt4 tools. The recipe is from OE with minor cleanup.

Signed-off-by: Yu Ke <ke.yu@intel.com>

2 files changed, 85 insertions, 0 deletions

diff --git a/meta-lsb/packages/qt4/qt4-tools-native.inc b/meta-lsb/packages/qt4/qt4-tools-native.inc
new file mode 100644
index 0000000000..7621d629f1
--- /dev/null
+++ b/meta-lsb/packages/qt4/qt4-tools-native.inc
@@ -0,0 +1,74 @@
+DESCRIPTION = "Native tools for Qt/[X11|Mac|Embedded] version 4.x"
+DEPENDS = "zlib-native dbus-native libsm-native"
+SECTION = "libs"
+HOMEPAGE = "http://qt.nokia.com"
+PRIORITY = "optional"
+
+inherit native
+
+SRC_URI = "http://get.qt.nokia.com/qt/source/qt-everywhere-opensource-src-${PV}.tar.gz \
+           file://qt-config.patch \
+           file://g++.conf \
+           file://linux.conf"
+S = "${WORKDIR}/qt-everywhere-opensource-src-${PV}"
+
+EXTRA_OECONF = "-prefix ${prefix} \
+                -L ${STAGING_LIBDIR_NATIVE} \
+                -I ${STAGING_INCDIR_NATIVE} \
+                -qt-libjpeg -qt-gif -system-zlib \
+                -no-libjpeg -no-libpng \
+                -no-accessibility \
+                -no-cups \
+                -no-exceptions  \
+                -no-nas-sound \
+                -no-nis \
+                -verbose -release -static \
+                -qt3support"
+
+# yank default -e, otherwise we get the following error:
+# moc_qbuffer.cpp: No such file or directory
+EXTRA_OEMAKE = " "
+
+do_configure() {
+        (echo o; echo yes) | ./configure ${EXTRA_OECONF} || die "Configuring qt failed. EXTRA_OECONF was ${EXTRA_OECONF}"
+}
+
+TOBUILD = "\
+  src/tools/moc \
+  src/corelib \
+  src/sql \
+  src/dbus \
+  src/qt3support \
+  src/xml \
+  src/tools/uic \
+  src/tools/rcc \
+  src/network \
+  src/gui \
+  src/tools/uic3 \
+  tools/linguist/lrelease \
+  tools/linguist/lupdate \
+  tools/qdbus \
+"
+
+do_compile() {
+        for i in ${TOBUILD}; do
+                cd ${S}/$i && oe_runmake CC="${CC}" CXX="${CXX}"
+        done
+}
+
+NATIVE_INSTALL_WORKS = "1"
+
+do_install() {
+        install -d ${D}${bindir}/
+        install -m 0755 bin/qmake ${D}${bindir}/qmake2
+        for i in moc uic uic3 rcc lrelease lupdate qdbuscpp2xml qdbusxml2cpp; do
+                install -m 0755 bin/${i} ${D}${bindir}/${i}4
+        done
+
+        install -d ${D}${datadir}/qt4/
+        cp -PfR mkspecs ${D}${datadir}/qt4/
+        ln -sf linux-g++ ${D}${datadir}/qt4/mkspecs/${BUILD_OS}-oe-g++
+        cp -f ${WORKDIR}/g++.conf ${WORKDIR}/linux.conf ${D}${datadir}/qt4/mkspecs/common/
+
+        install -m 0644 tools/porting/src/q3porting.xml ${D}${datadir}/qt4/
+}
diff --git a/meta-lsb/packages/qt4/qt4-tools-native_4.6.3.bb b/meta-lsb/packages/qt4/qt4-tools-native_4.6.3.bb
new file mode 100644
index 0000000000..de24b38dea
--- /dev/null
+++ b/meta-lsb/packages/qt4/qt4-tools-native_4.6.3.bb
@@ -0,0 +1,11 @@
+require qt4-tools-native.inc
+
+LICENSE = "LGPLv2.1 | GPLv3"
+LIC_FILES_CHKSUM = "file://LICENSE.LGPL;md5=fbc093901857fcd118f065f900982c24 \
+                    file://LICENSE.GPL3;md5=babc5b6b77441da277f5c06b2e547720 \
+                    file://LGPL_EXCEPTION.txt;md5=411080a56ff917a5a1aa08c98acae354"
+PR = "r0"
+
+EXTRA_OECONF += " -no-fast -silent -no-rpath"
+
+TOBUILD := "src/tools/bootstrap ${TOBUILD}"