blob: 457abfd5be3e085e31f8ff28a696d72450692791 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
SUMMARY = "Aktualizr SOTA Client"
DESCRIPTION = "SOTA Client application written in C++"
HOMEPAGE = "https://github.com/advancedtelematic/aktualizr"
SECTION = "base"
LICENSE = "MPL-2.0"
LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=9741c346eef56131163e13b9db1241b3"
DEPENDS = "boost curl openssl libarchive libsodium "
DEPENDS_append_class-target = "jansson ostree ${@bb.utils.contains('SOTA_CLIENT_FEATURES', 'hsm', ' libp11', '', d)} "
DEPENDS_append_class-native = "glib-2.0-native "
RDEPENDS_${PN}_class-target = "lshw "
RDEPENDS_${PN}_append_class-target = "${@bb.utils.contains('SOTA_CLIENT_FEATURES', 'hsm', ' engine-pkcs11', '', d)} "
PV = "1.0+git${SRCPV}"
PR = "7"
SRC_URI = " \
git://github.com/advancedtelematic/aktualizr;branch=${BRANCH} \
"
SRCREV = "57e9cdb8aa1e8ee9e682628bd67031d9be7aaafa"
BRANCH ?= "master"
S = "${WORKDIR}/git"
inherit cmake
BBCLASSEXTEND =+ "native"
EXTRA_OECMAKE = "-DWARNING_AS_ERROR=OFF -DCMAKE_BUILD_TYPE=Release -DAKTUALIZR_VERSION=${PV} "
EXTRA_OECMAKE_append_class-target = " -DBUILD_OSTREE=ON ${@bb.utils.contains('SOTA_CLIENT_FEATURES', 'hsm', '-DBUILD_P11=ON', '', d)} "
EXTRA_OECMAKE_append_class-native = " -DBUILD_SOTA_TOOLS=ON -DBUILD_OSTREE=OFF "
do_install_append () {
rm -f ${D}${bindir}/aktualizr_cert_provider
}
do_install_append_class-target () {
rm -f ${D}${bindir}/aktualizr_implicit_writer
}
do_install_append_class-native () {
rm -f ${D}${bindir}/aktualizr
rm -f ${D}${bindir}/aktualizr-info
install -d ${D}${libdir}/sota
install -m 0644 ${S}/config/sota_autoprov.toml ${D}/${libdir}/sota/sota_autoprov.toml
install -m 0644 ${S}/config/sota_hsm_test.toml ${D}/${libdir}/sota/sota_hsm_test.toml
install -m 0644 ${S}/config/sota_implicit_prov.toml ${D}/${libdir}/sota/sota_implicit_prov.toml
}
FILES_${PN}_class-target = " \
${bindir}/aktualizr \
${bindir}/aktualizr-info \
"
FILES_${PN}_class-native = " \
${bindir}/aktualizr_implicit_writer \
${bindir}/garage-deploy \
${bindir}/garage-push \
${libdir}/sota/* \
"
# vim:set ts=4 sw=4 sts=4 expandtab:
|
