Create recipe for implicit provisioning file shuffling.

Split aktualizr into basic and native recipes by moving most of the work
to an include file. Use aktualizr-implicit-writer (on host) to do the
actual work of configuring sota.toml and installing files.

Still not quite fully functional.

6 files changed, 94 insertions, 23 deletions

diff --git a/recipes-sota/aktualizr/aktualizr-auto-prov.bb b/recipes-sota/aktualizr/aktualizr-auto-prov.bb
index 054b5cd..b30e884 100644
--- a/recipes-sota/aktualizr/aktualizr-auto-prov.bb
+++ b/recipes-sota/aktualizr/aktualizr-auto-prov.bb
@@ -1,10 +1,12 @@
 SUMMARY = "Aktualizr systemd service and configurations"
-DESCRIPTION = "Systemd service and configurations for Aktualizr, the SOTA Client application written in C++"
+DESCRIPTION = "Systemd service and configurations for autoprovisioning Aktualizr, the SOTA Client application written in C++"
 HOMEPAGE = "https://github.com/advancedtelematic/aktualizr"
 SECTION = "base"
 LICENSE = "MPL-2.0"
 LIC_FILES_CHKSUM = "file://${WORKDIR}/LICENSE;md5=9741c346eef56131163e13b9db1241b3"
 RDEPENDS_${PN} = "aktualizr"
+PV = "1.0"
+PR = "6"
 
 SRC_URI = " \
   file://LICENSE \
@@ -12,8 +14,6 @@ SRC_URI = " \
   file://aktualizr-autoprovision.service \
   file://sota_autoprov.toml \
   "
-PV = "1.0"
-PR = "6"
 
 SYSTEMD_SERVICE_${PN} = "aktualizr.service"
 
diff --git a/recipes-sota/aktualizr/aktualizr-implicit-prov.bb b/recipes-sota/aktualizr/aktualizr-implicit-prov.bb
new file mode 100644
index 0000000..edec409
--- /dev/null
+++ b/recipes-sota/aktualizr/aktualizr-implicit-prov.bb
@@ -0,0 +1,36 @@
+SUMMARY = "Aktualizr systemd service and configurations"
+DESCRIPTION = "Systemd service and configurations for implicitly provisioning Aktualizr, the SOTA Client application written in C++"
+HOMEPAGE = "https://github.com/advancedtelematic/aktualizr"
+SECTION = "base"
+LICENSE = "MPL-2.0"
+LIC_FILES_CHKSUM = "file://${WORKDIR}/LICENSE;md5=9741c346eef56131163e13b9db1241b3"
+DEPENDS = "aktualizr-native"
+RDEPENDS_${PN} = "aktualizr"
+PV = "1.0"
+PR = "1"
+
+SRC_URI = " \
+  file://LICENSE \
+  file://aktualizr-autoprovision.service \
+  file://sota_implicit_prov.toml \
+  "
+
+SYSTEMD_SERVICE_${PN} = "aktualizr.service"
+
+inherit systemd
+
+export SOTA_PACKED_CREDENTIALS
+
+do_install() {
+    install -d ${D}/${systemd_unitdir}/system
+    install -m 0644 ${WORKDIR}/aktualizr-autoprovision.service ${D}/${systemd_unitdir}/system/aktualizr.service
+    install -d ${D}/usr/lib/sota
+    aktualizr_implicit_writer -c ${SOTA_PACKED_CREDENTIALS} \
+        -i ${WORKDIR}/sota_implicit_prov.toml -o ${D}/usr/lib/sota/sota.toml -p ${D}
+}
+
+FILES_${PN} = " \
+                ${systemd_unitdir}/system/aktualizr.service \
+                /usr/lib/sota/sota.toml \
+                /var/sota/root.crt \
+                "
diff --git a/recipes-sota/aktualizr/aktualizr-native_git.bb b/recipes-sota/aktualizr/aktualizr-native_git.bb
new file mode 100644
index 0000000..59479fd
--- /dev/null
+++ b/recipes-sota/aktualizr/aktualizr-native_git.bb
@@ -0,0 +1,16 @@
+require aktualizr_common.inc
+
+DEPENDS = "boost-native openssl-native libarchive-native libsodium-native"
+
+inherit native
+
+EXTRA_OECMAKE = "-DWARNING_AS_ERROR=OFF -DCMAKE_BUILD_TYPE=Release -DBUILD_OSTREE=OFF -DAKTUALIZR_VERSION=${PV}"
+
+do_install_append () {
+    rm ${D}${bindir}/aktualizr
+    rm ${D}${bindir}/aktualizr_cert_provider
+}
+
+FILES_${PN} = " \
+                ${bindir}/aktualizr_implicit_writer \
+                "
diff --git a/recipes-sota/aktualizr/aktualizr_common.inc b/recipes-sota/aktualizr/aktualizr_common.inc
new file mode 100644
index 0000000..61854ea
--- /dev/null
+++ b/recipes-sota/aktualizr/aktualizr_common.inc
@@ -0,0 +1,19 @@
+SUMMARY = "Aktualizr SOTA Client"
+DESCRIPTION = "SOTA Client application written in C++"
+HOMEPAGE = "https://github.com/advancedtelematic/aktualizr"
+SECTION = "base"
+LICENSE = "MPL-2.0"
+LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=9741c346eef56131163e13b9db1241b3"
+
+PV = "1.0+git${SRCPV}"
+PR = "7"
+
+SRC_URI = " \
+  git://github.com/advancedtelematic/aktualizr;branch=${BRANCH} \
+  "
+SRCREV = "1004efa3f86cef90c012b34620992b5762b741e3"
+BRANCH ?= "master"
+
+S = "${WORKDIR}/git"
+
+inherit cmake
diff --git a/recipes-sota/aktualizr/aktualizr_git.bb b/recipes-sota/aktualizr/aktualizr_git.bb
index 2d0dadc..4f6a175 100644
--- a/recipes-sota/aktualizr/aktualizr_git.bb
+++ b/recipes-sota/aktualizr/aktualizr_git.bb
@@ -1,32 +1,21 @@
-SUMMARY = "Aktualizr SOTA Client"
-DESCRIPTION = "SOTA Client application written in C++"
-HOMEPAGE = "https://github.com/advancedtelematic/aktualizr"
-SECTION = "base"
-LICENSE = "MPL-2.0"
-LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=9741c346eef56131163e13b9db1241b3"
-DEPENDS = "boost curl openssl jansson libsodium ostree"
+require aktualizr_common.inc
+
+DEPENDS = "boost curl jansson openssl libarchive libsodium ostree"
 RDEPENDS_${PN} = "lshw"
 
 DEPENDS_append = "${@bb.utils.contains('SOTA_CLIENT_FEATURES', 'hsm', ' libp11', '', d)}"
-
 RDEPENDS_${PN}_append = "${@bb.utils.contains('SOTA_CLIENT_FEATURES', 'hsm', ' engine-pkcs11', '', d)}"
 RDEPENDS_${PN}_append = "${@bb.utils.contains('SOTA_CLIENT_FEATURES', 'hsm-test', ' softhsm softhsm-testtoken', '', d)}"
 
-SRC_URI = " \
-  git://github.com/advancedtelematic/aktualizr;branch=${BRANCH} \
-  "
-SRCREV = "1004efa3f86cef90c012b34620992b5762b741e3"
-BRANCH ?= "master"
-
-PV = "1.0+git${SRCPV}"
-PR = "7"
-
-S = "${WORKDIR}/git"
-
-inherit cmake systemd
+inherit systemd
 
 EXTRA_OECMAKE = "-DWARNING_AS_ERROR=OFF -DCMAKE_BUILD_TYPE=Release -DBUILD_OSTREE=ON -DAKTUALIZR_VERSION=${PV}"
 
+do_install_append () {
+    rm ${D}${bindir}/aktualizr_cert_provider
+    rm ${D}${bindir}/aktualizr_implicit_writer
+}
+
 FILES_${PN} = " \
                 ${bindir}/aktualizr \
                 "
diff --git a/recipes-sota/aktualizr/files/sota_implicit_prov.toml b/recipes-sota/aktualizr/files/sota_implicit_prov.toml
new file mode 100644
index 0000000..31e2946
--- /dev/null
+++ b/recipes-sota/aktualizr/files/sota_implicit_prov.toml
@@ -0,0 +1,11 @@
+[tls]
+certificates_directory = "/var/sota/"
+ca_file = "root.crt"
+client_certificate = "client.pem"
+pkey_file = "pkey.pem"
+
+[uptane]
+metadata_path = "/var/sota/metadata"
+private_key_path = "ecukey.der"
+public_key_path = "ecukey.pub"
+