Add OTA SD image for Minnowboard

4 files changed, 86 insertions, 0 deletions

diff --git a/classes/sdcard_image-minnowboard-ota.bbclass b/classes/sdcard_image-minnowboard-ota.bbclass
new file mode 100644
index 0000000..c49b3cd
--- /dev/null
+++ b/classes/sdcard_image-minnowboard-ota.bbclass
@@ -0,0 +1,78 @@
+inherit image_types
+
+# Boot partition volume id
+BOOTDD_VOLUME_ID ?= "${MACHINE}"
+
+# Boot partition size [in KiB] (will be rounded up to IMAGE_ROOTFS_ALIGNMENT)
+BOOT_SPACE ?= "4096"
+
+IMAGE_ROOTFS_ALIGNMENT = "4096"
+SDIMG_OTA_ROOTFS_TYPE ?= "otaimg"
+SDIMG_OTA_ROOTFS = "${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.${SDIMG_OTA_ROOTFS_TYPE}"
+
+IMAGE_TYPEDEP_minnowboard-sdimg-ota = "${SDIMG_OTA_ROOTFS_TYPE}"
+IMAGE_DEPENDS_minnowboard-sdimg-ota = " \
+                        parted-native \
+                        mtools-native \
+                        dosfstools-native \
+                        minnowboard-bootfiles \
+                        "
+
+SDIMG_OTA = "${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.minnowboard-sdimg-ota"
+
+IMAGE_CMD_minnowboard-sdimg-ota () {
+        OTAROOT_SIZE=`du -Lb ${SDIMG_OTA_ROOTFS} | cut -f1`
+        OTAROOT_SIZE=$(expr ${OTAROOT_SIZE} / 1024 + 1)
+        BOOT_SPACE_ALIGNED=$(expr ${BOOT_SPACE} + ${IMAGE_ROOTFS_ALIGNMENT} - 1)
+        BOOT_SPACE_ALIGNED=$(expr ${BOOT_SPACE_ALIGNED} - ${BOOT_SPACE_ALIGNED} % ${IMAGE_ROOTFS_ALIGNMENT})
+        SDIMG_OTA_SIZE=$(expr ${IMAGE_ROOTFS_ALIGNMENT} + ${BOOT_SPACE_ALIGNED} + $OTAROOT_SIZE)
+
+        echo "Creating filesystem with Boot partition ${BOOT_SPACE_ALIGNED} KiB and RootFS $OTAROOT_SIZE KiB"
+
+        # Initialize sdcard image file
+        dd if=/dev/zero of=${SDIMG_OTA} bs=1024 count=0 seek=${SDIMG_OTA_SIZE}
+
+        # Create partition table
+        parted -s ${SDIMG_OTA} mklabel msdos
+        # Create boot partition and mark it as bootable
+        parted -s ${SDIMG_OTA} unit KiB mkpart primary fat32 ${IMAGE_ROOTFS_ALIGNMENT} $(expr ${BOOT_SPACE_ALIGNED} \+ ${IMAGE_ROOTFS_ALIGNMENT})
+        parted -s ${SDIMG_OTA} set 1 boot on
+        # Create rootfs partition to the end of disk
+        parted -s ${SDIMG_OTA} -- unit KiB mkpart primary ext2 $(expr ${BOOT_SPACE_ALIGNED} \+ ${IMAGE_ROOTFS_ALIGNMENT}) -1s
+        parted ${SDIMG_OTA} print
+
+        # Create a vfat image with boot files
+        BOOT_BLOCKS=$(LC_ALL=C parted -s ${SDIMG_OTA} unit b print | awk '/ 1 / { print substr($4, 1, length($4 -1)) / 512 /2 }')
+        rm -f ${WORKDIR}/boot.img
+        mkfs.vfat -n "${BOOTDD_VOLUME_ID}" -S 512 -C ${WORKDIR}/boot.img $BOOT_BLOCKS
+        sync
+
+        mcopy -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/minnowboard-bootfiles/* ::/
+
+        sync
+        dd if=${WORKDIR}/boot.img of=${SDIMG_OTA} conv=notrunc seek=1 bs=$(expr ${IMAGE_ROOTFS_ALIGNMENT} \* 1024) && sync && sync
+
+        if echo "${SDIMG_OTA_ROOTFS_TYPE}" | egrep -q "*\.xz"
+        then
+                xzcat ${SDIMG_OTA_ROOTFS} | dd of=${SDIMG_OTA} conv=notrunc seek=1 bs=$(expr 1024 \* ${BOOT_SPACE_ALIGNED} + ${IMAGE_ROOTFS_ALIGNMENT} \* 1024) && sync && sync
+        else
+                dd if=${SDIMG_OTA_ROOTFS} of=${SDIMG_OTA} conv=notrunc seek=1 bs=$(expr 1024 \* ${BOOT_SPACE_ALIGNED} + ${IMAGE_ROOTFS_ALIGNMENT} \* 1024) && sync && sync
+        fi
+
+        # Optionally apply compression
+        case "${SDIMG_OTA_COMPRESSION}" in
+        "gzip")
+                gzip -k9 "${SDIMG_OTA}"
+                ;;
+        "bzip2")
+                bzip2 -k9 "${SDIMG_OTA}"
+                ;;
+        "xz")
+                xz -k "${SDIMG_OTA}"
+                ;;
+        esac
+
+        rm -f ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.minnowboard-sdimg-ota
+        ln -s ${IMAGE_NAME}.minnowboard-sdimg-ota ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.minnowboard-sdimg-ota
+}
+
diff --git a/classes/sdcard_image-porter-ota.bbclass b/classes/sdcard_image-porter-ota.bbclass
index 1b1de79..5909b44 100644
--- a/classes/sdcard_image-porter-ota.bbclass
+++ b/classes/sdcard_image-porter-ota.bbclass
@@ -59,6 +59,9 @@ IMAGE_CMD_porter-sdimg-ota () {
                 dd if=${SDIMG_OTA_ROOTFS} of=${SDIMG_OTA} conv=notrunc seek=1 bs=$(expr 1024 \* ${BOOT_SPACE_ALIGNED} + ${IMAGE_ROOTFS_ALIGNMENT} \* 1024) && sync && sync
         fi
 
+        rm -f ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.porter-sdimg-ota
+        ln -s ${IMAGE_NAME}.porter-sdimg-ota ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.porter-sdimg-ota
+
         # Optionally apply compression
         case "${SDIMG_OTA_COMPRESSION}" in
         "gzip")
diff --git a/classes/sdcard_image-rpi-ota.bbclass b/classes/sdcard_image-rpi-ota.bbclass
index 2fa03c4..8fc2605 100644
--- a/classes/sdcard_image-rpi-ota.bbclass
+++ b/classes/sdcard_image-rpi-ota.bbclass
@@ -162,6 +162,9 @@ IMAGE_CMD_rpi-sdimg-ota () {
                 dd if=${SDIMG_OTA_ROOTFS} of=${SDIMG_OTA} conv=notrunc seek=1 bs=$(expr 1024 \* ${BOOT_SPACE_ALIGNED} + ${IMAGE_ROOTFS_ALIGNMENT} \* 1024) && sync && sync
         fi
 
+        rm -f ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.rpi-sdimg-ota
+        ln -s ${IMAGE_NAME}.rpi-sdimg-ota ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.rpi-sdimg-ota
+
         # Optionally apply compression
         case "${SDIMG_OTA_COMPRESSION}" in
         "gzip")
diff --git a/conf/distro/sota.conf.inc b/conf/distro/sota.conf.inc
index d9b88c7..23e5a43 100644
--- a/conf/distro/sota.conf.inc
+++ b/conf/distro/sota.conf.inc
@@ -32,6 +32,8 @@ DISTRO_TYPE ?= "${@bb.utils.contains("IMAGE_FEATURES", "debug-tweaks", "debug",
 ## Minnowboard
 PREFERRED_PROVIDER_virtual/bootloader_intel-corei7-64 = "u-boot-ota"
 UBOOT_MACHINE_intel-corei7-64 = "minnowmax_defconfig"
+IMAGE_CLASSES_append_intel-corei7-64 = " sdcard_image-minnowboard-ota"
+IMAGE_FSTYPES += "${@'minnowboard-sdimg-ota' if d.getVar('MACHINE', True).startswith('intel-corei7-64') else ''}"
 
 ## QEMU
 PREFERRED_PROVIDER_virtual/bootloader_qemux86 = "u-boot-ota"