16 files changed, 214 insertions, 0 deletions

diff --git a/conf/machine/include/machine-xilinx-board.inc b/conf/machine/include/machine-xilinx-board.inc
new file mode 100644
index 00000000..dcd4b030
--- /dev/null
+++ b/conf/machine/include/machine-xilinx-board.inc
@@ -0,0 +1,3 @@
+# Default Xilinx Board settings
+
+EXTRA_IMAGEDEPENDS += "virtual/bootloader"
diff --git a/conf/machine/include/machine-xilinx-default.inc b/conf/machine/include/machine-xilinx-default.inc
new file mode 100644
index 00000000..4d5d977d
--- /dev/null
+++ b/conf/machine/include/machine-xilinx-default.inc
@@ -0,0 +1,24 @@
+# Default Xilinx BSP Machine settings
+
+# File System Configuration
+IMAGE_FSTYPES ?= "cpio tar.gz ext2 ext2.gz.u-boot"
+IMAGE_CLASSES += "image_types_uboot"
+
+# Kernel Configuration
+PREFERRED_PROVIDER_virtual/kernel ?= "linux-xlnx"
+PREFERRED_VERSION_linux-xlnx ?= "3.8%"
+PREFERRED_VERSION_linux-yocto ?= "3.10%"
+
+# U-Boot Configuration
+PREFERRED_PROVIDER_virtual/bootloader ?= "u-boot-xlnx"
+PREFERRED_PROVIDER_u-boot ?= "u-boot-xlnx"
+PREFERRED_VERSION_u-boot-xlnx ?= "v2013.01%"
+
+# Architecture specific kernel configuration parts, defconfigs for Xilinx architectures
+MACHINE_KCONFIG_prepend += "common/linux/${SOC_FAMILY}/defconfig_${@'.'.join(d.getVar('LINUX_VERSION', True).split('.')[0:2]).strip('+')}.cfg "
+
+# Common Device Tree Includes
+MACHINE_DEVICETREE_append_zynq += " \
+                common/zynq7-base.dtsi \
+                common/zynq7-mainline-gem.dtsi \
+                "
diff --git a/conf/machine/include/microblaze/feature-microblaze-barrel-shift.inc b/conf/machine/include/microblaze/feature-microblaze-barrel-shift.inc
new file mode 100644
index 00000000..ca7e7e39
--- /dev/null
+++ b/conf/machine/include/microblaze/feature-microblaze-barrel-shift.inc
@@ -0,0 +1,3 @@
+TUNEVALID[barrel-shift] = "Enable Microblaze Hardware Barrel Shift."
+MBCCARGSBARRELSHIFT += "${@bb.utils.contains("TUNE_FEATURES", "barrel-shift", "-mxl-barrel-shift", "-mno-xl-barrel-shift" ,d)}"
+MBPKGBARRELSHIFT .= "${@bb.utils.contains("TUNE_FEATURES", "barrel-shift", "-bs", "" ,d)}"
diff --git a/conf/machine/include/microblaze/feature-microblaze-divide.inc b/conf/machine/include/microblaze/feature-microblaze-divide.inc
new file mode 100644
index 00000000..5d010a4a
--- /dev/null
+++ b/conf/machine/include/microblaze/feature-microblaze-divide.inc
@@ -0,0 +1,3 @@
+TUNEVALID[divide-hard] = "Enable Microblaze hardware divider."
+MBCCARGSDIV += "${@bb.utils.contains("TUNE_FEATURES", "divide-hard", "-mno-xl-soft-div", "-mxl-soft-div" ,d)}"
+MBPKGDIV .= "${@bb.utils.contains("TUNE_FEATURES", "divide-hard", "-div", "" ,d)}"
diff --git a/conf/machine/include/microblaze/feature-microblaze-endian.inc b/conf/machine/include/microblaze/feature-microblaze-endian.inc
new file mode 100644
index 00000000..80567611
--- /dev/null
+++ b/conf/machine/include/microblaze/feature-microblaze-endian.inc
@@ -0,0 +1,13 @@
+# This feature file must be included/required FIRST as it defines the start of the PKGARCH bitbake variable
+MBCCARGSENDIAN = ""
+MBPKGENDIAN = ""
+
+TUNEVALID[little-endian] = "Use Microblaze Little Endian."
+MBCCARGSENDIAN += "${@bb.utils.contains("TUNE_FEATURES", "little-endian", "-mlittle-endian", "" ,d)}"
+MBPKGENDIAN .= "${@bb.utils.contains("TUNE_FEATURES", "little-endian", "el", "eb" ,d)}"
+
+TUNEVALID[big-endian] = "Use Microblaze Big Endian."
+MBCCARGSENDIAN += "${@bb.utils.contains("TUNE_FEATURES", "big-endian", "-mbig-endian", "" ,d)}"
+MBPKGENDIAN .= "${@bb.utils.contains("TUNE_FEATURES", "big-endian", "eb", "" ,d)}"
+
+TUNECONFLICTS[little-endian] = "big-endian"
diff --git a/conf/machine/include/microblaze/feature-microblaze-fpu.inc b/conf/machine/include/microblaze/feature-microblaze-fpu.inc
new file mode 100644
index 00000000..bf2fe38b
--- /dev/null
+++ b/conf/machine/include/microblaze/feature-microblaze-fpu.inc
@@ -0,0 +1,17 @@
+TUNEVALID[fpu-soft] = "Use Microblaze software FPU"
+TUNEVALID[fpu-hard] = "Enable Microblaze hardware FPU in basic mode."
+TUNEVALID[fpu-hard-extended] = "Enable Microblaze hardware FPU in extended mode - conversion and square root instructions."
+
+# Establish which fpu is configured in TUNE_FEATURES. Soft is the default for gcc.
+MBCCARGSFPU_BASIC = "${@bb.utils.contains("TUNE_FEATURES", "fpu-hard", "-mhard-float", "", d)}"
+MBCCARGSFPU = "${@bb.utils.contains("TUNE_FEATURES", "fpu-hard-extended", "-mhard-float -mxl-float-convert -mxl-float-sqrt", "${MBCCARGSFPU_BASIC}" ,d)}"
+
+MBPKGFPU_BASIC = "${@bb.utils.contains("TUNE_FEATURES", "fpu-hard", "-fb", "", d)}"
+MBPKGFPU = "${@bb.utils.contains("TUNE_FEATURES", "fpu-hard-extended", "-fe", "${MBPKGFPU_BASIC}", d)}"
+
+# Set target fpu (bitbake known target) to soft or hard (basic or extended in microblaze language)
+TARGETFPU_BASIC = "${@bb.utils.contains("TUNE_FEATURES", "fpu-hard", "fpu-hard", "fpu-soft", d)}"
+TARGET_FPU = "${@bb.utils.contains("TUNE_FEATURES", "fpu-hard-extended", "fpu-hard", "${TARGETFPU_BASIC}", d)}"
+
+TUNECONFLICTS[fpu-hard] = "fpu-soft"
+TUNECONFLICTS[fpu-hard-extended] = "fpu-soft"
diff --git a/conf/machine/include/microblaze/feature-microblaze-multiply.inc b/conf/machine/include/microblaze/feature-microblaze-multiply.inc
new file mode 100644
index 00000000..e3f8ae5f
--- /dev/null
+++ b/conf/machine/include/microblaze/feature-microblaze-multiply.inc
@@ -0,0 +1,9 @@
+TUNEVALID[multiply-low] = "Enable Microblaze Hardware Multiply with low (32 bit) result."
+TUNEVALID[multiply-high] = "Enable Microblaze Hardware Multiply with high (64 bit) result."
+
+# Establish which Multiply output result size to use
+MBCCARGSMUL_BASIC = "${@bb.utils.contains("TUNE_FEATURES", "multiply-low", "-mno-xl-soft-mul", "-mxl-soft-mul" ,d)}"
+MBCCARGSMUL = "${@bb.utils.contains("TUNE_FEATURES", "multiply-high", "-mno-xl-soft-mul -mxl-multiply-high", "${MBCCARGSMUL_BASIC}" ,d)}"
+
+MBPKGMUL_BASIC = "${@bb.utils.contains("TUNE_FEATURES", "multiply-low", "-ml", "" ,d)}"
+MBPKGMUL = "${@bb.utils.contains("TUNE_FEATURES", "multiply-high", "-mh", "${MBPKGMUL_BASIC}" ,d)}"
diff --git a/conf/machine/include/microblaze/feature-microblaze-pattern-compare.inc b/conf/machine/include/microblaze/feature-microblaze-pattern-compare.inc
new file mode 100644
index 00000000..347fba79
--- /dev/null
+++ b/conf/machine/include/microblaze/feature-microblaze-pattern-compare.inc
@@ -0,0 +1,3 @@
+TUNEVALID[pattern-compare] = "Enable Microblaze Pattern Compare Instructions."
+MBCCARGSPATTERNCOMPARE = "${@bb.utils.contains("TUNE_FEATURES", "pattern-compare", "-mxl-pattern-compare", "-mno-xl-pattern-compare" ,d)}"
+MBPKGSPATTERNCOMPARE = "${@bb.utils.contains("TUNE_FEATURES", "pattern-compare", "-cmp", "" ,d)}"
diff --git a/conf/machine/include/microblaze/feature-microblaze-reorder.inc b/conf/machine/include/microblaze/feature-microblaze-reorder.inc
new file mode 100644
index 00000000..0d809ad1
--- /dev/null
+++ b/conf/machine/include/microblaze/feature-microblaze-reorder.inc
@@ -0,0 +1,3 @@
+TUNEVALID[reorder] = "Enable Microblaze Reorder Instructions."
+MBCCARGSREORDER = "${@bb.utils.contains("TUNE_FEATURES", "reorder", "-mxl-reorder", "-mno-xl-reorder" ,d)}"
+MBPKGREORDER = "${@bb.utils.contains("TUNE_FEATURES", "reorder", "-re", "" ,d)}"
diff --git a/conf/machine/include/microblaze/feature-microblaze-v7.inc b/conf/machine/include/microblaze/feature-microblaze-v7.inc
new file mode 100644
index 00000000..6022e473
--- /dev/null
+++ b/conf/machine/include/microblaze/feature-microblaze-v7.inc
@@ -0,0 +1,7 @@
+# Setup version 'feature set' for supported Microblaze version 7 versions
+TUNEVALID[v7.30] = "Use Microblaze version 7.30"
+
+MBCCARGSVERSION += "${@bb.utils.contains("TUNE_FEATURES", "v7.30", "-mcpu=v7.30.a", "" ,d)}"
+MBPKGVERSION .= "${@bb.utils.contains("TUNE_FEATURES", "v7.30", "-v7.30", "" ,d)}"
+
+TUNECONFLICTS[v7.30] += "reorder little-endian"
diff --git a/conf/machine/include/microblaze/feature-microblaze-v8.inc b/conf/machine/include/microblaze/feature-microblaze-v8.inc
new file mode 100644
index 00000000..46a11cfd
--- /dev/null
+++ b/conf/machine/include/microblaze/feature-microblaze-v8.inc
@@ -0,0 +1,45 @@
+# Setup version 'feature set' for supported Microblaze version 8 versions
+TUNEVALID[v8.50] = "Use Microblaze version 8.50"
+MBCCARGSVERSION += "${@bb.utils.contains("TUNE_FEATURES", "v8.50", "-mcpu=v8.50.a", "" ,d)}"
+MBPKGVERSION .= "${@bb.utils.contains("TUNE_FEATURES", "v8.50", "-v8.50", "" ,d)}"
+
+TUNEVALID[v8.40] = "Use Microblaze version 8.40"
+MBCCARGSVERSION += "${@bb.utils.contains("TUNE_FEATURES", "v8.40", "-mcpu=v8.40.a", "" ,d)}"
+MBPKGVERSION .= "${@bb.utils.contains("TUNE_FEATURES", "v8.40", "-v8.40", "" ,d)}"
+
+TUNEVALID[v8.30] = "Use Microblaze version 8.30"
+MBCCARGSVERSION += "${@bb.utils.contains("TUNE_FEATURES", "v8.30", "-mcpu=v8.30.a", "" ,d)}"
+MBPKGVERSION .= "${@bb.utils.contains("TUNE_FEATURES", "v8.30", "-v8.30", "" ,d)}"
+
+TUNEVALID[v8.20] = "Use Microblaze version 8.20"
+MBCCARGSVERSION += "${@bb.utils.contains("TUNE_FEATURES", "v8.20", "-mcpu=v8.20.a", "" ,d)}"
+MBPKGVERSION .= "${@bb.utils.contains("TUNE_FEATURES", "v8.20", "-v8.20", "" ,d)}"
+
+TUNEVALID[v8.10] = "Use Microblaze version 8.10"
+MBCCARGSVERSION += "${@bb.utils.contains("TUNE_FEATURES", "v8.10", "-mcpu=v8.10.a", "" ,d)}"
+MBPKGVERSION .= "${@bb.utils.contains("TUNE_FEATURES", "v8.10", "-v8.10", "" ,d)}"
+
+TUNEVALID[v8.00] = "Use Microblaze version 8.00"
+MBCCARGSVERSION += "${@bb.utils.contains("TUNE_FEATURES", "v8.00", "-mcpu=v8.00.a", "" ,d)}"
+MBPKGVERSION .= "${@bb.utils.contains("TUNE_FEATURES", "v8.00", "-v8.00", "" ,d)}"
+
+TUNECONFLICTS[v8.00] += "reorder"
+TUNECONFLICTS[v8.10] += "reorder"
+TUNECONFLICTS[v8.20] += "reorder"
+
+# Perform some additional sanity checking
+python __anonymous () {
+    import bb
+    tune_features = bb.data.getVar('TUNE_FEATURES', d, 1)
+    tuneslist = tune_features.split()
+
+    #
+    # GCC will fail on v8.30 if reorder and pattern-compare are not 
+    # both in ccflags
+    # -mxl-reorder requires -mxl-pattern-compare for -mcpu=v8.30.a
+    # Check if either one exists alone and if so, add the other
+    #
+    if 'v8.30' in tuneslist:
+        if 'reorder' in tuneslist and 'pattern-compare' not in tuneslist:
+            d.setVar("TUNE_FEATURES", "%s pattern-compare" % tune_features)
+}
diff --git a/conf/machine/include/microblaze/feature-microblaze-v9.inc b/conf/machine/include/microblaze/feature-microblaze-v9.inc
new file mode 100644
index 00000000..cb934f6a
--- /dev/null
+++ b/conf/machine/include/microblaze/feature-microblaze-v9.inc
@@ -0,0 +1,4 @@
+# Setup version 'feature set' for supported Microblaze version 9 versions
+TUNEVALID[v9.0] = "Use Microblaze version 9.0"
+MBCCARGSVERSION += "${@bb.utils.contains("TUNE_FEATURES", "v9.0", "-mcpu=v9.0", "" ,d)}"
+MBPKGVERSION .= "${@bb.utils.contains("TUNE_FEATURES", "v9.0", "-v9.0", "" ,d)}"
diff --git a/conf/machine/include/microblaze/feature-microblaze-versions.inc b/conf/machine/include/microblaze/feature-microblaze-versions.inc
new file mode 100644
index 00000000..24181cc9
--- /dev/null
+++ b/conf/machine/include/microblaze/feature-microblaze-versions.inc
@@ -0,0 +1,19 @@
+# Microblaze Versions are defined as features sets, each containing 
+# a set of hardware features.
+
+MBCCARGSVERSION = ""
+MBPKGVERSION = ""
+require conf/machine/include/microblaze/feature-microblaze-v9.inc
+require conf/machine/include/microblaze/feature-microblaze-v8.inc
+require conf/machine/include/microblaze/feature-microblaze-v7.inc
+
+# Setup a 'feature set' conflict list which ensures only one version is selected
+# when defining the TUNE_FEATURES_tune-<>  in local.conf file.
+TUNECONFLICTS[v9.0]  += "v7.30 v8.00 v8.10 v8.20 v8.30 v8.40 v8.50"
+TUNECONFLICTS[v8.50] += "v7.30 v8.00 v8.10 v8.20 v8.30 v8.40 v9.0"
+TUNECONFLICTS[v8.40] += "v7.30 v8.00 v8.10 v8.20 v8.30 v8.50 v9.0"
+TUNECONFLICTS[v8.30] += "v7.30 v8.00 v8.10 v8.20 v8.40 v8.50 v9.0"
+TUNECONFLICTS[v8.20] += "v7.30 v8.00 v8.10 v8.30 v8.40 v8.50 v9.0"
+TUNECONFLICTS[v8.10] += "v7.30 v8.00 v8.20 v8.30 v8.40 v8.50 v9.0"
+TUNECONFLICTS[v8.00] += "v7.30 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0"
+TUNECONFLICTS[v7.30] += "v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0"
diff --git a/conf/machine/include/tune-microblaze-features.inc b/conf/machine/include/tune-microblaze-features.inc
new file mode 100644
index 00000000..fd7e0c8f
--- /dev/null
+++ b/conf/machine/include/tune-microblaze-features.inc
@@ -0,0 +1,19 @@
+# The order of these files defines the order of sections in the PKGARCH variable
+require conf/machine/include/microblaze/feature-microblaze-endian.inc
+require conf/machine/include/microblaze/feature-microblaze-versions.inc
+require conf/machine/include/microblaze/feature-microblaze-barrel-shift.inc
+require conf/machine/include/microblaze/feature-microblaze-multiply.inc
+require conf/machine/include/microblaze/feature-microblaze-divide.inc
+require conf/machine/include/microblaze/feature-microblaze-fpu.inc
+require conf/machine/include/microblaze/feature-microblaze-pattern-compare.inc
+require conf/machine/include/microblaze/feature-microblaze-reorder.inc
+
+# Architecture name, either 'microblaze' or 'microblazeel' depending on endianess
+TUNE_ARCH = "microblaze${@bb.utils.contains("TUNE_FEATURES", "little-endian", "el", "" ,d)}"
+
+# Compiler args
+TUNE_CCARGS += "${MBCCARGSENDIAN} ${MBCCARGSVERSION} ${MBCCARGSBARRELSHIFT} ${MBCCARGSMUL} ${MBCCARGSDIV} ${MBCCARGSFPU} ${MBCCARGSPATTERNCOMPARE} ${MBCCARGSREORDER}"
+
+# Package Architecture formatting
+MBPKGMATH = "${MBPKGMUL}${MBPKGDIV}${MBPKGFPU}"
+TUNE_PKGARCH = "microblaze${MBPKGENDIAN}${MBPKGVERSION}${MBPKGBARRELSHIFT}${MBPKGSPATTERNCOMPARE}${MBPKGREORDER}${MBPKGMATH}"
diff --git a/conf/machine/include/tune-microblaze.inc b/conf/machine/include/tune-microblaze.inc
new file mode 100644
index 00000000..851379b8
--- /dev/null
+++ b/conf/machine/include/tune-microblaze.inc
@@ -0,0 +1,20 @@
+DEFAULTTUNE ?= "microblaze"
+SOC_FAMILY ?= "microblaze"
+
+require conf/machine/include/tune-microblaze-features.inc
+require conf/machine/include/soc-family.inc
+
+TUNEVALID[microblaze] = "Microblaze"
+AVAILTUNES += "microblaze"
+
+TUNE_FEATURES_tune-microblaze = "microblaze"
+PACKAGE_EXTRA_ARCHS_tune-microblaze = "${TUNE_PKGARCH}"
+
+# Linux Configuration
+KERNEL_IMAGETYPE ?= "linux.bin.ub"
+
+# U-Boot Configuration
+UBOOT_MACHINE ?= "microblaze-generic"
+
+# linux-yocto KMACHINE
+KMACHINE ?= "microblaze"
diff --git a/conf/machine/include/tune-zynq.inc b/conf/machine/include/tune-zynq.inc
new file mode 100644
index 00000000..46334205
--- /dev/null
+++ b/conf/machine/include/tune-zynq.inc
@@ -0,0 +1,22 @@
+DEFAULTTUNE ?= "zynq"
+SOC_FAMILY ?= "zynq"
+
+require conf/machine/include/tune-cortexa9.inc
+require conf/machine/include/soc-family.inc
+
+TUNEVALID[zynq] = "Zynq"
+AVAILTUNES += "zynq"
+
+TUNE_FEATURES_tune-zynq += "${TUNE_FEATURES_tune-armv7a-neon} zynq"
+ARMPKGARCH = "${ARMPKGARCH_tune-armv7a-neon}"
+PACKAGE_EXTRA_ARCHS_tune-zynq = "${PACKAGE_EXTRA_ARCHS_tune-armv7a-neon} zynq"
+
+# Linux Configuration
+KERNEL_IMAGETYPE ?= "uImage"
+
+# Set default load address.
+# Override with KERNEL_EXTRA_ARGS_<board> += "..." in machine file if required
+KERNEL_EXTRA_ARGS_zynq += "UIMAGE_LOADADDR=0x8000"
+
+# linux-yocto KMACHINE
+KMACHINE ?= "zynq"