# We have a conf and classes directory, add to BBPATH
BBPATH .= ":${LAYERDIR}"

# We have a packages directory, add to BBFILES
BBFILES += "${LAYERDIR}/recipes-*/*/*.bb"
BBFILES += "${LAYERDIR}/recipes-*/*/*.bbappend"

BBFILE_COLLECTIONS += "xilinx-microblaze"
BBFILE_PATTERN_xilinx-microblaze = "^${LAYERDIR}/"
BBFILE_PRIORITY_xilinx-microblaze = "5"

LAYERDEPENDS_xilinx-microblaze = "core"

LAYERSERIES_COMPAT_xilinx-microblaze = "nanbield"

# Microblaze does not support stack-protector!
SECURITY_STACK_PROTECTOR:microblaze = ""

OLDEST_KERNEL:microblaze = "3.15"

INHERIT += "rust_microblaze"

# We want to use gcc 12.x for the microblaze stuff, and 13.x for any host tooling
GCCVERSION:microblaze = "12.2.%"
SDKGCCVERSION:microblaze = "13.%"

GDBVERSION:microblaze = "12.1"
# canon-prefix-map doesn't exist in gcc 12.x
DEBUG_PREFIX_MAP:remove:microblaze = "-fcanon-prefix-map"

MICROBLAZE_SKIP_MSG = ""
MICROBLAZE_SKIP_MSG:microblaze = "This recipe does not currently work on microblaze."

# ../../../alsa-lib-1.2.9/src/control/control.c:3648:1: error: symver is only supported on ELF platforms
SKIP_RECIPE[alsa-lib] = "${MICROBLAZE_SKIP_MSG}"