Merge pull request #150 from advancedtelematic/feat/remerge-recipes

Feat/remerge recipes

6 files changed, 49 insertions, 57 deletions

diff --git a/classes/sota_bleeding.inc b/classes/sota_bleeding.inc
index 77d004b..fc5947d 100644
--- a/classes/sota_bleeding.inc
+++ b/classes/sota_bleeding.inc
@@ -1,2 +1 @@
 SRCREV_pn-aktualizr ?= "${AUTOREV}"
-SRCREV_pn-aktualizr-native ?= "${AUTOREV}"
diff --git a/recipes-sota/aktualizr/aktualizr-auto-prov.bb b/recipes-sota/aktualizr/aktualizr-auto-prov.bb
index 48777b2..4f9fe4f 100644
--- a/recipes-sota/aktualizr/aktualizr-auto-prov.bb
+++ b/recipes-sota/aktualizr/aktualizr-auto-prov.bb
@@ -39,8 +39,8 @@ do_install_append() {
     if [ -n "${SOTA_PACKED_CREDENTIALS}" ]; then
         install -d ${D}/${systemd_unitdir}/system
         install -m 0644 ${WORKDIR}/aktualizr-autoprovision.service ${D}/${systemd_unitdir}/system/aktualizr.service
-        install -d ${D}/usr/lib/sota
-        install -m "0644" ${WORKDIR}/sota_autoprov.toml ${D}/usr/lib/sota/sota.toml
+        install -d ${D}${libdir}/sota
+        install -m "0644" ${WORKDIR}/sota_autoprov.toml ${D}${libdir}/sota/sota.toml
 
       # deploy SOTA credentials
       if [ -e ${SOTA_PACKED_CREDENTIALS} ]; then
@@ -57,6 +57,6 @@ do_install_append() {
 
 FILES_${PN} = " \
                 ${systemd_unitdir}/system/aktualizr.service \
-                /usr/lib/sota/sota.toml \
+                ${libdir}/sota/sota.toml \
                 /var/sota/sota_provisioning_credentials.zip \
                 "
diff --git a/recipes-sota/aktualizr/aktualizr-implicit-prov.bb b/recipes-sota/aktualizr/aktualizr-implicit-prov.bb
index a01ef48..21e38c9 100644
--- a/recipes-sota/aktualizr/aktualizr-implicit-prov.bb
+++ b/recipes-sota/aktualizr/aktualizr-implicit-prov.bb
@@ -22,13 +22,13 @@ inherit systemd
 do_install() {
     install -d ${D}/${systemd_unitdir}/system
     install -m 0644 ${WORKDIR}/aktualizr-autoprovision.service ${D}/${systemd_unitdir}/system/aktualizr.service
-    install -d ${D}/usr/lib/sota
+    install -d ${D}${libdir}/sota
     aktualizr_implicit_writer -c ${SOTA_PACKED_CREDENTIALS} \
-        -i ${WORKDIR}/sota_implicit_prov.toml -o ${D}/usr/lib/sota/sota.toml -p ${D}
+        -i ${WORKDIR}/sota_implicit_prov.toml -o ${D}${libdir}/sota/sota.toml -p ${D}
 }
 
 FILES_${PN} = " \
                 ${systemd_unitdir}/system/aktualizr.service \
-                /usr/lib/sota/sota.toml \
-                /usr/lib/sota/root.crt \
+                ${libdir}/sota/sota.toml \
+                ${libdir}/sota/root.crt \
                 "
diff --git a/recipes-sota/aktualizr/aktualizr-native_git.bb b/recipes-sota/aktualizr/aktualizr-native_git.bb
deleted file mode 100644
index b89e9de..0000000
--- a/recipes-sota/aktualizr/aktualizr-native_git.bb
+++ /dev/null
@@ -1,18 +0,0 @@
-require aktualizr_common.inc
-
-DEPENDS = "boost-native glib-2.0-native curl-native openssl-native libarchive-native libsodium-native"
-
-inherit native
-
-EXTRA_OECMAKE = "-DWARNING_AS_ERROR=OFF -DCMAKE_BUILD_TYPE=Release -DBUILD_SOTA_TOOLS=ON -DBUILD_OSTREE=OFF -DAKTUALIZR_VERSION=${PV}"
-
-do_install_append () {
-    rm ${D}${bindir}/aktualizr
-    rm ${D}${bindir}/aktualizr_cert_provider
-    rm ${D}${bindir}/garage-deploy
-}
-
-FILES_${PN} = " \
-                ${bindir}/aktualizr_implicit_writer \
-                ${bindir}/garage-push \
-                "
diff --git a/recipes-sota/aktualizr/aktualizr_common.inc b/recipes-sota/aktualizr/aktualizr_common.inc
deleted file mode 100644
index 79c5e37..0000000
--- a/recipes-sota/aktualizr/aktualizr_common.inc
+++ /dev/null
@@ -1,19 +0,0 @@
-SUMMARY = "Aktualizr SOTA Client"
-DESCRIPTION = "SOTA Client application written in C++"
-HOMEPAGE = "https://github.com/advancedtelematic/aktualizr"
-SECTION = "base"
-LICENSE = "MPL-2.0"
-LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=9741c346eef56131163e13b9db1241b3"
-
-PV = "1.0+git${SRCPV}"
-PR = "7"
-
-SRC_URI = " \
-  git://github.com/advancedtelematic/aktualizr;branch=${BRANCH} \
-  "
-SRCREV = "67c4f44c4136d16871726449502e3926098e8524"
-BRANCH ?= "master"
-
-S = "${WORKDIR}/git"
-
-inherit cmake
diff --git a/recipes-sota/aktualizr/aktualizr_git.bb b/recipes-sota/aktualizr/aktualizr_git.bb
index 1b3986a..470c9bf 100644
--- a/recipes-sota/aktualizr/aktualizr_git.bb
+++ b/recipes-sota/aktualizr/aktualizr_git.bb
@@ -1,22 +1,52 @@
-require aktualizr_common.inc
+SUMMARY = "Aktualizr SOTA Client"
+DESCRIPTION = "SOTA Client application written in C++"
+HOMEPAGE = "https://github.com/advancedtelematic/aktualizr"
+SECTION = "base"
+LICENSE = "MPL-2.0"
+LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=9741c346eef56131163e13b9db1241b3"
 
-DEPENDS = "boost curl jansson openssl libarchive libsodium ostree"
-RDEPENDS_${PN} = "lshw"
+DEPENDS = "boost curl openssl libarchive libsodium "
+DEPENDS_append_class-target = "jansson ostree ${@bb.utils.contains('SOTA_CLIENT_FEATURES', 'hsm', ' libp11', '', d)} "
+DEPENDS_append_class-native = "glib-2.0-native "
 
-DEPENDS_append = "${@bb.utils.contains('SOTA_CLIENT_FEATURES', 'hsm', ' libp11', '', d)}"
-RDEPENDS_${PN}_append = "${@bb.utils.contains('SOTA_CLIENT_FEATURES', 'hsm', ' engine-pkcs11', '', d)}"
-RDEPENDS_${PN}_append = "${@bb.utils.contains('SOTA_CLIENT_FEATURES', 'hsm-test', ' softhsm softhsm-testtoken', '', d)}"
+RDEPENDS_${PN}_class-target = "lshw "
+RDEPENDS_${PN}_append_class-target = "${@bb.utils.contains('SOTA_CLIENT_FEATURES', 'hsm', ' engine-pkcs11', '', d)} "
+RDEPENDS_${PN}_append_class-target = "${@bb.utils.contains('SOTA_CLIENT_FEATURES', 'hsm-test', ' softhsm softhsm-testtoken', '', d)} "
 
-inherit systemd
+PV = "1.0+git${SRCPV}"
+PR = "7"
 
-EXTRA_OECMAKE = "-DWARNING_AS_ERROR=OFF -DCMAKE_BUILD_TYPE=Release -DBUILD_OSTREE=ON ${@bb.utils.contains('SOTA_CLIENT_FEATURES', 'hsm', '-DBUILD_P11=ON', '', d)} -DAKTUALIZR_VERSION=${PV}"
+SRC_URI = " \
+  git://github.com/advancedtelematic/aktualizr;branch=${BRANCH} \
+  "
+SRCREV = "67c4f44c4136d16871726449502e3926098e8524"
+BRANCH ?= "master"
+
+S = "${WORKDIR}/git"
+
+inherit cmake
+
+BBCLASSEXTEND =+ "native"
+
+EXTRA_OECMAKE = "-DWARNING_AS_ERROR=OFF -DCMAKE_BUILD_TYPE=Release -DAKTUALIZR_VERSION=${PV} "
+EXTRA_OECMAKE_append_class-target = "-DBUILD_OSTREE=ON ${@bb.utils.contains('SOTA_CLIENT_FEATURES', 'hsm', '-DBUILD_P11=ON', '', d)} "
+EXTRA_OECMAKE_append_class-native = "-DBUILD_SOTA_TOOLS=ON -DBUILD_OSTREE=OFF "
 
 do_install_append () {
-    rm ${D}${bindir}/aktualizr_cert_provider
-    rm ${D}${bindir}/aktualizr_implicit_writer
-    rm ${D}${bindir}/garage-deploy
+    rm -f ${D}${bindir}/aktualizr_cert_provider
+    rm -f ${D}${bindir}/garage-deploy
+}
+do_install_append_class-target () {
+    rm -f ${D}${bindir}/aktualizr_implicit_writer
+}
+do_install_append_class-native () {
+    rm -f ${D}${bindir}/aktualizr
 }
 
-FILES_${PN} = " \
+FILES_${PN}_class-target = " \
                 ${bindir}/aktualizr \
                 "
+FILES_${PN}_class-native = " \
+                ${bindir}/aktualizr_implicit_writer \
+                ${bindir}/garage-push \
+                "